Datei / Ordnerabfrage mit Icon (Button) anzeigen

firewalldevil

Hallo,

ich möchte Dateien und / oder Ordner abfragen in einem kleinen "Fenster".
Ein kleiner Button soll zeigen vorhanden ( grün ) nicht vorhanden ( rot ), halt wie eine Statusabfrage, der Button sollte vor dem Eintrag stehen.

Das Programm soll eine Datei ( abfrage.txt ) abfragen, in die ich einfach das Ziel reihenweise einkopiere.

zb
C:\temp\code
C:\Program Files (x86)\Internet Explorer\iexplorer.exe
usw

Ist der Button rot, möchte ich in einen hinterlegen Ordner springen.

machbar.....???

**Oscar**

Zitat von firewalldevil

machbar.....???

Na klar!
Fang an!

firewalldevil

sehr coole Antwort!

WER kann mir das programmieren?

**Oscar**

Oh! Entschuldige!
Ich habe nicht gesehen, dass Du das in Programmieranfragen gepostet hast.
Du solltest noch dazuschreiben, was Du bezahlen willst und bis wann das fertig sein soll.

Zitat von firewalldevil

Ist der Button rot, möchte ich in einen hinterlegen Ordner springen.

Diese Anforderung solltest Du auch etwas präzisieren.
Wo ist der Ordner hinterlegt?
Und für jeden Eintrag der gleiche Ordner? Oder für jeden Eintrag ein extra Ordner?
Was heißt: "möchte ich in einen Ordner springen"? Soll der Ordner auf dem Desktop (Explorer) geöffnet werden?

nwmbd

Hallo Oscar, hallo firewalldevil,

ich bin absoluter Beginner, selbst ich kann dir das "machen".

Aber Oscar hat es mehr als verdient, gutes Gelingen.

MFG

firewalldevil

ähm, bin nicht sicher wie viel Aufwand das ist und was so idR "gezahlt" wird, Amazon Wunsch?

Das Programm soll halt abfragen, ob Programme installiert sind, ohne den Programmstatus von Windows abzufragen, mir reichen die Dateien oder Ordner.
Ist die Datei nicht da, dann halt rot und man könnte über eine zweite Datei ( Sprungziel.txt ) den Ordner angeben, wo ich das Programm dann installieren kann.

**Oscar**

Zitat von firewalldevil

ähm, bin nicht sicher wie viel Aufwand das ist und was so idR "gezahlt" wird

Das haben wir ja schon geklärt. Spende an das Forum reicht!
Die Änderungswünsche kannst Du mir ja noch mitteilen. Dann baue ich das noch ein.

In die Runde gefragt: Ist so ein Programm von allgemeinen Interesse? Dann würde ich das auch hier posten.

nwmbd

Warum nicht, interessant zu sehen wie du es umsetzt

**Oscar**

Ok!

Screenshot:
FileCheck_Screenshot.png

AutoIt

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=FileCheck.exe
#AutoIt3Wrapper_Res_Description=FileCheck
#AutoIt3Wrapper_Res_Fileversion=1.0.0.0
#AutoIt3Wrapper_Res_LegalCopyright=Oscar (www.autoit.de)
#AutoIt3Wrapper_Res_Language=1031
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>
#include <WindowsConstants.au3>


OnAutoItExitRegister('OnAutoItExit')
Opt('GUIOnEventMode', 1)


Global $sTitle = 'FileCheck'
Global $sVersion = '1.0.0.0'
Global $sDate = '06.10.2016'
Global $sDatafile = @ScriptDir & '\FileCheck.txt'


Global $aFileFolder, $iCount = 0, $aidFileCheck[1][3]


Global $hMainGui = GUICreate(StringFormat('%s v%3.3s', $sTitle, $sVersion), 730, 600, -1, -1) ; das Fenster erstellen
GUISetBkColor(0xEEEEEE) ; Hintergrundfarbe für das Fenster festlegen
GUISetIcon('shell32.dll', 23) ; Icon für das Fenster festlegen
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseMainGui') ; Funktion die beim schließen des Fensters aufgerufen wird
_ReadDatafile() ; die Datei mit den Datei-Pfaden einlesen und Gui-Elemente erstellen
_CheckFileFolder() ; testen, ob die Pfade existieren
GUISetState(@SW_SHOW, $hMainGui) ; das Fenster anzeigen


