Alternativer Lösungsweg - GuiCtrlSetBkColor

Yaerox

Ich habe ein Tool mit einer GUI, einer Listview in der der Benutzer via Inputs Neue Zeilen einfügen kann, und die Zeilen färben können soll.

Problem:
- Erstelle ich mit der Native-Funktion die Zeile so habe ich den Index der eben angelegten Zeile nicht.
- Erstelle ich mit der UDF-Funktion die Zeile so habe ich die control-ID der eben angelegten Zeile nicht.

Ich dachte:

Zitat von _GUICtrlListView_AddItem - Remarks

As AutoIt uses the $iParam parameter to store the controlID of native-created ListView items, this value should be set sufficiently high for UDF-created items to avoid possible conflict with any existing controls - a starting value of 1000 is recommended.

der Parameter wird mit der jeweiligen ID besetzt. Fehlanzeige:

Spoiler anzeigen

AutoIt: Example

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>


;~ Example()
Func Example()
	Local $hImage, $idListview, $iRetVal
	Local $cID_LVITEM


	; Create GUI
	GUICreate("ListView Set Extended Style", 400, 300)
	$idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
	GUISetState(@SW_SHOW)


	; Add columns
	_GUICtrlListView_InsertColumn($idListview, 0, "Column 1", 100)
	_GUICtrlListView_InsertColumn($idListview, 1, "Column 2", 100)
	_GUICtrlListView_InsertColumn($idListview, 2, "Column 3", 100)




	; Add items
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)


	ConsoleWrite("GuiCtrlSetBkColor $iRetVal: " & GuiCtrlSetBkColor($iRetVal, 0xFF0000) & @CRLF)
	ConsoleWrite("GuiCtrlSetBkColor $cID_LVITEM: " & GuiCtrlSetBkColor($cID_LVITEM, 0xFF0000) & @CRLF)


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

Dann habe ich das nochmal gelesen und dachte ich kann dort eine Zahl angeben, die als Control-ID gesetzt wird. Dann wird jedoch die Zeile nicht gefärbt (Grund unbekannt):

Spoiler anzeigen

AutoIt: Example1

Example1()
Func Example1()
	Local $hImage, $idListview, $iRetVal
	Local $cID_LVITEM = 5000


	; Create GUI
	GUICreate("ListView Set Extended Style", 400, 300)
	$idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
	GUISetState(@SW_SHOW)


	; Add columns
	_GUICtrlListView_InsertColumn($idListview, 0, "Column 1", 100)
	_GUICtrlListView_InsertColumn($idListview, 1, "Column 2", 100)
	_GUICtrlListView_InsertColumn($idListview, 2, "Column 3", 100)




	; Add items
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)
	$cID_LVITEM += 1
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)
	$cID_LVITEM += 1
	$iRetVal = _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", -1, $cID_LVITEM)
	ConsoleWrite("$iRetVal: " & $iRetVal & @CRLF)
	ConsoleWrite("$cID_LVITEM: " & $cID_LVITEM & @CRLF)


	ConsoleWrite("GuiCtrlSetBkColor $iRetVal: " & GuiCtrlSetBkColor($iRetVal, 0xFF0000) & @CRLF)
	ConsoleWrite("GuiCtrlSetBkColor $cID_LVITEM: " & GuiCtrlSetBkColor($cID_LVITEM, 0xFF0000) & @CRLF)


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example1

Alles anzeigen

Den Index möchte ich nutzen um mit der Funktion _GUICtrlListView_SetItemText die Zeile im Nachhinein noch bearbeiten zu können. Die ControlID der Zeile soll in einer versteckten Spalten geschrieben werden. Nun habe ich bislang als einzige Lösung GUICtrlSetData statt _GUICtrlListView_SetItemText:

Spoiler anzeigen

AutoIt: Example2

