[Problem] Item Reader - Daten aus 3 Dateien lesen & zuordnen

Ram3000

Hallo Leute und Profis
Ich versuche schon seit längerem ein kleines Tool zu schreiben, wo ich Daten aus 3 Dateien einlesen und zuordnen möchte.

Leider bin ich wohl zu blöd dazu und ich schaffe es einfach nicht.....voll das Brett vor dem Kopf.

Ich würde mich echt freuen, wenn mir einer dabei helfen könnte.

Vielen dank !

Hier sind auch noch die entsprechenden Dateien die man benötigt:

Download

Hier mal ein Screen, wie das zusammenhängt:

https://imgur.com/a/2l7xC

Code

#include <GUIListView.au3>
Opt("GUIOnEventMode", 1)
$hGUI=GUICreate("Item-Lister", 900, 800)
$hList = GUICtrlCreateListView("Item Code|DEFINE|Item Name|Item Text", 20, 20, 860, 650)
_GUICtrlListView_SetColumn($hList, 0, 'ITEM-ID', 60, 0)
_GUICtrlListView_SetColumn($hList, 1, 'Itenname', 240, 0)
_GUICtrlListView_SetColumn($hList, 2, 'Itenbeschreibung', 356, 0)
_GUICtrlListView_SetColumn($hList, 3, 'Define', 180, 0)
GUISetOnEvent(-3, "close")
GUISetState()
$button01 = GUICtrlCreateButton ("OPTIONS", 20, 680, 200, 50)
$button02 = GUICtrlCreateButton ("LOAD V16", 230, 680, 200, 50)
$button03 = GUICtrlCreateButton ("LOAD V19", 470, 680, 200, 50)
$button04 = GUICtrlCreateButton ("Export the List (ID | NAME)", 680, 680, 200, 50)
$itemnames         = propitemget_itemname("propItem.txt.txt")
$itemverweise     = propitemget_itemverweis("propItem.txt.txt")
$define            = propitemget_itemdefine("propItem.txt", $itemverweise)
$itemcode        = propitemget_itemcode("defineItem.h",$itemverweise)

If IsArray($itemnames) Then
    For $x = 0 To UBound($itemnames) - 1
       getcode()
         if $x < 10  Then
            GUICtrlCreateListViewItem($itemcode &"|"& $itemnames[$x] &"|"& $itemverweise[$x] &"|"& $define[$x], $hList)
         Else
         EndIf
    Next
Else

EndIf
While GUIGetMsg() <> -3
WEnd


Func propitemget_itemname($propitempath)
    Return StringRegExp(FileRead($propitempath), "IDS_PROPITEM_TXT_\w*\s([\w ()äÄöÖüÜ.]*)", 3)
EndFunc   ;==>propitemget_itemname

Func propitemget_itemverweis($propitempath)
    Return StringRegExp(FileRead($propitempath), "(IDS_PROPITEM_TXT_\w*)\s[\w ()äÄöÖüÜ.]*", 3)
EndFunc

Func propitemget_itemdefine($propitempath, $itemverweis)
    Return StringRegExp(FileRead($propitempath), "(II_[\w_]*)\s" & $itemverweis, 3)
EndFunc

Func propitemget_itemcode($propitempath, $define)
    ;Return StringRegExp(FileRead($propitempath), "(II_[\w_]*)\s" & $itemcode, 3)
EndFunc


Func getcode()
    $codeid=propitemget_itemcode("defineItem.h", $define)
    $definecode=propitemget_itemdefine("propItem.txt", $codeid)
    $itemcode=$definecode
 EndFunc

Func test()
   $ids=_GUICtrlListView_GetItemTextArray(GUICtrlGetHandle($hList), ControlListView("Test", "", "", "GetSelected"))
   $define=propitemget_itemdefine("propItem.txt", $ids[3])
   $Z=$define[0]
EndFunc




     Func close()
    Exit
 EndFunc   ;==>close

Alles anzeigen

**alpines**

Wofür willst du denn das ganze extrahieren? Für einen Bot?

Ich kann dir nur raten nicht immer die Daten parsen zu wollen, das dauert viel zu lange. Parse sie einmal vernünftig in ein Dictionary oder Array und greif dann darauf zu.

Der Index kann dir dabei als Schlüssel oder Arrayindex dienen.