Global $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY') ; die Message bei Windows registrieren
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY') ; das Fenster für den Empfang der Message registrieren
Global $g_iID = _WinAPI_ShellChangeNotifyRegister($hMainGui, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), @ScriptDir, 1) ; Windows mitteilen welches Verzeichnis überwacht werden soll
If @error Then ; wenn das fehlschlägt, dann...
	MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Fehler', '"ShellChangeNotifyRegister" ist fehlgeschlagen.')
	Exit ; Programm mit Fehlermeldung beenden
EndIf


While Sleep(250) ; in einer Endlosschleife immer 250 ms warten und danach die Pfade auf Existenz testen
	_CheckFileFolder()
WEnd


Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	; diese Funktion wird aufgerufen, wenn sich im überwachten Verzeichnis (@ScriptDir) eine Datei ändert
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	; wenn die geänderte Datei mit der Datendatei übereinstimmt, dann...
	If $sPath = $sDatafile Then _ReadDatafile() ; die Datei mit den Datei-Pfaden einlesen und Gui-Elemente neu erstellen
EndFunc   ;==>WM_SHELLCHANGENOTIFY


Func _CloseMainGui()
	If MsgBox(4 + 32 + 256, $sTitle, 'Soll das Programm wirklich beendet werden?', 0, $hMainGui) = 7 Then Return
	Exit
EndFunc   ;==>_CloseMainGui


Func OnAutoItExit()
	If $g_iID Then _WinAPI_ShellChangeNotifyDeregister($g_iID)
EndFunc   ;==>OnAutoItExit


Func _CheckFileFolder()
	For $i = 0 To $iCount - 1 ; Schleife, um alle Pfade aus der Datendatei durchzugehen
		If FileExists($aFileFolder[$i]) Then ; wenn der Pfad existiert, dann...
			If BitAND(GUICtrlGetState($aidFileCheck[$i][2]), $GUI_DISABLE) Then ; wenn der Button deaktiviert ist, dann...
				GUICtrlSetState($aidFileCheck[$i][2], $GUI_ENABLE) ; Button aktivieren
				GUICtrlSetBkColor($aidFileCheck[$i][0], 0x00FF00) ; und die Farbe auf grün setzen
			EndIf
		Else ; anderenfalls (Pfad existiert nicht)
			If BitAND(GUICtrlGetState($aidFileCheck[$i][2]), $GUI_ENABLE) Then ; wenn der Button aktiviert ist, dann...
				GUICtrlSetState($aidFileCheck[$i][2], $GUI_DISABLE) ; Button deaktivieren
				GUICtrlSetBkColor($aidFileCheck[$i][0], 0xFF0000) ; und die Farbe auf rot setzen
			EndIf
		EndIf
	Next
EndFunc   ;==>_CheckFileFolder