Example2()
Func Example2()
	Local $hImage, $idListview, $iRetVal
	Local $cID_LVITEM1, $cID_LVITEM2, $cID_LVITEM3


	; Create GUI
	GUICreate("ListView Set Extended Style", 400, 300)
	$idListview = GUICtrlCreateListView("C1|C2|C3|C4|C5|C6", 2, 2, 394, 268)
	$cID_LVITEM1 = GUICtrlCreateListViewItem("A|B|C|D|E|", $idListview)
	$cID_LVITEM2 = GUICtrlCreateListViewItem("A|B|C|D|E|", $idListview)
	$cID_LVITEM3 = GUICtrlCreateListViewItem("A|B|C|D|E|", $idListview)
	GUISetState(@SW_SHOW)


	ConsoleWrite("$cID_LVITEM1: " & $cID_LVITEM1 & @CRLF)
	ConsoleWrite("$cID_LVITEM2: " & $cID_LVITEM2 & @CRLF)
	ConsoleWrite("$cID_LVITEM3: " & $cID_LVITEM3 & @CRLF)
	ConsoleWrite("GuiCtrlSetBkColor $cID_LVITEM2: " & GuiCtrlSetBkColor($cID_LVITEM2, 0xFF0000) & @CRLF)


 	GUICtrlSetData($cID_LVITEM2, "A|B|C|D|E|" & $cID_LVITEM2)


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

Kennt ihr alternative Lösungswege?

**UEZ**

Schon mal hier reingeschaut?: https://www.autoitscript.com/forum/topic/18…ws-udf-version/

Yaerox

Nein, die UDF kannte ich nicht. Danke für den Tipp, das sieht sehr genial aus. Werde damit wohl ein wenig rumspielen

**autoBert**

du könntest die CtrlId's der LV-Items in einem Array speichern. Ich verstehe allerdings nicht warum es nicht möglich sein soll sie auch direkt in der LV abzuspeichern. ~~Ich werde mal das verlinkte Beispiel so abändern und dann hierein editieren.~~
Erledigt:

C

;https://autoit.de/index.php/Thread/84194-Alternativer-L%C3%B6sungsweg-GuiCtrlSetBkColor/?postID=673544#post673544
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <ListviewConstants.au3>
#include <array.au3>
#include <File.au3>
Global $aNames[1]
_FileReadToArray('Benutzer.txt',$aNames,$FRTA_NOCOUNT)
$hGui=GUICreate("LV-Items färben", 220, 400)
$listview = GUICtrlCreateListView("Name|Status|CtrlID", 10, 10, 210, 350)
For $i = 0 To UBound($aNames)-1
	$iItem = GUICtrlCreateListViewItem($aNames[$i] & "|Offline", $listview)
	GUICtrlSetData($iItem, "||" & $iItem)
Next
$idAdd=GUICtrlCreateButton('+',10,370,30)
$idDel=GUICtrlCreateButton('-',180,370,30)
_GUICtrlListView_SetColumnWidth($listview, 0, 140)
_GUICtrlListView_SetColumnWidth($listview, 1, 40)
;_GUICtrlListView_SetColumnWidth($listview, 2, 0) ;0 = unsichtbar
_GUICtrlListView_RegisterSortCallBack($listview)
_RandomOnOff()
GUISetState(@SW_SHOW)
;GUICtrlSetColor(-1, 0x22C21F)
;GUICtrlSetColor(-1, 0xAA0000)
While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			_GUICtrlListView_UnRegisterSortCallBack($listview)
			_FileWriteFromArray('Benutzer.txt',$aNames)
			Exit
		Case $listview
			_GUICtrlListView_SortItems($listview, GUICtrlGetState($listview))
		Case $idDel
			$aItem = _GUICtrlListView_GetItemTextArray($listview)
			If MsgBox($MB_YESNO+$MB_ICONQUESTION+$MB_DEFBUTTON2,$aItem[1],'Soll Eintrag gelöscht werden?',$hGui)=$idYes Then
				GUICtrlDelete($aItem[3])
				;to do auch noch aus $aNames löschen
			EndIf
		Case $idAdd
			$sText=InputBox('Neuer Benutzer','Benutzer',Default,'',20)
			If MsgBox($MB_YESNO+$MB_ICONQUESTION+$MB_DEFBUTTON1,$sText,'Soll Eintrag hinzugefügt werden?',$hGui)=$idYes Then
				$iItem = GUICtrlCreateListViewItem($sText & "|Neu", $listview)
				_ArrayAdd($aNames,$sText)
				GUICtrlSetData($iItem, "||" & $iItem)
				_GUICtrlListView_EnsureVisible($listview,UBound($aNames)-1)
				GUICtrlSetBkColor($iItem,0x00FF12)
				Sleep(2000)
			EndIf
	EndSwitch