(Du kannst übrigens Dateianhänge auch hier im Forum hochladen, dazu braucht man mega nicht!)

Ram3000

Hallo, nein das ist nicht für ein Bot.

Ich möchte die Liste mit dem Programm erstellen um zu prüfen ob Daten fehlen und sie dann für ein GM-Tool exportieren.

Für das GM-Tool brauche ich dann nur die ID und den Namen (ID|NAME).

Könntest Du mir evtl helfen, ich komme echt nicht weiter und ich bin auch noch nicht so fit in AutoIt...

Das mit den Dateianhängen wusste ich nicht...sorry.

**alpines**

Hier mal wie ich das ganze auf die schnelle gelöst habe, es gibt garantiert schnellere Wege, denn das Parsen dauert hin schon ziemlich lange.

Ich hab keinen effizienten Algorithmus implementiert, er sucht einfach alles von vorne bis hinten durch und braucht für jedes Item im Schnitt die Hälfte aller Einträge (miserabel, ganz zu schweigen von den RegEx-Patterns).

Mit einem Dictionary wird das ganze sicherlich schneller gehen, da die Werte gehasht indexiert werden und man nicht das gesamte Array durchsuchen muss.

Du solltest nach dem Parsen der Datenbank sie unbedingt in einem einfacheren Format speichern, damit du nicht immer alles neuparsen musst.

AutoIt

#include <Array.au3>

; ========== Database Parsing ==========

Global $aItems[0][5] ;Id, Define, IdentifierString, Name, Description

Global $sDefineItem = FileRead("defineItem.h")
Global $sPropItem = FileRead("propItem.txt")
Global $sPropItem2 = FileRead("propItem.txt.txt")

Global $aRegEx = StringRegExp($sDefineItem, "#define\s(.+?)\s+(\d+)(?:\s.+?)?\R", 3)

If Not UBound($aRegEx) Then Exit ;Database Parsing Error

ReDim $aItems[UBound($aRegEx) / 2][5]

For $i = 0 To UBound($aRegEx) - 2 Step 2
    $aItems[$i / 2][0] = $aRegEx[$i + 1]    ;Define
    $aItems[$i / 2][1] = $aRegEx[$i]        ;Id
Next

Global $aRegEx = StringRegExp($sPropItem, "\d+\s+(II_.+?)\s+(IDS_.+?)\s+\d+\s+\d", 3)

For $i = 0 To UBound($aRegEx) - 2 Step 2
    For $j = 0 To UBound($aItems) - 1
        If $aRegEx[$i] = $aItems[$j][1] Then
            $aItems[$j][2] = $aRegEx[$i + 1]    ;IdentifierString

            $aInfo = _GetItemNameAndDescription($sPropItem2, $aItems[$j][2])

            If UBound($aInfo) Then
                $aItems[$j][3] = $aInfo[0]    ;Name
                $aItems[$j][4] = $aInfo[1]    ;Description
            EndIf

            ExitLoop
        EndIf
    Next

    ConsoleWrite($i & @CRLF)
Next

_ArrayDisplay($aItems)
Exit

; ========== Database Parsing ==========

Func _GetItemNameAndDescription($sPropItem2, $sIdentifier)
    Return StringRegExp($sPropItem2, $sIdentifier & "\s(.+?)\R.+?\s(.*?)\R", 3)
EndFunc

Alles anzeigen

Ram3000

wow cool danke !

ich werde mir das mal ansehen und mal etwas damit rumspielen, ich muss es ja noch weiterverarbeiten...

ja das dauert wirklich etwas länger, aber es ist besser als alles andere was ich geschafft hatte.

ich werde das hoffentlich nicht öfters machen müssen und das ist dann auch mein nächster schrift:

ich möchte dann ja die liste genauso speichern und als kleinere Liste mit "ID | NAME".

Also 2 knöpfe zum speichern als zB .txt und das ding ist fast fertig

die daten werden leider so angelegt bzw sind vom original so schlimm...mich nerven diese daten auch...

DANKE!

**alpines**

Beim nächsten Mal Erledigt-Haken setzen nicht vergessen!

Ram3000

hehe auch das kannte ich noch nicht

**BugFix**

Also ich hab dir mal eine, wie ich finde, recht flotte Variante erstellt: Parsen und Listview befüllen < 2 Sekunden.

