Benötige Infomaterial für Anfänger - Bearbeiten von Textdateien

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <FileConstants.au3>


_Example()


Func _Example()


	Local $aFileText = FileReadToArray(@ScriptDir & "\Logfile.txt")
	_ArrayDisplay($aFileText, "Inhalt der Datei")
	Local $aIndex = _ArrayFindAll($aFileText, "disabled=no", 0, 0, 0, 1)
	_ArrayDisplay($aIndex, "Indizes mit Treffern")
	Local $iMaxIndex = UBound($aFileText)
	Local $iResultMax = UBound($aIndex)


	Local $aResults[$iResultMax]


	For $i = 0 To $iResultMax - 1
		If $aIndex[$i] + 2 <= $iMaxIndex Then $aResults[$i] = StringLeft($aFileText[$aIndex[$i] + 2], StringInStr($aFileText[$aIndex[$i] + 2], " radio") - 1)
	Next


	_ArrayDisplay($aResults, "Die gesuchten Textinhalte")


	Local $sString = ""




	For $i = 0 To UBound($aResults) - 1
		$sString &= "enable " & $aResults[$i] & @CRLF
	Next ; Ende des Schleifendurchlaufs


	MsgBox($MB_SYSTEMMODAL, "Die fertige Zeichenfolge", $sString)


	Local $hFileOpen = FileOpen(@ScriptDir & "\Ergebnis.txt", $FO_OVERWRITE)
	FileWrite($hFileOpen, $sString)
	FileClose($hFileOpen)


EndFunc   ;==>_Example

; Vorbemerkung: Die Variablen beginnen immer mit $. Später kommt eine vllt. aussagekräftige Bezeichnung.
; Dazwischen ist es absolut sinnvoll und hier auch angewendet, den Variablen ein/mehrere Kürzel für den Inhalt mitzugeben,
; damit dir und anderen immer sofort klar ist, ob gerade mit einem Array, einer Integer-, oder String-Variable gearbeitet wird.
; Dazu und vieles andere Sinnvolle hier: https://www.autoitscript.com/wiki/Best_coding_practices
;
; Darüber hinaus: Du kannst in SciTE auf jeden Befehl im Quellcode klicken, dann F1 drücken und landest in der Hilfe mit ausführbaren Beispielcode zu der Funktion.




#include <Array.au3> ; Für die im Skript benutzten _Array... Funktionen benötigt
#include <MsgBoxConstants.au3> ; Die verwendete MsgBox hat einen Stil. Sie taucht nur mit einem OK-Button auf. Dazu könnte man das flag 0 nutzen und braucht dieses Include nicht.
; Ich möchte hier aber die sprechendere Konstante $MB_SYSTEMMODAL verwenden und binde dazu diese au3-Datei ein, in der diese Konstanten definiert sind.
; Allgemein ist es sinnvoll in den Skripten, die in der Hilfe angegebenen Konstanten zu verwenden, statt den Zahlenwerten (, auch wenn ich das selbst nicht immer mache..).
; Sollten sich in vielleicht neu erscheinenden AutoIt-Versionen Änderungen bei den Zahlenwerten ergeben, würden Fehler auftreten, hättest du die Zahlen verwendet.


#include <FileConstants.au3> ; Für die verwendete Konstante im FileOpen-Aufruf.


_Example()