WEnd
Func _RandomOnOff()
	AdlibUnRegister("_RandomOnOff")
	_GUICtrlListView_BeginUpdate($listview)
	For $i = 0 To _GUICtrlListView_GetItemCount($listview)-1
		$aItem = _GUICtrlListView_GetItemTextArray($listview, $i)
		;_ArrayDisplay($aItem)
		If IsArray($aItem) Then
			If Random(1, 3, 1) = 1 Then
				GUICtrlSetData($aItem[3], "|Off")
				GUICtrlSetBkColor($aItem[3], 0xAA0000)
			Else
				GUICtrlSetData($aItem[3], "|On")
				GUICtrlSetBkColor($aItem[3], 0x22C21F)
			EndIf
		EndIf
	Next
	If GUICtrlGetState($listview) = 1 Then
		_GUICtrlListView_SortItems($listview, 0)
		_GUICtrlListView_SortItems($listview, 1)
	EndIf
	_GUICtrlListView_EndUpdate($listview)
	AdlibRegister("_RandomOnOff", Random(5000, 10000, 1))
EndFunc   ;==>_RandomOnOff

Alles anzeigen

Edit: Add- und DeleteButton noch hinzugefügt.

Yaerox

Zitat von autoBert

Ich verstehe allerdings nicht warum es nicht möglich sein soll sie auch direkt in der LV abzuspeichern.

Die Aussage kann ich grad nicht nachvollziehen. Sage ich das irgendwo?
So wie du es machst (erstellen und dann in einer zweiten Zeile diese Information an die LV-Zeile anhängen) mach ich das aktuell ja auch.

Interessanter Ansatz ist jedoch:

Zitat von autoBert

$aItem = _GUICtrlListView_GetItemTextArray($listview)

Man scheint dort ja alle control-ID zu erhalten ... ich werd mir die Funktion dann nochmal genauer anschauen müssen bei Zeiten...arbeite an diesem Projekt leider immer nur wenn Zeit dafür ist.

**autoBert**

Zitat von Yaerox

Die Aussage kann ich grad nicht nachvollziehen. Sage ich das irgendwo?

dann habe ich:

Zitat von Yaerox

Dann habe ich das nochmal gelesen und dachte ich kann dort eine Zahl angeben, die als Control-ID gesetzt wird. Dann wird jedoch die Zeile nicht gefärbt (Grund unbekannt):

wohl falsch interpretiert.

Zitat von Yaerox

So wie du es machst (erstellen und dann in einer zweiten Zeile diese Information an die LV-Zeile anhängen) mach ich das aktuell ja auch.
Man scheint dort ja alle control-ID zu erhalten

man erhält damit ein Array mit allen Spalteninhalten zu einem LV-Item. Du mußt übrigens nicht alle Spaltenwerte angeben, nur die geänderten:

Code

GUICtrlSetData($cID_LVITEM2, "|New B||New D||" & $cID_LVITEM2)

ein "zusammenstringen" mit Werten aus dem ResultArray von _GUICtrlListView_GetItemTextArray schadet aber auch nicht:

Code

$aItem = _GUICtrlListView_GetItemTextArray($idListview, 1);achtung Index nicht CtrlID
 	GUICtrlSetData($cID_LVITEM2, $aItem[1]&'|'&'New B|'&$aItem[3]&'|New D||'& $cID_LVITEM2)

Wichtig zu wissen ist, daß _GUICtrlListView_GetItemTextArray den 0 basierten Index des LV-Items erwartet und nicht die CtrlID. Das schöne daran ist aber ist: ist kein Index oder -1 angegeben wird das 1. selektierte genommen. Deshalb immer nur in LV mit $LVS_SINGLESEL verwenden, bzw. Routine(n) anpassen:

Code

Case $idDel
			AdlibUnRegister("_RandomOnOff") ;damit sich die Indizes nicht durch Neu-Sortierung ändern
			$aSelected = _GUICtrlListView_GetSelectedIndices($listview, True)
			If IsArray($aSelected) Then
				For $i = 1 To $aSelected[0]
					$aItem = _GUICtrlListView_GetItemTextArray($listview, $aSelected[$i])
					If MsgBox($MB_YESNO + $MB_ICONQUESTION + $MB_DEFBUTTON2, $aItem[1], 'Soll Eintrag gelöscht werden?', $hGui) = $idYes Then
						GUICtrlDelete($aItem[3])
						$iItem = _ArraySearch($aNames, $aItem[1])
						_ArrayDelete($aNames, $iItem)
					EndIf
				Next
			EndIf
			AdlibRegister("_RandomOnOff", Random(5000, 10000, 1))

Alles anzeigen

Yaerox

Zitat von autoBert

Du mußt übrigens nicht alle Spaltenwerte angeben, nur die geänderten:

Das war mir neu Danke für den Tipp.