Text in ein Fenster einfügen mit $WM_SETTEXT nicht möglich?

**BugFix**

Kennt sicher jeder: Im Internet ein paar Angebote suchen, rauskopieren und zusammenstellen in einem eigenen Dokument.

Copy & Paste übernimmt dann leider die Formatierung inkl. Tabelle etc., sodass man dann nachbearbeiten muss.

Deshalb hatte ich mir jetzt eine Funktion erstellt, die den Inhalt der Zwischenablage als Nur-Text ausliest und an der Mausposition im aktuell geöffneten Fenster einfügt.

Send() möchte ich auf jeden Fall vermeiden und hatte deshalb mit _SendMessage(HWnd, $WM_SETTEXT, ... ) probiert. Obwohl das Child-Window erkannt wird, an das die Nachricht gesendet wird, läßt sich kein Text einfügen. Fehler gibt _SendMessage nicht zurück. Habe ich zuviel in diese Funktion hinein interpretiert, kann sie gar keinen Text, wie von mir gewünscht, einfügen?

Bin auch für andere (Send-freie) Lösungen zu haben.

AutoIt

#include <Clipboard.au3>
#include <WinAPISys.au3>

HotKeySet('^u', '_ClipBoard_InsertUnformat') ; Ctrl+U
HotKeySet('^+e', '_exit')                    ; Ctrl+Shift+E

Func _ClipBoard_InsertUnformat()
    ; get clipboard entry as text-only
    Local $sClip = _ClipBoard_GetData($CF_UNICODETEXT)

    ; get current window & child window from mouse position
    Local $hWnd = WinGetHandle('[ACTIVE]')
    Local $tPOINT = _WinAPI_GetMousePos(True, $hWnd)
    Local $hChild = _WinAPI_ChildWindowFromPointEx($hWnd, $tPOINT)

    ; check if child exists
    If $hChild = $hWnd Then Return

    ; create buffer
    Local $tCLIP = DllStructCreate('wchar buffer[' & StringLen($sClip)+1 & ']')
    $tCLIP.buffer = $sClip & Chr(0)

    ; sets text from buffer to mouse position
#cs  >> https://msdn.microsoft.com/en-us/library/windows/desktop/ms632644(v=vs.85).aspx <<
    Remarks
    The DefWindowProc function sets and displays the window text. For an edit control, the text is the contents of the edit control.
    For a combo box, the text is the contents of the edit-control portion of the combo box. For a button, the text is the button name.
    For other windows, the text is the window title.
#ce
;~     _SendMessage($hWnd, $WM_SETTEXT, 0, DllStructGetPtr($tCLIP))      ; mit $hWnd wird Titel gesetzt --> das funktioniert
    _SendMessage($hChild, $WM_SETTEXT, 0, DllStructGetPtr($tCLIP))    ; den Text in ein offenes Editor- oder Wordfenster eintragen funktioniert nicht
EndFunc

Func _exit()
    Exit
EndFunc

While True
    Sleep(10)
WEnd

Alles anzeigen

Tuxedo

Also ich kann noch nicht genau nachvollziehen was dein Script tun soll, aber ich hab mal getestet und

im Browser etwas markiert kopiert und bin dann zu einem Wordpad Fenster gewechselt und

dort habe ich Ctrl+u gedrückt – dann wurde der markierte Text unformatiert eingefügt.

Wenn das deine Absicht war funktioniert es voll und ganz.

Ich hoffe das hilft dir schon mal weiter.

**BugFix**

OK, Danke fürs Probieren. An Wordpad hatte ich gar nicht gedacht. Aber dadurch ist zumindest klar, dass es mit Word oder anderen Editoren, deren Schreibfläche kein (Rich)Edit-Ctrl ist, nicht funktionieren kann.

Ich hatte gehofft, dass das universell ist - war dann nix.

Nun muss ich nach einer Alternative suchen.

Tuxedo

Halt Halt nicht so schnell, hab gerade nochmal probiert beim Editor klappt es auch und Word benutzte ich schon ewig nicht mehr aber WPS ich probiers dort gleich mal aus und geb dir Bescheid.

**Bitnugger**

Schau mal hier... ob das evtl. hilft.

@trancexx schreibt:

Use _SendMessageA() or change string type to "wstr" ("wchar" for buffer).

Tuxedo

Also bei WPS Kingsoft Office funktioniert es nicht.

Eventuell geht es ja deshalb nicht weil Office Programme meistens eine eigene Verwaltung für s Clipboard haben

und daurch solche Aktionen blockiert werden??

**BugFix**

Zitat von Bitnugger

Schau mal hier... ob das evtl. hilft.

Dort geht es nur um das Ändern des Fenstertitels - das klappt ja auch mit meiner Methode.

Ich möchte jedoch im Textbereich einfügen und das ist scheinbar nur genau bei den von MSDN benannten Typen (Edit, Combobox, Button) möglich. Der Word-Edit-Bereich ist aber eine völlig andere Fensterklasse, wie bei den meisten Office-Programmen.

Tuxedo

Hallo BugFix ich weiß ja nicht wie anspruchsvoll du bist, aber genau für diesen Zweck für den du das Script gemacht hast habe ich mein Tool Smartclip entworfen.