AutoIt

#include <GUIListView.au3>
Opt('GUIOnEventMode', 1)

Global $SF = StringFormat
Global $sPathItem = $SF('%s\defineItem.h', @ScriptDir)
Global $sPathPropItem = $SF('%s\propItem.txt', @ScriptDir)
Global $sPathPropItemTxt = $SF('%s\propItem.txt.txt', @ScriptDir)
Global $sPathResult = $SF('%s\result.txt', @ScriptDir)

#cs #STRUKTUR#

$sPathItem
#define II_WEA_AXE_RODNEY               81
........Key.............................Value

$sPathPropItem
6    II_WEA_AXE_RODNEY    IDS_PROPITEM_TXT_000124    1    1    IK1_WEAPON    IK2_.....
....Key.................Value

$sPathPropItemTxt
IDS_PROPITEM_TXT_000124    Rodney Axe
Key.....................Value @CRLF optionale Beschreibung



============# Abhängigkeiten #=================
Key[$sPathPropItem] = Key[$sPathItem] --> ID
Value[$sPathPropItem] = Key[$sPathPropItemTxt] --> TEXT

Es muss nur durch $sPathPropItem Wert für Wert iteriert werden.
Andere Werte werden einmalig in ein Dictionary gepackt und sind dann direkt abrufbar.
#ce

Global $timer = TimerInit()

Global $aItem = StringRegExp(FileRead($sPathItem), '(?<=\r\n)#define\s+([\S\T]+)\s+(\d+)', 3)
; Index 0 (+2/4/6...) = Key     II_WEA_AXE_RODNEY
; Index 1 (+2/4/6...) = Value   81
Global $oItem = ObjCreate('Scripting.Dictionary')
For $i = 0 To UBound($aItem) -2 Step 2
    $oItem.Add($aItem[$i], $aItem[$i+1]) ; ItemDefine = ID
Next

Global $aItemTxt = StringRegExp(FileRead($sPathPropItemTxt), '(\w+\d+)\s([^\r]+)\r\n\w+\d+\s([^\r]*)', 3)
; Index 0 (+3/5/7...) = Key     IDS_PROPITEM_TXT_000124
; Index 1 (+3/5/7...) = Value   Rodney Axe
; Index 2 (+3/5/7...) = Value2  [optionale Beschreibung]
Global $oItemTxt = ObjCreate('Scripting.Dictionary')
For $i = 0 To UBound($aItemTxt) -3 Step 3
    $oItemTxt.Add($aItemTxt[$i], $aItemTxt[$i+1] & '|' & $aItemTxt[$i+2])
Next

Global $aPropItem = StringRegExp(FileRead($sPathPropItem), '(?<=\r\n)\d+\t+([\w_\d]+)\t+([\S]+)\s+', 3)
; Index 0 (+2/4/6...) = Key     II_WEA_AXE_RODNEY
; Index 1 (+2/4/6...) = Value   IDS_PROPITEM_TXT_000124

; GUI
Global $sResult = ''

$hGUI=GUICreate("Item-Lister", 900, 800)
$hList = GUICtrlCreateListView("Item Code|DEFINE|Item Name|Item Text", 20, 20, 860, 650)
_GUICtrlListView_SetColumn($hList, 0, 'ITEM-ID', 60, 0) ; 2. Spalte = 470 Px breit, rechts ausgerichtet
_GUICtrlListView_SetColumn($hList, 1, 'Itenname', 240, 0) ; 2. Spalte = 470 Px breit, rechts ausgerichtet
_GUICtrlListView_SetColumn($hList, 2, 'Itenbeschreibung', 356, 0) ; 2. Spalte = 470 Px breit, rechts ausgerichtet
_GUICtrlListView_SetColumn($hList, 3, 'Define', 180, 0) ; 1. Spalte = 40 Px breit, links ausgerichtet
GUISetOnEvent(-3, "_close")

For $i = 0 To UBound($aPropItem) -2 Step 2
    ; ID | Name | Beschreibung | ItemDefine
    ; 81 | Rodney Axe | | II_WEA_AXE_RODNEY
    ; zum Ablegen in speicherbaren String
