Scriptabbruch bei Linksklick/Rechtsklick

Impstar

Hi Leute,

ich würde gerne ein Script beenden sobald die linke oder rechte Maustaste gedrückt (1 Klick, nicht dauerhaft) wird.

Mein Script läuft in einer einfachen Endlosschleife und soll erstmal nichts anderes machen als alle 5 Sekunden ein "a" und einen Zeilenumbruch in eine Worddatei (Dokument1) zu schreiben.

Später ist es dazu da um in einem anderem Programm alle paar Sekunden andere Optionen aufzurufen, aber das bekomme ich hin.

Bisher habe ich folgenden Code zusammengesetzt, der aber nicht wirklich funktioniert:

#include <Constants.au3>

#include <AutoItConstants.au3>

#Include <Misc.au3>

func kill()

Exit

Endfunc

WinActivate("Dokument1")

Sleep( 100 )

If _IsPressed(01) then kill()

Do

Send("{a}")

Send("{Enter}")

Sleep( 5000 )

Until 1=2

Ich hab auch mal ausprobiert "If _IsPressed(01) then kill()" durch "Hotkeyset("MouseClick("left")","kill")" zu ersetzen, aber das klappt auch nicht.

Kann mir jemand helfen?

Vielen Dank im Voraus

**alpines**

Du fragst die Maustaste nur einmal ab, dabei müsste die If-Abfrage eigentlich in der Do-Schleife stehen.

Impstar

zunächst einmal danke für deine Antwort, aber:

Dann muss ich die Maustaste gedrückt halten bis wieder eine Abfrage stattfindet, in diesem Fall bis zu 5 Sekunden.

Klar, ich kann ne weitere Schleife in die Schleife bauen und die Intervalle sehr kurz gestalten, aber gibt es nicht vielleicht eine Möglichkeit die Maustaste als Hotkey zu deklarieren?

**alpines**

Nein, die gibt es nicht. Mit HotKeySet kannst du nur Tasten belegen.

Was hindert dich daran einfach 10ms zu sleepen und zu prüfen ob die Taste gedrückt wurde? Du zählst dann nebenbei mit wie oft du die Schleife durchlaufen bist um zu gucken ob es 5 Sekunden waren.

Impstar

Sieht bei mir jetzt so aus:

#include <Constants.au3>

#include <AutoItConstants.au3>

#Include <Misc.au3>

func kill()

Exit

Endfunc

WinActivate("Dokument1")

Sleep( 100 )

Do

Send("{a}")

Send("{Enter}")

Local $i = 0

Do

$i = $i + 1

Sleep( 10 )

If _IsPressed(01) then kill()

Until $i = 500

Until 1 = 2

Schade dass das mit den Hotkeys nicht geht, aber es funktioniert, das ist die Hauptsache.

Lieben Dank

**BugFix**

Zitat von Impstar

aber gibt es nicht vielleicht eine Möglichkeit die Maustaste als Hotkey zu deklarieren?

Zitat von alpines

Nein, die gibt es nicht. Mit HotKeySet kannst du nur Tasten belegen.

Was die Funktion HotKeySet selbst betrifft, hat alpines völlig recht. Aber es gibt schon Möglichkeiten, auf Mausaktionen zu reagieren und dabei die eigentliche Mausaktion zu verwerfen. Sowas muss man dann an ein Fenster koppeln um sich nicht sein System lahm zu legen.

Hier ein nicht kpl. Bsp., es sind keine Aktionen definiert, kein Aktionsfenster festgelegt. Aber wenn du keinen Plan hast, was dort passiert, lass lieber die Finger von.

Spoiler anzeigen

AutoIt

#cs  WICHTIG!!!
In der Funktion "_MouseProcedure" darf nicht verweilt werden, d.h. MsgBox oder _ArrayDisplay sind absolut tabu!
Auch dürfen keine zeitintensiven Funktionen aufgerufen werden. Andere Aktionen über Globale Variablen oder AdlibRegister starten.
Die Funktion darf niemals mit einfachem Return verlassen werden, sondern ausschliesslich mit "Return _WinAPI_CallNextHookEx".
Es ist zwingend ein Aktionsfenster zuzuordnen, keinesfalls darf das Skript systemweit verwendet werden.
Überlege gründlich, welche Mausaktion genutzt werden soll, denn diese geht für das System verloren (innerhalb des Aktionsfensters)
und wird ausschliesslich von diesem Skript genutzt. 
#ce

#include <WinAPI.au3>
#include <WindowsConstants.au3>
OnAutoItExitRegister('OnAutoItExit')

HotKeySet('^+q', '_Exit')  ; Strg+Shift+Q   -- nur um dieses Bsp. beenden zu können

Global Const $HC_ACTION = 0
Global $hStub_MouseProc = DllCallbackRegister("_MouseProcedure", "long", "int;wparam;lparam")
Global $hmod = _WinAPI_GetModuleHandle(0)
Global $hHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, DllCallbackGetPtr($hStub_MouseProc), $hmod)

Global $sTitleActionWindow = 'Der Titel des Fensters, in dem der Maus-Hotkey gültig sein soll'

While True
    Sleep(50)
WEnd

Func _MouseProcedure($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    If WinGetTitle('[ACTIVE]') <> $sTitleActionWindow Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)

    Local $info = DllStructCreate("int X;int Y;dword mouseData;dword flags;dword time;ulong_ptr dwExtraInfo", $lParam)
    Local $iX = DllStructGetData($info, 1)
    Local $iY = DllStructGetData($info, 2)    
    Local $mouseData = DllStructGetData($info, 3)
    
    ; Hier wäre noch sinnvoll zu prüfen, ob $iX und $iY innerhalb des Aktionsfensters sind 
    ; --> wenn nicht: Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)

    If $nCode = $HC_ACTION Then
        Switch $wParam
            Case $WM_MOUSEMOVE
                ; Reagieren auf Mausbewegung  (sollte man nicht verwenden, dann bleibt die Maus auf der Stelle stehen!)
            Case $WM_MOUSEWHEEL
                If _WinAPI_HiWord($mouseData) > 0 Then
                    ; Reagieren auf Mausrad vorwärts
                Else
                    ; Reagieren auf Mausrad rückwärts
                EndIf
            Case $WM_LBUTTONDOWN
                ; Reagieren auf linken Mausbutton drücken
            Case $WM_LBUTTONUP
                ; Reagieren auf linken Mausbutton lösen
            Case $WM_RBUTTONDOWN
                ; Reagieren auf rechten Mausbutton drücken
            Case $WM_RBUTTONUP
                ; Reagieren auf rechten Mausbutton lösen
            Case $WM_MBUTTONDOWN
                ; Reagieren auf mittleren Mausbutton drücken (Mausrad)
            Case $WM_MBUTTONUP
                ; Reagieren auf mittleren Mausbutton lösen (Mausrad)
        EndSwitch
    EndIf
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc

Func _Exit()
    Exit
EndFunc

Func OnAutoItExit()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hStub_MouseProc)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

**Kanashius**

Falls du nur auf nen Mausklick reagieren willst, aber nicht blockieren, bietet sich noch _isPressed() an :).

Dabei spielt das Fenster keine Rolle.

**alpines**

Zitat von Impstar

If _IsPressed(01) then kill()

Zitat von Kanashius

Falls du nur auf nen Mausklick reagieren willst, aber nicht blockieren, bietet sich noch _isPressed() an :).

???