Scrollbalken

**Tweaky**

Hi,

ich habe 2 Fragen zu Scrollbalken.

Ich würde es gerne so einstellen, dass alle Controls im scrollbaren Bereich liegen.

Bei der folgenden Beispiel muss ich "

Code

_GUIScrollBars_Init($hGui, 1, 63)

angeben. Jedoch musste ich die Zahl 63 ausprobieren. Gibt es hier eine logische Erklärung für diesen Wert?

Ist es möglich innerhalb der GUI zu scrollen?

Spoiler anzeigen

AutoIt

#Region    ;************ Includes ************
#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>
#EndRegion ;************ Includes ************


Local $hGuiMsg, $hGui

$hGui = GUICreate("ScrollBar: Beispiel", 400, 400, -1, -1) ;, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
For $i = 1 To 20
    GUICtrlCreateButton("Test" & $i, 10, 10 + 50 * $i)
    ConsoleWrite(10 + 50 * $i & @CRLF)
Next


GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_SIZE, "WM_SIZE") ; Fenstergröße ändern
GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL") ; Vertikales Scrollen

_GUIScrollBars_Init($hGui, 1, 63) ;<<< warum gerade 63???
_GUIScrollBars_EnableScrollBar($hGui, $SB_VERT)
While 1
    $hGuiMsg = GUIGetMsg()

    Switch $hGuiMsg
        Case $GUI_EVENT_CLOSE ;, $nExititem
            ExitLoop
    EndSwitch
WEnd



; Fenstergröße wurde geändert
Func WM_SIZE($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam
    Local $iIndex = -1, $iCharY, $iCharX, $iClientXMax, $iClientX, $iClientY, $ivMax
    For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
        If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
            $iIndex = $x
            $iClientXMax = $__g_aSB_WindowInfo[$iIndex][1]
            $iCharX = $__g_aSB_WindowInfo[$iIndex][2]
            $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
            $ivMax = $__g_aSB_WindowInfo[$iIndex][7]
            ExitLoop
        EndIf
    Next
    If $iIndex = -1 Then Return 0

    Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)

    ; Ermittelt die Abmessungen der Arbeitsfläche.
    $iClientX = BitAND($lParam, 0x0000FFFF)
    $iClientY = BitShift($lParam, 16)
    $__g_aSB_WindowInfo[$iIndex][4] = $iClientX
    $__g_aSB_WindowInfo[$iIndex][5] = $iClientY

    ; Setzt den vertikalen Scrollbereich und die Seitengröße
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $ivMax)
    DllStructSetData($tSCROLLINFO, "nPage", $iClientY / $iCharY)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)

    ; Setzt den horizontalen Scrollbereich und die Seitengröße
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", 2 + $iClientXMax / $iCharX)
    DllStructSetData($tSCROLLINFO, "nPage", $iClientX / $iCharX)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

; Horizontales Scrollen
Func WM_HSCROLL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $lParam
    Local $iScrollCode = BitAND($wParam, 0x0000FFFF)

    Local $iIndex = -1, $iCharX, $iPosX
    Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

    For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
        If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
            $iIndex = $x
            $iCharX = $__g_aSB_WindowInfo[$iIndex][2]
            ExitLoop
        EndIf
    Next
    If $iIndex = -1 Then Return 0

    ; Ermittelt alle Informationen der horizontalen Scrollbar
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosX = DllStructGetData($tSCROLLINFO, "nPos")
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    ; Speichert die x-Position für einen späteren Vergleich
    $iPos = $iPosX
    #forceref $iMin, $iMax
    ; Auswertung der vom System gemeldeten Scroll-Nachricht
    Switch $iScrollCode
        Case $SB_LINELEFT ; Der Anwender klickte auf den linken Pfeil
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)

        Case $SB_LINERIGHT ; Der Anwender klickte auf den rechten Pfeil
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)

        Case $SB_PAGELEFT ; Der Anwender klickte links neben dem Scrollbalken
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)

        Case $SB_PAGERIGHT ; Der Anwender klickte rechts neben dem Scrollbalken
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)

        Case $SB_THUMBTRACK ; Der Anwender zog den Scrollbalken
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch

;~    // Setzt die neue Position und ermittelt sie danach erneut.
;~    // Abhängig von den Windows-Einstellungen kann es sein, dass die gelesenen Werte nicht die gleichen sind, wie die vorher gesetzten.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    ; // Falls sich die x-Position der Scrollbar geändert hat, den Fensterbereich verschieben und aktualisieren
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($iPos <> $iPosX) Then _GUIScrollBars_ScrollWindow($hWnd, $iCharX * ($iPosX - $iPos), 0)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL

; Vertikales Scrollen
Func WM_VSCROLL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
    Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
    Local $iIndex = -1, $iCharY, $iPosY
    Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

    For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
        If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
            $iIndex = $x
            $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
            ExitLoop
        EndIf
    Next
    If $iIndex = -1 Then Return 0

    ; Ermittelt alle Informationen der vertikalen Scrollbar
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosY = DllStructGetData($tSCROLLINFO, "nPos")
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    ; Speichert die y-Position für einen späteren Vergleich
    $iPos = $iPosY

    ; Auswertung der vom System gemeldeten Scroll-Nachricht
    Switch $iScrollCode
        Case $SB_TOP ; Der Anwender klickte auf die "Pos1"-Taste
            DllStructSetData($tSCROLLINFO, "nPos", $iMin)

        Case $SB_BOTTOM ; Der Anwender klickte auf die "Ende"-Taste
            DllStructSetData($tSCROLLINFO, "nPos", $iMax)

        Case $SB_LINEUP ; Der Anwender klickte auf den oberen Pfeil
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)

        Case $SB_LINEDOWN ; Der Anwender klickte auf den unteren Pfeil
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)

        Case $SB_PAGEUP ; Der Anwender klickte oberhalb des Scrollbalkens
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)

        Case $SB_PAGEDOWN ; Der Anwender klickte unterhalb des Scrollbalkens
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)

        Case $SB_THUMBTRACK ; Der Anwender zog den Scrollbalken
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch

;~    // Setzt die neue Position und ermittelt sie danach erneut.
;~    // Abhängig von den Windows-Einstellungen kann es sein, dass die gelesenen Werte nicht die gleichen sind, wie die vorher gesetzten.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    ; // Falls sich die y-Position der Scrollbar geändert hat, den Fensterbereich verschieben und aktualisieren
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($iPos <> $iPosY) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
        $iPosY = $iPos
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Alles anzeigen

**Tweaky**

push

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Naja, es muss nicht 63 sein! Sofern ich Deine Frage richtig verstehe geht es auch mit 100 oder 200 nur scrollst Du dann weiter runter, da der slider kleiner ist. Der Wert steuert die Länge des Sliders. Wenn Dein Fenster, so klein ist, dass der Slider keinen Platz zum bewegen hat --> nix scrollen. Bei 63 ist der Slider eben gerade so groß, dass er im Verhältniss zur Länge des "Scrollfeldes" das ganze ~~genau~~ bis an die untere Fenstergrenze scrollt.

Also wohl ein Zussamenhang von:

Wie groß müsste Dein Fenster sein um alle Buttens aufeinmal darzustellen, wie groß ist Dein Fenster tatsächlich, und wie groß darf nun der Slider sein, damit er sich in Deinem realen Fenster soweit bewegt, dass die gescrollte Entfernung = der theorethischen Maximallänge des Fensters ist. 63, 64 65 je nachdem wie genau Du das haben willst

Oder so ähnlich

Gruß

Peter

**Tweaky**

Jemand eine Ahnung wie ich mit der Maus scrollen kann?

**alpines**

Zitat von Tweaky

Jemand eine Ahnung wie ich mit der Maus scrollen kann?

Wenn die ScrollBars-UDF das nativ nicht unterstützt dann registriere doch die entsprechenden WM_* Nachrichten (müsste WM_MOUSEWHEEL sein)

und frage in deiner registrierten Funktionen die übergebenen Wörter ab und scrolle mit den eingebauten Funktionen oder sende das entsprechende Event an die ScrollBars-UDF (sofern diese die WM_VSCROLL-Events oder ähnliches unterstützt).