;~     $sResult &= $SF('%s|%s|%s%s', $oItem.Item($aPropItem[$i]), $oItemTxt.Item($aPropItem[$i+1]), $aPropItem[$i], @CRLF)
    ; oder direkt in Listview eintragen
    GUICtrlCreateListViewItem($SF('%s|%s|%s%s', $oItem.Item($aPropItem[$i]), $oItemTxt.Item($aPropItem[$i+1]), $aPropItem[$i]), $hList)
Next

; Schreiben in Datei
;~ FileWrite($sPathResult, $sResult)

ConsoleWrite(TimerDiff($timer)/1000 & @CRLF)
GUISetState()

While True
    Sleep(50)
WEnd

Func _close()
    Exit
EndFunc

Alles anzeigen

**alpines**

Ich sags doch, Dictionaries eignen sich hier hervorragend. Wenn man aber im Nachhinein die Dateien sowieso in einem einfacheren Format ohne Zusatzinformationen speichert, sind die paar Sekunden glaube ich im Nachhinein auch egal. Trotzdem schönes Beispiel!

Ram3000

BugFix :

WOW Dickes Danke ! Das sieht sehr gut aus.
Aber kann es sein das das FileWrite nichts macht? Bei mir wir keine Datei erstellt...?!

**alpines**

Zitat von Ram3000

Aber kann es sein das das FileWrite nichts macht? Bei mir wir keine Datei erstellt...?!

Ist ja auch auskommentiert.

**Musashi**

Hallo Ram3000 !

Zitat von Ram3000

Aber kann es sein das das FileWrite nichts macht? Bei mir wir keine Datei erstellt...?!

Ich habe den Code jetzt nicht getestet, aber :

Zitat von BugFix

; Schreiben in Datei
;~ FileWrite($sPathResult, $sResult)

Der Befehl FileWrite ist im Beispiel von BugFix auskommentiert ! Entferne mal das ;~ und schaue was dann passiert.

Gruß Musashi

**BugFix**

Zitat von Ram3000

Aber kann es sein das das FileWrite nichts macht? Bei mir wir keine Datei erstellt...?!

Wie bereits gesagt wurde, ist dieser Teil auskommentiert. D.h., du musst auch in der Schleife den Teil

;~ $sResult &= $SF('%s|%s|%s%s', $oItem.Item($aPropItem[$i]), $oItemTxt.Item($aPropItem[$i+1]), $aPropItem[$i], @CRLF)

wieder aktivieren.

Ram3000

Hey, ich habe das schon versucht und habe es aktiviert, aber ohne erfolg

Code

$sResult &= $SF('%s|%s|%s%s', $oItem.Item($aPropItem[$i]), $oItemTxt.Item($aPropItem[$i+1]), $aPropItem[$i], @CRLF)
    ; oder direkt in Listview eintragen
    GUICtrlCreateListViewItem($SF('%s|%s|%s%s', $oItem.Item($aPropItem[$i]), $oItemTxt.Item($aPropItem[$i+1]), $aPropItem[$i]), $hList)
Next
; Schreiben in Datei
 FileWrite($sPathResult, $sResult)
ConsoleWrite(TimerDiff($timer)/1000 & @CRLF)

**Musashi**

Hallo Ram3000 !

Zitat von alpines

Du kannst übrigens Dateianhänge auch hier im Forum hochladen, dazu braucht man mega nicht!

Könntest Du die Dateien mal hochladen ! Die Seite wird von meinem Script-Plugin komplett gesperrt. Da ich nicht gerade ein Fan von mega.nz bin, habe ich auch keine Lust diesbzgl. etwas freizugeben

Gruß Musashi

**alpines**

Zitat von Musashi

Könntest Du die Dateien mal hochladen !

Bitte sehr.

**Musashi**

Hallo Ram3000 !

1. Wenn ich folgendes ausführe :

; Schreiben in Datei (Original von BugFix)

ConsoleWrite("Path=" & $sPathResult & @CRLF) ; nur zur Consolenanzeige eingefügt

FileWrite($sPathResult, $sResult)

zeigt die Konsole :

Path=C:\BS_AutoIt\Projekte\Testprogramme

esult.txt

Es wird keine Datei angelegt !

2. Wenn ich den Pfad direkt setze, also :

$sPathResult = @ScriptDir & "\result.txt"

ConsoleWrite("Path=" & $sPathResult & @CRLF)

FileWrite($sPathResult, $sResult)

zeigt die Konsole :