Func _ReadDatafile()
	If $iCount <> 0 Then ; wenn sich auf dem Fenster bereits Gui-Elemente befinden, dann...
		For $i = 0 To $iCount - 1 ; Schleife für die "Zeilen"
			For $j = 0 To 2 ; Schleife für die "Spalten"
				GUICtrlDelete($aidFileCheck[$i][$j]) ; alle Gui-Elemente löschen
			Next
		Next
	EndIf
	Local $sData = FileRead($sDatafile) ; Datei mit den Pfaden einlesen
	$aFileFolder = StringSplit($sData, @CRLF, 3) ; und beim Zeilenumbruch splitten
	$iCount = UBound($aFileFolder) - 1 ; Anzahl der Pfade merken
	ReDim $aidFileCheck[$iCount][3] ; das Array neu dimensionieren
	Local $aWinPos = WinGetPos($hMainGui), $aClientSize = WinGetClientSize($hMainGui) ; Position und Größe des Fensters holen
	WinMove($hMainGui, '', $aWinPos[0], $aWinPos[1], $aClientSize[0], $iCount * 40 + 56) ; das Fenster in der Größe an die neue Anzahl anpassen
	For $i = 0 To $iCount - 1 ; Schleife, um alle Pfade aus der Datendatei durchzugehen
		$aidFileCheck[$i][0] = GUICtrlCreateLabel('', 20, 24 + $i * 40, 16, 16, Default, $WS_EX_STATICEDGE) ; Label für den Status (rot/grün) erstellen
		GUICtrlSetBkColor(-1, 0xFF0000) ; erstmal auf rot setzen
		$aidFileCheck[$i][1] = GUICtrlCreateInput('', 44, 20 + $i * 40, 600, 24, BitOR($ES_LEFT, $ES_AUTOHSCROLL, $ES_READONLY)) ; das Feld für den Pfad erstellen
		GUICtrlSetBkColor(-1, 0xFFFFFF) ; Hintergrundfarbe auf weiß setzen
		GUICtrlSetFont(-1, 12, 400, 0, 'Tahoma', 5) ; Schriftart und -größe festlegen
		GUICtrlSetData(-1, $aFileFolder[$i]) ; den Pfad eintragen
		$aidFileCheck[$i][2] = GUICtrlCreateButton('', 650, 18 + $i * 40, 48, 28, $BS_ICON) ; Button zum aufrufen des Ordners erstellen
		GUICtrlSetImage(-1, 'shell32.dll', 23, 0) ; das Lupensymbol aus der Shell32.dll für den Button festlegen
		GUICtrlSetOnEvent(-1, '_OpenFolder') ; diese Funktion wird aufgerufen, wenn auf den Button geklickt wird
		GUICtrlSetState(-1, $GUI_DISABLE) ; den Button erstmal deaktivieren
		GUICtrlSetTip(-1, 'Öffne Verzeichnis im Explorer') ; den Tooltip für den Button festlegen
	Next
EndFunc   ;==>_ReadDatafile


Func _OpenFolder()
	Local $iButton = (@GUI_CtrlId - $aidFileCheck[0][2]) / 3 ; ermitteln welcher Button angeklickt wurde
	Local $sFolder
	If StringInStr(FileGetAttrib($aFileFolder[$iButton]), 'D') Then ; wenn der Pfad ein Verzeichnis ist, dann...
		$sFolder = $aFileFolder[$iButton] ; das Verzeichnis übernehmen
	Else ; anderenfalls (Pfad ist eine Datei)
		$sFolder = StringRegExpReplace($aFileFolder[$iButton], '(.+\\).*', '$1') ; das Verzeichnis aus dem Pfad extrahieren
	EndIf
	If StringRight($sFolder, 1) <> '\' Then $sFolder &= '\' ; wenn das Verzeichnis am Ende keinen Backslash aufweist, dann einen hinzufügen
	ShellExecute($sFolder) ; das Verzeichnis mit dem Explorer öffnen
EndFunc   ;==>_OpenFolder

Alles anzeigen

firewalldevil

Änderungswunsch:

Im Programm möchte ich nicht die Abfrage der Datei sehen, sondern wozu es gehört.

Also IE Abfrage, Eintrag: IE 11, der Ordner dahinter soll nicht in den der Abgefragt wird, sondern in den wo die Setup Datei liegt, das müsste man erstmalig angeben, bzw die Quellen hinrouten die später bleibt.

Ziel ist ich prüfe das System auf installierte Programm, wenn rot ( optisch ) dann gehe zum Setup und installiere.

Rev3 wäre das für unterschiedliche Abteilungen zu prüfen.

Maske: Marketing oder Konstruktion usw....

**Oscar**

Das hättest Du mal gleich am Anfang schreiben sollen, dann hätte ich das anders aufgebaut.
Es ist also kein Programm zum überwachen von Pfaden, sondern ein Installations-Check. Ich benenne es mal um in InstallCheck.

Normalerweise prüft man das (Programme installiert Ja/Nein) über die Registry. Dort kann man auch Versionen unterscheiden.
Nur bei Programmen, die sich nicht in die Registry eintragen, würde ich auf die Datei-Pfade ausweichen