Func _Example()


	Local $aFileText = FileReadToArray(@ScriptDir & "\Logfile.txt") ; Datei wird in ein Array ($aArray) eingelesen. "@ScriptDir" ist ein AutoIt-Makro und steht für das Verzeichnis, in dem das Skript liegt.
	_ArrayDisplay($aFileText, "Inhalt der Datei") ; Inhalt wird angezeigt. WICHTIG: Hier siehst du, das die erste Zeile die Nummer Null trägt! Arrays sind nullbasiert. Das bedeutet: Anzahl der Elemente sind bspw. 9. Dann ist die letzte Elementenummer 8.
	Local $aIndex = _ArrayFindAll($aFileText, "disabled=no", 0, 0, 0, 1) ; Hier werden alle Zeilen mit "disabled=no" gesucht. Ergebnisse kommen in das Array $aIndex
	_ArrayDisplay($aIndex, "Indizes mit Treffern") ; Hier werden die Trefferzeilen angezeigt. (Es geht bei Null los. Daher ist der erste Treffer hier in Zeile bzw. Array-Index Null).
	Local $iMaxIndex = UBound($aFileText) ; Mit Ubound wird die Anzahl der Einträge (Indizes) in einem Array ermittelt. Hier vom Inhalte der Datei.
	Local $iResultMax = UBound($aIndex) ; Hier wird die Anzahl der Einträge der Trefferzeilen ermittelt.


	Local $aResults[$iResultMax] ; Hier wird ein Array erstellt, in das die Zielinhalte kommen. In den eckigen Klammern steht die Anzahl der Elemente, die das Array fassen soll.
	; In diesem Fall nutzen wir die Variable $iResultMax, die ja die Anzahl der Treffer beinhaltet.


	For $i = 0 To $iResultMax - 1 ; Hier gehen wir das Array mit den Treffern durch und verarbeiten es.


		; Ich nutze hierzu eine For .. To .. Schleife. Die Variable $i (sie existiert nur innerhalb der Schleife) nimmt in diesem Fall bei jedem Schleifendurchlauf einen um eins höheren Wert an.
		; Die Schleife startet bei 0 und endet, wenn $i den Wert $iResultMax - 1 angenommen hat.
		; $iResultMax - 1 weil $iResultMax = die Anzahl der Elemente ist. Ich beginne die Schleife aber nicht bei Eins, sondern bei Null. - Daher jede Zeile minus Eins.


		If $aIndex[$i] + 2 <= $iMaxIndex Then $aResults[$i] = StringLeft($aFileText[$aIndex[$i] + 2], StringInStr($aFileText[$aIndex[$i] + 2], " radio") - 1) ; Hier werden die Treffer ermittelt. Schritt für Schritt:
		; "If $aIndex[$i] + 2 <= $iMaxIndex Then":
		; bspw. im ersten Durchlauf in Worten (Wenn 0 + 2 kleiner oder gleich (hier) 9 dann..)
		; Wenn der Wert von Element $aIndex[$i] + 2 noch innerhalb der Größe des Arrays mit den Inhalten ist, dann (soll nur Fehler vermeiden, falls mal keine zwei Zeilen nach einem Treffer kommen)..
		; Im ersten Durchlauf ist $aIndex[$i] = $aIndex[0], im zweiten $aIndex[1] - wie in For $i = 0 To.. angegeben.
		; $aIndex[0] hat nun, wie du im zweiten _ArrayDisplay gesehen hast, den Wert Null (weil der erste Treffer mit "disabled=no" im Element Null (erstes Element) von $aFileText war).
		; Ich suche etwas zwei Zeilen darunter und sage daher immer $aIndex[$i] + 2


		; "$aResults[$i] = ":
		; Wenn die If .. Then Bedingung von oben zutrifft, dann wird das Folgende als aktuelles Element von $aResults verwendet.
		; Wieder am Beispiel vom ersten Durchlauf: $aResults[0] ist gleich.


		; StringLeft($aFileText[$aIndex[$i] + 2], StringInStr($aFileText[$aIndex[$i] + 2], " radio") - 1):
		; Hier habe ich zwei Funktionen in eine Zeile geschrieben. StringLeft und StringInStr. Schau dir zu allen Befehlen am besten auch gleich die Hilfe an. (Wort in SciTE anklicken und F1 drücken).
		; StringLeft gibt vom Text, den man reinwirft, den Text bis zum n-ten Zeichen zurück.
		; StringLeft ( "Gesamter Text", Anzahl der Zeichen von Links )
		; Als "Gesamter Text" gebe ich nun $aFileText[$aIndex[$i] + 2] an. Für den ersten Durchlauf ist das der Inhalt der Zeile (Element) 0 + 2 vom Array $aFileText. Also $aFileText[2]
		; Hier willst du ja nicht die gesamte Zeile, sondern nur einen Teil vom Anfang. Dafür benutze ich die Funktion StringInStr. (Sucht einen Suchtext in einem bestimmten Text).
		; StringInStr($aFileText[$aIndex[$i] + 2], " radio") sucht also in der angegebenen Zeile nach " radio", was ich in deinem Bsp. als eindeutigen Trenner gesehen habe.
		; Diese Funktion gibt bei Erfolg die Nummer des ersten Zeichens des Treffers zurück. Man kann das in einer Variable speichern oder direkt verwenden wie hier.
		; Das heißt, StringLeft("abcde", 2) ergibt genauso "ab" wie auch StringLeft("abcde", StringInStr("abcde", "b")), weil StringInStr("abcde", "b") gleich Zwei ist.
		; Im Skript ziehe ich "StringInStr($aFileText[$aIndex[$i] + 2], " radio")" noch Eins ab, weil du das erste Zeichen des Treffers (das Leerzeichen) ja nicht im Ergebnis haben möchtest.
		; Statt es direkt zu verwenden, hättest man die Rückgabe von StringInStr, wie geschrieben auch in einer Variable speichern können. Das ist vor Allem dann sinnvoll,
		; wenn du wiederholt auf diese Information zurückgreifen möchtest. Das könnte hier dann so aussehen:
		; Local $iCharNumber = StringInStr($aFileText[$aIndex[$i] + 2], " radio")
		; If $aIndex[$i] + 2 <= $iMaxIndex Then $aResults[$i] = StringLeft($aFileText[$aIndex[$i] + 2], $iCharNumber - 1)
	Next ; Next markiert das Ende eines Schleifendurchlaufs. Alles in der Schleife spielt sich zwischen For .. To .. und Next ab.


	_ArrayDisplay($aResults, "Die gesuchten Textinhalte") ; Der Text, der in die Textdatei soll.


	Local $sString = "" ; Hier deklariere ich eine lokale Variable, in die der Text soll.




	For $i = 0 To UBound($aResults) - 1 ; Wieder eine Schleife. Von Null bis zur Anzahl der Elemente von $aResults minus Eins (Weil wir ja nicht bei 1 beginnen sondern bei Null).


		$sString &= "enable " & $aResults[$i] & @CRLF ; Hier siehst du zwei Dinge, die mit dem Verkettungs-Operator & angestellt werden können.
		; 1. wird hier der leeren Variable $sString ($sString = "") in jedem Durchlauf neuer Inhalt ergänzt "&=".
		; Würde hier nur "=" stehen, bekäme die Variable bei jedem Durchlauf einen neuen Wert.
		; 2. werden hier ein String (Zeichenfolge "enable ") mit einer Variable $aResults[$i] (Inhalt des Array-Elementes $i)
		; und dem Makro für einen Windows-Zeilenumbruch (@CRLF) verkettet und ergeben einen zusammenhängenden Text.


	Next ; Ende des Schleifendurchlaufs


	MsgBox($MB_SYSTEMMODAL, "Die fertige Zeichenfolge", $sString) ; Hier wird eine Windows Message Box eingeblendet, die dir die Zeichenkette anzeigt, die dann in die Zieldatei geschrieben werden soll.


	Local $hFileOpen = FileOpen(@ScriptDir & "\Ergebnis.txt", $FO_OVERWRITE) ; Schreibst du häufiger in eine Datei, ist es sinnvoll,
	; die Datei mit der Funktion FileOpen zu öffnen/erstellen und mit dem handle weiter zu arbeiten.
	; Das ist deutlich schneller, weil die gleich genutzte Funktion FileWrite das sonst bei jedem Aufruf selbst macht..
	; Ich verwende das hier, damit du auf die Funktion aufmerksam wirst, weil sie bei Arbeiten mit Textdateien häufig hilft/notwendig ist (Zeichensatz usw.).
	; Bei dieser einmaligen Nutzung von FileWrite ist es eigentlich sinnlos, es sei denn du wolltest mit FileOpen sicherstellen, dass das Zielverzeichnis erstellt wird.


	FileWrite($hFileOpen, $sString) ; Hier wird schließlich die Zieldatei, die wir zuvor mit FileOpen geöffnet haben beschrieben.
	; Daher steht als erster Parameter nicht der Dateipfad, sondern das Filehandle von FileOpen.


	FileClose($hFileOpen) ; Hat man eine Datei mit FileOpen geöffnet/erstellt, muss dieser Zugriff mit FileClose wieder beendet werden.