**Bitnugger**

Wie es der Zufall will, habe zwei UDFs inkl. Demo... eine ist, soweit ich es ersehen kann, von Oscar , die andere von @Großvater ... beide mit WM_MOUSEWHEEL.

Oscar : https://www.autoit.de/index.php?page…1092#post161092

Der Link ^ ^ ist leider tot... dafür tut es der aber...

Standard GUI Scrollbar machen

oder hier...

MouseWheel auswerten

@Großvater: GUIScroll-UDF - scrollbare GUIs

**Tweaky**

Danke für die Tipps.

Mittlerweile habe ich eine andere UDF gefunden, mit der man mit einem Befehl das ganze hinzufügt (inklusive scrollen).

Es ist diese UDF

https://www.autoitscript.com/forum/topic/11…sion-16-feb-17/

Die UDF befindet sich im 1. Post ganz unten.

Nun gibt es nur noch 1 Problem.

Wenn in einer ComboBox gescrollt wird, so kann die GUI nicht gescrollt werden.

Erst wenn ein anderer Button angeklickt wird geht dies.

Ist es möglich, dass man auf die Scrollbalken oder in die GUI klickt und dass dann die ComboBox den Fokus verliert?

Spoiler anzeigen

AutoIt

#Region ;************ Includes ************
#include <GUIScrollbars_Ex.au3>
#EndRegion ;************ Includes ************

Local $hGui = GUICreate("Example", 300, 200)

Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185, 20)
GUICtrlCreateButton("zum scrollen klicken", 150, 170)
GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")

GUISetState(@SW_SHOW, $hGui)

_GUIScrollbars_Generate($hGui, 0, 300, 0, 0, False, 7)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Alles anzeigen

**alpines**

Registrier doch ein Klickevent oder pach ein großes unsichtbares Label hinter allen Controls, welches bei Click ControlFocus ausführt.

**Bitnugger**

Zitat von Tweaky

Nun gibt es nur noch 1 Problem.

Wenn in einer ComboBox gescrollt wird, so kann die GUI nicht gescrollt werden.

Erst wenn ein anderer Button angeklickt wird geht dies.

Also bei mir kann ich scrollen, sobald die Maus nicht über einem Control steht... egal, was ich mit dem Combo mache... und es ist auch völlig egal, welches Control den Fokus hat.

Du musst also nur die Maus zu einer Stelle bewegen, wo kein Control ist... dann kannst du die GUI scrollen... und dabei verliert das Combo nicht mal den Fokus.

**Tweaky**

Hast du das Beispiel in Post 7 verwendet?

**Bitnugger**

Zitat von Tweaky

Hast du das Beispiel in Post 7 verwendet?

Ja.

**Tweaky**

Also ich kann die GUI nur scrollen wenn ich zuvor auf den Button in der GUI geklickt habe.

Bei mir wird die ComboBox gescrollt.

Tuxedo

Es verhält sich bei mir ebenso wie bei Tweaky , sprich scrollen ist erst nach Drücken auf den

Button möglich. Vielleicht hat Bitnugger einen speziellen Maustreiber der das steuert oder.

**Bitnugger**

Zitat von Tuxedo

Vielleicht hat Bitnugger einen speziellen Maustreiber der das steuert

Ja, das gut möglich sein... ich habe eine Logitech Wireless Mouse M560 und der Treiber setzt dann evtl. automatisch den Fokus auf das unter dem Mauszeiger befindliche Control.

Auf meinem Mini-Server mit Windows 7 und Standard-Maustreiber von Microsoft verhält es sich bei mir auch so und es hilft auch nicht, den Fokus auf ein anderes Control zu setzen.

Dass es bei mir funktioniert, kann aber auch daran liegen, dass ich auf meinem großen PC Windows 10 fahre...

fakeraol

Dann also bei jedem WM_MOUSEWHEEL Event die Maus-Position über der GUI abfragen und mit dem ComboBox-Control abgleichen. Und dann entweder Control scrollen, oder GUI.