USB Stick beim Einstecken mit Daten bespielen

firewalldevil

Hallo,

evtl gibt es das schon...

aber wir müssen ca. 500-1000 Sticks bespielen.

Nun suche ich ein Programm welches das kann.

Stick wird eingesteckt und es werden alles Daten aus einem definiertem Ordner auf den Stick kopiert.

Und das wenn ich bis zu 8 USB Ports mit Stick bestücke, also bei jedem einstecken eines neuen USB Stick....

Wer kann mir da behilflich sein?

Gruß

**alpines**

Das sollte nicht allzuschwierig sein. Lass dir die Sticks auflisten mit den Drive* Funktionen und dann checkst du einfach ob deine Daten schon drauf sind, wenn nicht einfach kopieren.

//Edit, nicht gesehen das es in Gegenleistung ist.

tokolosh

Ich habe ein ähnliches Programm schon geschrieben, nur dass dieser nur dann zündet wenn bestimmte Sticks/Disks eingesteckt werden (Entweder durch Name definiert oder per bestimmte Textdatei auf dem Stick).
Theoretisch könnte ich diese so anpassen dass sie immer zündet wenn eine Disk oder ein Stick eingesteckt wird. Ausserdem müsste ich noch die Mailfunktion bei Abschluss des Vorgags entfernen - denke nicht dass du 500 bis 1000 mails haben möchtest dass der Kopiervorgang abgeschlossen wurde lol.
Ausserdem, möchtest du die Dateien direkt ins Root der Sticks kopieren oder lieber in einen Unterverzeichnis? Derzeit gibt es bei meinem Programm die Möglichkeit in einen Unterverzeichnis zu kopieren (Name ist jedoch konfigurierbar)

Also Programm gibt es schon bräuchte lediglich ein paar kleine Anpassungen an deine Bedürfnisse.

**AspirinJunkie**

Die Fragestellung wurde damals folgendermaßen gelöst:

AutoIt

#include <WindowsConstants.au3>
#include <Misc.au3>


If _Singleton("USB_Kopier_Tool", 1) = 0 Or $CmdLine[0] >= 2 Then ; Slave-Prozess
	If $CmdLine[0] < 2 Then _Fehler("Fehler bei der ParameterÃ¼bergabe an Slaveskript", $CmdLineRaw, False)
	Local $s_TargetDir = $CmdLine[2]
	Local $s_SourceDir = $CmdLine[1]


	DirCopy($s_SourceDir, $s_TargetDir, 1)


	If FileExists("RemoveDrive.exe") Then Run("RemoveDrive.exe " & StringLeft($s_TargetDir, 2) & " -e -f -l", @ScriptDir, @SW_HIDE)
Else ; Master-Prozess
	Global $s_SourceDir = FileSelectFolder("Quellordner wÃ¤hlen", @ScriptDir)
	If Not FileExists($s_SourceDir) Then _Fehler("Kein korrekter Quellordner gewÃ¤hlt", $s_SourceDir)


	Global Const $DBT_DEVICEARRIVAL = 0x8000
	Global Const $DBT_DEVICEREMOVECOMPLETE = 0x8004


	Global Const $tagDEV_BROADCAST_HDR = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved"
	Global Const $tagDEV_BROADCAST_VOLUME = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved; dword dbcv_unitmask; word dbcv_flags"


	HotKeySet("^q", raus) ; mit Strg-q Programm beenden


;~ #Region ShellEvent registrieren
	Global $h_GUI = GUICreate("")
	GUIRegisterMsg($WM_DEVICECHANGE, evDeviceChange)
	#EndRegion


	; Endlosschleife
	While Sleep(10000)
	WEnd
EndIf