Path=C:\BS_AutoIt\Projekte\Testprogramme\Result.txt

Die Datei ist vorhanden !

Gruß Musashi

**BugFix**

Ich schau noch mal drauf, habe auch gerade festgestellt, dass in der *txt.txt an einigen Stellen kein Leerzeichen am Ende der Zeile ist und somit mein Pattern falsch greift.

EDIT

Ich hatte nicht bedacht, dass StringFormat auch \r \n \t direkt umsetzt. Hier '%s\result.txt' dann logischerweise ein Zeilenumbruch, muss also maskiert werden: '%s\\result.txt'

EDIT_2

Deine Datei propItem.txt.txt ist unvollständig! Da kann ich mir 'nen Wolf probieren - so ist sie nicht auslesbar.

Das Muster, was auch anfangs stimmt:

TEXT_NR_GERADE = Text

TEXT_NR_UNGERADE = optionale Beschreibung

Nur ist die Datei nachher unvollständig und es sind z.T. nur Zeilen mit Beschreibung hintereinander, Bsp.

IDS_PROPITEM_TXT_006079 (Questitem)

IDS_PROPITEM_TXT_006081 (Questitem)

IDS_PROPITEM_TXT_006083 (Questitem)

IDS_PROPITEM_TXT_006085 (Questitem)

Frage:

- Wo sind die Texte für IDS_PROPITEM_TXT_006080 / --82 / --84 etc.?

- Sollen diese leeren Beschreibungen aussen vor bleiben?

Ram3000

Musashi: Danke für die Hilfe.

BugFix :

Edit1:

Danke für den Edit. Jetzt schreibt das Script die Datei mit Inhalt.

Edit2:

Diese Datei ist original so wie sie ist, dort habe ich noch nichts geändert.

Es gibt nicht immer zwangsläufig eine Beschreibung, die Programmierer meinen es sei nicht nötig und so haben nicht alle Einträge eine Beschreibung, leider.

Normalerweise ist 'sollte' es so sein:

IDS_PROPITEM_TXT_000004 Itemname

IDS_PROPITEM_TXT_000005 Itembeschreibung, ob nötig oder nicht

IDS_PROPITEM_TXT_000006 Itemname

IDS_PROPITEM_TXT_000007 Itembeschreibung, ob nötig oder nicht

Manchmal haben die einfach nur einen Itemname hinterlegt, ohne Beschreibung.

IDS_PROPITEM_TXT_000008 Itemname

IDS_PROPITEM_TXT_000009 Itemname

Und manchmal machen die auch einfach riesen Sprünge.

IDS_PROPITEM_TXT_001008 Itemname

IDS_PROPITEM_TXT_002001 Itemname

Die fehlenden Texte sind vom original schon so und sollten als leerzeichen ' ' gesetzt werden, dann kann ich sehen wo etwas fehlt.

Kleine Frage zum FileWrite: Wie kann ich es machen, das die result.txt immer neu gefüllt wird? Jetzt schreibt das Script immer weiter in die Datei, dann ist alles mehrfach in der Datei.

Ich danke Dir schon einmal für deine Mühe !!!

**BugFix**

Zitat von Ram3000

Und manchmal machen die auch einfach riesen Sprünge.

IDS_PROPITEM_TXT_001008 Itemname

IDS_PROPITEM_TXT_002001 Itemname

Das ist natürlich eine schwache Kür. Somit kann man nämlich die Itemnamen nicht von den optionalen Beschreibungen unterscheiden. Und da ist es völlig egal, ob man das mit RegEx auswertet oder Zeile für Zeile. Es gibt einfach keinen Unterschied zwischen Namen und Beschreibungen - beides ist Text und die Identifier unterscheiden sich nur an einer fortlaufenden Zahl.

Zitat von Ram3000

Kleine Frage zum FileWrite: Wie kann ich es machen, das die result.txt immer neu gefüllt wird? Jetzt schreibt das Script immer weiter in die Datei, dann ist alles mehrfach in der Datei.

Zwei Möglichkeiten.

1. Wenn Datei bereits besteht: Löschen und dann neu erstellen - Oder:

2. Datei im Überschreibmodus öffnen

$fH = FileOpen(DATEIPFAD, 2+8) ; overwrite+create_folderstruct

Filewrite($fH, INHALT)

FileClose($fH)