- Offizieller Beitrag
Hi,
ich habe die IRC.au3 von Chip (s. hier) um einige Funktionen erweitert:
_IRCSendAction
Ermöglicht das Senden von Nachrichten des Typs ACTION
Darstellung: [10:25] ***MEIN_NICK macht eine Aktion
_IRCQuit
Beendet die erstellte IRC-Verbindung, optional mit angehängter Nachricht
Anmerkung: Nicht alle Clients können mit QUIT übergebene Nachrichten darstellen
_IRCLeaveChannel
Verlassen eines Channels, optional mit angehängter Nachricht
Spoiler anzeigen
;===============================================================================
;
; Description: Sends a message as ACTION using IRC
; Parameter(s): $irc - Socket Identifer from _IRCConnect ()
; $msg - Message you want to send
; $chan - Channel/Nick you wish to send to
; Requirement(s): _IRCConnect () to be run
; Return Value(s): On Success - 1
; On Failure - -1 = Server disconnected.
; Author(s): BugFix
; Note(s): English only
;
;===============================================================================
Func _IRCSendAction ($irc, $msg, $chan="")
If $irc = -1 Then Return 0
If $chan = "" Then
TCPSend($irc, $msg & @CRLF)
If @error Then
MsgBox(1, "IRC.au3", "Server has disconnected.")
Return -1
EndIf
Return 1
EndIf
TCPSend($irc, "PRIVMSG " & $chan & " :" & Chr(1) & "ACTION " & $msg & Chr(1) & @CRLF)
If @error Then
MsgBox(1, "IRC.au3", "Server has disconnected.")
Return -1
EndIf
Return 1
EndFunc
;===============================================================================
;
; Description: Close the IRC Connection
; Parameter(s): $irc - Socket Identifer from _IRCConnect ()
; $msg - Message to send with quit
; Requirement(s): _IRCConnect () to be run
; Return Value(s): On Success - 1
; On Failure - -1 = Server disconnected.
; Author(s): BugFix
; Note(s): English only
;
;===============================================================================
Func _IRCQuit($irc, $msg="")
If $irc = -1 Then Return 0
TCPSend($irc, "QUIT :" & $msg & @CRLF)
Return 1
EndFunc
;===============================================================================
;
; Description: Leave the IRC Channel
; Parameter(s): $irc - Socket Identifer from _IRCConnect ()
; $msg - Message to send with part
; Requirement(s): _IRCConnect () to be run
; Return Value(s): On Success - 1
; On Failure - -1 = Server disconnected.
; Author(s): BugFix
; Note(s): English only
;
;===============================================================================
Func _IRCLeaveChannel ($irc, $msg="", $chan="")
If $irc = -1 Then Return 0
TCPSend($irc, "PART " & $chan & " :" & $msg & @CRLF)
If @error Then
MsgBox(1, "IRC.au3", "Server has disconnected.")
Return -1
EndIf
Return 1
EndFunc