Zum Anderen gehe ich davon aus, dass das InstallCheck nicht permanent laufen soll, sondern nur um den Status zu checken.
Somit kann ich mir das mit dem SHELLCHANGENOTIFY sparen. Das einlesen der Datendatei beim Start reicht ja aus.
Und dauernd die Pfade zu überprüfen ist auch überflüssig.

Für das Datenformat würde ich folgendes vorschlagen:
1. Zeile: Name des Programms für den Eintrag in der Liste
2. Zeile: Pfad in der Registry
3. Zeile: Verzeichnis, in dem das Setup-Programm liegt
Leerzeile (könnte man weglassen, sieht aber beim eingeben schöner aus, weil die Programme dann getrennt voneinander stehen)
1. Zeile:
2. Zeile:
3. Zeile:
Leerzeile
usw...

firewalldevil

ja hört sich gut an, sorry aber ich habe das auch im Nachgang mir überlegt....

**Oscar**

Bislang sieht das jetzt so aus:
InstallCheck.png

Ich habe jetzt noch einen Button zum aufrufen der Website (downloaden des Programms) hinzugefügt. Wenn keine Website angegeben ist, dann wird der Button deaktiviert.
Ganz oben der Button ist zum erneuten testen der Installation.
Der Button direkt hinter dem Programmnamen ruft das Installationsverzeichnis oder gleich die Installationsdatei auf (per ShellExecute).

Es fehlt jetzt noch die Auswahl der Abteilung.
Und noch ein paar Fragen:
Wie viele Abteilungen werden das?
Wie viele Programme (pro Abteilung) sollen dort eingetragen werden?
Wie groß (Auflösung) sind die Monitore?

Weil ich das bei zu vielen Programmen sonst mehrspaltig machen muss.

firewalldevil

ähm, das sieht schon sehr gut aus, die Buttons sind sehr cool gewählt!

Max 5 Versionen, evtl könnten man per Reiter, bis zu 25-30 Programme würde ich abfragen, oder man kann vorher den Standard prüfen, also ie11, adobe, firefox, 7zip, freepdf, usw

i.dR haben wir fullHD Monitore.

nwmbd

Der Oscar macht die Menschen glücklich, sieht richtig gut aus.

Das sieht ja ganz schön aufwendig aus, wo liegen wir hier preislich?

**Oscar**

Zitat von firewalldevil

i.dR haben wir fullHD Monitore.

Ich habe das gerade mal getestet.
Bei 30 Programmen muss ich das auf drei Spalten aufteilen.
Die benötigte Auflösung beträgt dann ca. 1280x600. Das würde dann die Mindestauflösung sein. Ist das ok?
Hier mal ein Beispiel-Screenshot:
InstallCheck.png

firewalldevil

Hallo Oscar,

wenn man die Abteilungen unterscheiden kann, wären evtl nur 20 notwendig bzw eine allgemeine Abfrage zu der gängigsten Software, dann müsste man nur noch abteilungsbezogen abfragen.

**Oscar**

Wie gesagt, es geht ja durchaus auch mit drei Spalten.
Solange alle eure Rechner mit Monitoren ausgestattet sind, die eine Mindestauflösung von 1280x600 haben, ist alles ok.
Dann können wir das so lassen.

Kommen wir zu den Abteilungen. Wenn ich das richtig verstehe, dann gibt es 5 Abteilungen.
Es gibt eine bestimmte Programm-Sammlung, die in allen Abteilungen installiert sein soll.
Und dann gibt es Programme, die nur in einzelnen Abteilungen installiert werden.
Ist das so korrekt?

firewalldevil

Hallo Oscar,

man kann auch 5 unterschiedliche Rechner sagen.

Ich kann sicher auch mit 5 Versionen ( Konfigs ) von der Abfrage arbeiten, das wäre für dich weniger arbeit.

**Oscar**

Das war jetzt gar nicht so viel mehr Arbeit.
Schau Dir mal die Datendatei "InstallCheck.txt" an. Dort habe ich diverse Kommentare zu deren Aufbau hinzugefügt.
Die Kommentare kannst Du ruhig drin stehen lassen und auch eigene Kommentare hinzufügen. Wichtig ist nur, dass Kommentare mit einem Semikolon beginnen.
Ich hoffe, Du verstehst den Aufbau. Ansonsten frag einfach.