EndFunc   ;==>_Example

;-- TIME_STAMP   2017-06-13 22:37:32   v 0.1


#Region ;************ Includes ************
#include <File.au3>
#EndRegion ;************ Includes ************


_Example()


Func _Example()
	Local $sFile = FileOpenDialog('Datei öffnen...', @ScriptDir, 'Text (*.txt;*.ini)', $FD_FILEMUSTEXIST)
	If @error Then Exit 1


	Local $aArray = FileReadToArray($sFile), $aOut[0]
	_ArrayDisplay($aArray, '$aArray')


	For $i = 0 To UBound($aArray) - 1 Step 1
		If StringInStr($aArray[$i], 'disabled=no') Then
			ConsoleWrite('$i + 2 (' & $i + 2 & ') >= UBound($aArray) (' & UBound($aArray) & ')' & @CRLF)
			If $i + 2 >= UBound($aArray) Then ExitLoop ; Es gibt keine übernächste Zeile!
			_ArrayAdd($aOut, StringMid($aArray[$i + 2], 1, StringInStr($aArray[$i + 2], ' ')))
		EndIf
	Next


	; Haben wir etwas in $aOut? Wenn ja, dann Ergebnis in Datei speichern!
	If UBound($aOut) Then
		; Inhalt von $aOut als Array anzeigen...
		_ArrayDisplay($aOut, '$aOut')


		; Inhalt von $aOut mit einer MessageBox anzeigen...
		Local $sOut = ''
		For $i = 0 To UBound($aOut) - 1
			$sOut &= 'enable ' & $aOut[$i] & @CRLF
		Next
		MsgBox(0, 'Ausgabe', $sOut)


		; Inhalt von $aOut in der Console ausgeben...
		ConsoleWrite(_ArrayToString($aOut, @CRLF) & @CRLF)


		; Ergebnis aus $aOut in Datei speichern...
		Local $sSaveResultAs = FileSaveDialog('Ausgabe in Datei speichern...', @ScriptDir, 'All (*.txt)', BitOR($FD_PATHMUSTEXIST, $FD_PROMPTOVERWRITE))
		If @error Then Exit 3 ; Keine Datei zum Speichern angegeben...
		_FileWriteFromArray($sSaveResultAs, $aOut)
	EndIf
EndFunc   ;==>_Example