HTML Code beim Kopieren und abspeichern übernehmen

Slider99

Hallo ich habe mal eine Frage. Wenn ich einen Text mit Bild auf einer Homepage makiere und dann mit Autoit abspeichere, dann wird der HTML Code nicht mit abgespeichert. Wenn ich aber das ganze beispielhaft in den Woltlab Blog 3.0 hineinkopiere dann wird die Seitenstruktur von der Homepage mit übernommen. Wie kann man mit Autoit veranlassen, dass der HTML Code mit übernommen wird. Viele Grüße Tom

Code

; ********************************************** Titel eingeben **********************
MsgBox(262144, "Titel eingeben", "")

$bak = ClipGet()
;~ MsgBox(0, "Zwischenablage enthält:", $bak)

$file = FileOpen("Titel_" & $a & ".txt", 2)

; Prüfen, ob Datei im Schreibmodus geöffnet ist
If $file = -1 Then
MsgBox(0, "Fehler", "Die Datei konnte nicht geöffnet werden.")
Exit
EndIf


FileWrite($file, $baK & @CRLF)


FileClose($file)

Alles anzeigen

Lottich

Ich glaube nicht, dass .txt das richtige Dateiformat dafür ist. Soweit mir bekannt ist, können keine Bilder als solche in eine .txt dargestellt werden. Versuchs mal mit .rtf

Kann gut sein, dass es damit funktioniert.

Slider99

Danke für die Info. Ich werde es ausprobieren und melde mich wieder

Schade, hat mit RTF leider nicht funktioniert
wenn ich zum Beispiel hier einen kopierten Link einfüge, dann wird der HTML Code
übernommen. Wenn ich es mit Autoit abspeicher dann nicht

Slider99

Ich habe als Beispiel irgend etwas von einer Homepage kopiert und hier eingefügt, so sieht man Text und ein Bild, als Beispiel

Sorten sind empfehlenswert [Blockierte Grafik: https://www.mein-schoener-garten.de/sites/default/files/styles/square_s/public/rosen-einpflanzen-3176820-blp-msg.jpg?itok=w0Mnuwcu] Ziergärten

Rosen richtig pflanzen

**Musashi**

Hallo Slider99 !

Das u.a. Skript stammt nicht von mir, sondern die Ehre gebührt dem User 'Mat' aus dem englischen Forum, siehe Thread :

https://www.autoitscript.com/forum/topic/13…-from-web-page/

AutoIt

#include <ClipBoard.au3>

If (Not _ClipBoard_Open(0)) Then
    ConsoleWriteError("_ClipBoard_Open failed" & @LF)
Else
    Local $sData = _Clipboard_GetHTML()
    Switch @error
        Case 1
            ConsoleWriteError("Could not register CF_HTML format" & @LF)
        Case 2
            ConsoleWriteError("Clipboard data not available in HTML format" & @LF)
        Case 3
            ConsoleWriteError("Invalid HTML format header (missing end or start fragment)" & @LF)
        Case 0
            ConsoleWrite($sData & @LF)
    EndSwitch
EndIf

_ClipBoard_Close()

; #FUNCTION# ====================================================================================================================
; Name ..........: _Clipboard_GetHTML
; Description ...: Retrieves the data from the clipboard in HTML format
; Syntax ........: _Clipboard_GetHTML( )
; Parameters ....: None
; Return values .: Success: Returns the data from the clipbard as html.
;                  Failure: Returns an empty string and sets @error:
;                           | 1 - Could not register CF_HTML format
;                           | 2 - Clipboard data not available in HTML format
;                           | 3 - Invalid HTML format header (missing end or start fragment)
; Author ........: Matt Diesel (Mat)
; Modified ......:
; Remarks .......: This assumes that the clipboard is already open. The _Clipboard_Open function should be called first.
; Related .......:
; Link ..........:
; Example .......: Above.
; ===============================================================================================================================
Func _Clipboard_GetHTML()
    Local $CF_HTML, $pHTML, $tHeader, $asHeader, $asLine, $iStartFragment = -1, $iEndFragment = -1

    ; Register the CF_HTML format
    $CF_HTML = _ClipBoard_RegisterFormat("HTML Format")

    If (Not $CF_HTML) Then Return SetError(1, 0, "") ; Could not register CF_HTML format
    If (Not _ClipBoard_IsFormatAvailable($CF_HTML)) Then Return SetError(2, 0, "") ; Clipboard data not available in HTML format

    $pHTML = _ClipBoard_GetDataEx($CF_HTML)

    $tHeader = DllStructCreate("char t[104]", $pHTML)
    $asHeader = StringSplit(DllStructGetData($tHeader, "t"), @CRLF, 1)

    ; Find start and end of fragment from header.
    For $i = 1 To $asHeader[0]
        $asLine = StringSplit($asHeader[$i], ":")

        Switch $asLine[1]
            Case "StartFragment"
                $iStartFragment = Int($asLine[2])
            Case "EndFragment"
                $iEndFragment = Int($asLine[2])
        EndSwitch
    Next

    If (($iEndFragment < 0) Or ($iStartFragment < 0)) Then Return SetError(3, 0, "") ; Invalid HTML format header (missing end or start fragment)

    $tHeader = DllStructCreate("char t[" & $iEndFragment - $iStartFragment  & "]", $pHTML + $iStartFragment)
    Return DllStructGetData($tHeader, "t")
EndFunc   ;==>_Clipboard_GetHTML

Alles anzeigen

Markiert und kopiert man z.B. den linken Avatarbereich deines Startbeitrages in das Clipboard, dann erfolgt als Rückgabe :

HTML

<aside class="messageSidebar member" itemprop="author" itemscope="" itemtype="http://schema.org/Person">
    <div class="messageAuthor">
        
        
                                
                            <div class="userAvatar">
                    <a href="https://autoit.de/wcf/index.php?user/204052-slider99/"><img src="https://autoit.de/wcf/images/avatars/avatar-default.svg" style="width: 128px; height: 128px" alt="" class="userAvatarImage"></a>
                    
                                    </div>
                        
            <div class="messageAuthorContainer">
                <a href="https://autoit.de/wcf/index.php?user/204052-slider99/" class="username userLink" data-user-id="204052" itemprop="url" id="wcf2" data-cache-id="com.woltlab.wcf.user-204052">
                    <span itemprop="name"><span style="color:#6e6e6e;"><strong>Slider99</strong> </span></span>
                </a>
                                
                
            </div>
            
                                                <div class="userTitle">
                        <span class="badge userTitleBadge">SchÃ¼ler</span>
                    </div>
                                                        </div>
    
    
    
                        <div class="userCredits">
                <dl class="plain dataList">
                    <dt><a href="https://autoit.de/index.php?user-post-list/204052-slider99/" class="" data-tooltip="BeitrÃ¤ge von Slider99">BeitrÃ¤ge</a></dt>
    <dd>59</dd>
                </dl>
            </div>
        
        
    
</aside>

Alles anzeigen

Diese Rückgabe wird hier, sofern kein Error (Case 0) auftritt, in die Konsole geschrieben (Du kannst sie aber natürlich auch speichern).

Eine fertige Lösung ist es nicht, aber ggf. führt es Dich in die gewünschte Richtung

Gruß Musashi

Slider99

Danke Musashi

ich werde jetzt ein bisschen experimentieren. Du hast mir schon mal weitergeholfen.