; Funktion die aufgerufen wird wenn ein Event auftritt:
Func evDeviceChange(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
	Switch $wParam ; was ist passiert


		Case $DBT_DEVICEARRIVAL ; Device hinzugefÃ¼gt
			Local $DEV_BROADCAST_HD = DllStructCreate($tagDEV_BROADCAST_HDR, $lParam)


			If $DEV_BROADCAST_HD.dbch_devicetype = 2 Then ; falls hinzugefÃ¼gtes Device vom Typ "Volume" ist (Laufwerk)
				Local $DEV_BROADCAST_VOLUME = DllStructCreate($tagDEV_BROADCAST_VOLUME, $lParam) ; im Falle Volume entspricht die Struktur in $lparam einer DEV_BROADCAST_VOLUME
				Local $s_VolumeChar = Chr(65 + Int(Log($DEV_BROADCAST_VOLUME.dbcv_unitmask) / Log(2))) ; der Laufwerksbuchstabe des hinzugefÃ¼gten Laufwerkes
				Local $s_Type = DriveGetType($s_VolumeChar & ":\")
				If $s_Type = "Removable" Then Run(@Compiled ? _
						_buildRunString(@ScriptFullPath, $s_SourceDir, $s_VolumeChar & ":\") : _
						_buildRunString(@AutoItExe, @ScriptFullPath, $s_SourceDir, $s_VolumeChar & ":\"))
			EndIf


		Case $DBT_DEVICEREMOVECOMPLETE ; Device entfernt
			; Vorgehen Ã¤hnlich Zweig $DBT_DEVICEARRIVAL
	EndSwitch
EndFunc   ;==>evDeviceChange




Func raus()
	Exit
EndFunc   ;==>raus


Func _buildRunString($A = "", $B = "", $C = "", $D = "", $E = "", $F = "", $G = "", $H = "", $I = "", $J = "", $K = "", $L = "", $M = "", $N = "")
	; by AspirinJunkie
	Local $s_Ret = ""
	For $I = 65 To 78
		If Eval(Chr($I)) = "" Then ExitLoop
		$s_Ret &= addQuotesIfNecessary(Eval(Chr($I))) & " "
	Next
	Return StringTrimRight($s_Ret, 1)
EndFunc   ;==>_buildRunString


Func addQuotesIfNecessary(ByRef Const $s_String, Const $s_Quote = '"')
   ; by AspirinJunkie
   If StringLeft($s_String, StringLen($s_Quote)) == $s_Quote And StringRight($s_String, StringLen($s_Quote)) == $s_Quote Then Return $s_String
    Return StringInStr($s_String, ' ', 1) ? $s_Quote & $s_String & $s_Quote : $s_String
EndFunc


Func _Fehler(Const $s_Text, $Ret = Default, Const $b_Exit = True, Const $Error = @error, Const $Extended = @extended, $ScriptLine = @ScriptLineNumber)
	#forcedef $d_SCRIPTLINEOFFSET, $d_SCRIPTLINEOFFSET_OFFSET
	; by AspirinJunkie
	Local $a_DllRet = DllCall("kernel32.dll", "dword", "GetLastError")
	Local $d_APIError = @error ? 0 : $a_DllRet[0]
	Local $a_DllRet = DllCall("Wininet.dll", 'bool', 'InternetGetLastResponseInfoW', 'dword*', 0, 'wstr', "", 'dword*', 4096)
	Local $s_InetError = @error ? 0 : $a_DllRet[1]
	Local $s_InetErrorMsg = @error ? "" : $a_DllRet[2]
	Local $a_DllRet = DllCall("kernel32.dll", "dword", "FormatMessageW", _
			"dword", 0x1100, _      ; Flags
			"ptr", 0, _             ; Source (hier unwichtig)
			"dword", $d_APIError, _ ; Error-Code
			"dword", 1031, _        ; Language-ID (per _WinAPI_MAKELANGID ermittelbar)
			"wstr*", "", _          ; Buffer fÃ¼r Ausgabestring
			"DWORD", 0, _           ; Buffersize (hier automatisch durch entsprechendes Flag)
			"ptr", 0)
	Local $s_APIMessage = @error Or $d_APIError == 0 ? "" : $a_DllRet[5]


	If IsDeclared("d_SCRIPTLINEOFFSET") Then $ScriptLine -= $d_SCRIPTLINEOFFSET + $d_SCRIPTLINEOFFSET_OFFSET


	If IsArray($Ret) Then ; falls Return-Value = Array
		Local $s_Temp = "Array"
		For $I = 1 To UBound($Ret, 0)
			$s_Temp &= "[" & UBound($Ret, $I) & "]"
		Next
		$Ret = $s_Temp
	EndIf


	Local $s_Out = '"' & $s_Text & '"' & @CRLF & @CRLF & _
			"Line: " & $ScriptLine & @CRLF & _
			"@error: " & $Error & @CRLF & _
			"@extended: " & $Extended & _
			($Ret = Default ? "" : @CRLF & "Return value: " & $Ret) & _
			($d_APIError = 0 ? "" : "API-Error: " & $d_APIError & " - " & $s_APIMessage & @CRLF) & _
			($s_InetError = 0 ? "" : "WinINet-Error: " & $s_InetError & " - " & $s_InetErrorMsg)


	MsgBox(48, "Fehler", $s_Out)
	If $b_Exit Then Exit
EndFunc   ;==>_Fehler

Alles anzeigen

Maßgabe war, dass mehrere Sticks gleichzeitig jeweils beim Einstecken beschrieben werden können (daher die Variante über Multiprocessing).
Des Weiteren sollten die Sticks nach dem Bespielvorgang automatisch ausgeworfen werden damit deren LED ausgeht und der User erkennt welcher Stick schon fertig ist. Das wurde einfach über das optionale Tool RemoveDrive bewerkstelligt.