Ich bin zwar noch nicht ganz zufrieden damit aber deine Wünsche würde es erfüllen(Textstücke und Bilder von diversen Stellen einsammeln und an einem Ort gesammelt wieder einfügen.

Und vor allem funktioniert es recht einfach mit den üblichen Befhlen Ctrl+v und Ctrl+c und es fügt leider nur unformatierten Text ein

genau wie du es wolltest, kannst ja mal drübergucken.

**Bitnugger**

Und so... (funktioniert bei mir mit Word 2016)

AutoIt

;-- TIME_STAMP   2017-11-21 13:04:44   v 0.1

#Region    ;************ Includes ************
#Include <WindowsConstants.au3>
#include <Clipboard.au3>
#include <WinAPISys.au3>
#EndRegion ;************ Includes ************

HotKeySet('^u', '_ClipBoard_InsertUnformat') ; Ctrl+U
HotKeySet('^+e', '_exit')                    ; Ctrl+Shift+E

Func _ClipBoard_InsertUnformat()
    ; get clipboard entry as text-only
    Local $sClip = _ClipBoard_GetData($CF_UNICODETEXT)

    ; get current window & child window from mouse position
    Local $hWnd = WinGetHandle('[ACTIVE]')
    Local $tPOINT = _WinAPI_GetMousePos(True, $hWnd)
    Local $hChild = _WinAPI_ChildWindowFromPointEx($hWnd, $tPOINT)

    ; check if child exists
    If $hChild = $hWnd Then Return

    ControlSend($hChild, '', '', $sClip, $SEND_RAW)
EndFunc

Func _exit()
    Exit
EndFunc

While True
    Sleep(10)
WEnd

Alles anzeigen

Oben mit dem Script, unten ohne...

**BugFix**

Grundsätzlich funktioniert es damit.

Bei mir wird aber bei jedem Zeilenumbruch ein Seitenumbruch eingefügt. Ich muss dort ControlSend($hChild, '', '', StringReplace($sClip, @CRLF, @CR) , $SEND_RAW) verwenden.

Ich lass es mal noch offen, vielleicht gibt es noch andere Ideen.

**Oscar**

Ich hätte noch eine andere Idee.

Man registriert einen eigenen Clipboard-Viewer (Beispiel aus der Hilfe zu "_ClipBoard_SetViewer").

Dort dann bei "_ClipBoard_GetData" $CF_UNICODETEXT eintragen und zurück in die Zwischenablage. Fertig!

Und so nebenbei bleibt man bei den gewohnten [ctrl] & [c] bzw, [ctrl] & [v]:

AutoIt

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Global $g_idMemo, $g_hNext = 0

Example()

Func Example()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialize clipboard viewer
    $g_hNext = _ClipBoard_SetViewer($hGUI)

    GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
    GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")

    MemoWrite("GUI handle ....: " & $hGUI)
    MemoWrite("Viewer handle .: " & _ClipBoard_GetViewer())

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Shut down clipboard viewer
    _ClipBoard_ChangeChain($hGUI, $g_hNext)
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Handle $WM_CHANGECBCHAIN messages
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Show that message was received
    MemoWrite("***** $WM_CHANGECBCHAIN *****")

    ; If the next window is closing, repair the chain
    If $wParam = $g_hNext Then
        $g_hNext = $lParam
        ; Otherwise pass the message to the next viewer
    ElseIf $g_hNext <> 0 Then
        _SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
    EndIf
EndFunc   ;==>WM_CHANGECBCHAIN

; Handle $WM_DRAWCLIPBOARD messages
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Display any text on clipboard
    Local $sClip = _ClipBoard_GetData($CF_UNICODETEXT) ; <- Zwischenablage hier als Text auslesen
    _ClipBoard_SetData($sClip) ; <- und hier wieder in die Zwischenablage zurueckschreiben
    MemoWrite($sClip)

    ; Pass the message to the next viewer
    If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc   ;==>WM_DRAWCLIPBOARD

Alles anzeigen

**BugFix**

Zitat von Oscar

Dort dann bei "_ClipBoard_GetData" $CF_UNICODETEXT eintragen und zurück in die Zwischenablage. Fertig!

Das hatte ich auch schon überlegt, allerdings habe ich da einen weniger aufwändigen und flexibleren Weg gewählt.

- Hotkey um nur bei Bedarf den Inhalt der Zwischenablage in pur Text zu wandeln

- Einfügen mit normal CTRL+V

AutoIt

#include <Clipboard.au3>

HotKeySet('^u', '_Clipboard_AsTextOnly') ; Ctrl+U
HotKeySet('^+e', '_exit')                ; Ctrl+Shift+E

Func _Clipboard_AsTextOnly()
    _ClipBoard_SetData(ClipGet(), $CF_UNICODETEXT)
EndFunc

Func _exit()
    Exit
EndFunc

While True
    Sleep(10)
WEnd

Alles anzeigen

Ich werde dann wohl die Variante belassen, ein Hotkey mehr zum Ausführen bringt mich nicht um.

**Oscar**

Übrigens: Wenn es Dir nur um das einfügen in Word geht, bietet Word bereits eine Funktion zum unformatierten Einfügen: [ctrl] & [alt] & [v].

Bei Softmaker FreeOffice ist es: [ctrl] & [shift] & [v]