DllStructCreate für DllCall

Espyre

Hallo zusammen,

ich versuche seit einigen Tagen die Struktur in AutoIt für einen DllCall abzubilden.

C

BOOL getAccessibleActions(long vmID, AccessibleContext accessibleContext, AccessibleActions *actions)

/**
******************************************************
*  AccessibleAction packages
******************************************************
*/
#define MAX_STRING_SIZE   1024
#define SHORT_STRING_SIZE   256
#define MAX_ACTION_INFO 256
#define MAX_ACTIONS_TO_DO 32


// an action assocated with a component
typedef struct AccessibleActionInfoTag {
wchar_t name[SHORT_STRING_SIZE];	// action name
} AccessibleActionInfo;

// all of the actions associated with a component
typedef struct AccessibleActionsTag {
jint actionsCount;		// number of actions
AccessibleActionInfo actionInfo[MAX_ACTION_INFO];	// the action information
} AccessibleActions;

// struct for requesting the actions associated with a component
typedef struct GetAccessibleActionsPackageTag {
long vmID;
JOBJECT64 accessibleContext;					// the component
AccessibleActions rAccessibleActions;		// the actions
} GetAccessibleActionsPackage;

/**

Alles anzeigen

Meine bisherigen Versuche sehen wie folgt aus:

AutoIt

; Variante 1
Local $tAccessibleActionName   = DllStructCreate('WCHAR name[256]')
Local $ptrAccessibleActionName = DllStructGetPtr($tAccessibleActionName)
Local $tAccessibleActions      = DllStructCreate('INT actionsCount;PTR actionInfo')
DllStructSetData($tAccessibleActions, 'actionInfo', $ptrAccessibleActionName)
DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'struct*', $tAccessibleActions)

; Variante 2
Local $tagAccessibleActions    = "INT actionsCount;WCHAR name[256];"
Local $tAccessibleActions      = DllStructCreate($tagAccessibleActions)
DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'struct*', $tAccessibleActions)
  
; Variante 3
DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'struct', DllStructCreate('int actionsCount;WCHAR name[256]'))

Alles anzeigen

Alle Varianten führten bisher zum Absturz des Scriptes.

Mit "long vmID" und "AccessibleContext accessibleContext" kann ich ohne Probleme die Element-Info's auslesen (z.B. Name, Rolle etc.). Somit schließe ich diese Parameter als Fehlerquelle aus.

Danke und viele Grüße

Espyre

**BugFix**

Bei der dritten Struktur habe ich keinen Plan, was mit JOBJECT64 für ein Datentyp gemeint ist.

Anfangen würde ich so:

AutoIt

Global Const $MAX_STRING_SIZE   = 1024
Global Const $SHORT_STRING_SIZE = 256
Global Const $MAX_ACTION_INFO   = 256
Global Const $MAX_ACTIONS_TO_DO = 32

;~ typedef struct AccessibleActionInfoTag {
;~ wchar_t name[SHORT_STRING_SIZE];    // action name
;~ } AccessibleActionInfo;
Global $tAccessibleActionInfo = DllStructCreate('wchar name[' & $SHORT_STRING_SIZE & ']')

;~ typedef struct AccessibleActionsTag {
;~ jint actionsCount;        // number of actions
;~ AccessibleActionInfo actionInfo[MAX_ACTION_INFO];    // the action information
;~ } AccessibleActions;
Global $tAccessibleActions = DllStructCreate('int actionsCount;' & DllStructGetPtr($tAccessibleActionInfo) & '[' & $MAX_ACTION_INFO & ']')

Alles anzeigen

Laut Definition ist actionInfo ein Array von Pointern auf die Struktur AccessibleActionInfo, ich hoffe das klappt so.

Espyre

Danke, der Aufruf führt zumindest zu keinem Fehler. Leider enthält er mMn auch nicht die gewünschten Daten.

Nach meinem Verständnis sollte bei an Anzahl "1" rauskommen und beim Namen der Aktion "click" oder so ähnlich.

JavaMonkey2.png JavaMonkey.png

Ich hole mal eben aus, wie ich zu den benötigten Daten für den Aufruf komme.

AutoIt

Global Const $c_JOBJECT64  = "UINT64"   ;~ JOBJECT64
Global Const $cP_JOBJECT64 = "UINT64*" ;~ POINTER(JOBJECT64)
Global $g_hAccessBridgeDll, $vmId, $acParent

; Ermittelt das Main-Object anhand des Fensterhandles
Func _JAB_getMainElement($hWnd)

    If BitAND(WinGetState($hWnd), 8) = 0 Then
        WinActivate($hWnd)
        WinWaitActive($hWnd)
    EndIf
    
    $sIsJavaWindow = DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'isJavaWindow', 'hwnd', $hWnd)
    If @Error <> 0 Or $sIsJavaWindow[0] <> 1 Then Return SetError(-1, 0, 0)

    $sAC_fromHwnd = DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleContextFromHWND', 'hwnd', $hWnd, 'long*', $vmID, $cP_JOBJECT64, $acParent)
    If @Error <> 0 Then Return SetError(-2, 0, 0)

    $vmId     = $sAC_fromHwnd[2]
    $acParent = $sAC_fromHwnd[3]
EndFunc ;<==/JAB_getMainElement

Alles anzeigen

Ich habe bisher zwei Möglichkeiten gefunden, ein Object in der Applikation zu identifizieren. Mit Koordinaten oder über den Tree von JavaMonkey. Die zweite Variante habe ich im Einsatz.

AutoIt

; Mit getAccessibleChildFromContext bis zum gewünschten Objekt
; Beispiel: $sElementPfad = '0,1,0,2,0,0'
; Den Pfad entnehme ich JavaMonkey (siehe Anhang)
Func _JAB_GetElement($hWnd, $sElementPfad)
    Local $aPfad      = StringSplit($sElementPfad, ',',2)
    Local $acElements = $acParent

    If BitAND(WinGetState($hWnd), 8) = 0 Then
        WinActivate($hWnd)
        WinWaitActive($hWnd)
    EndIf

    For $i = 0 To Ubound($aPfad) -1
        $sResult = DllCall($g_hAccessBridgeDll, 'long', 'getAccessibleChildFromContext','long', $vmId, $c_JOBJECT64, $acElements, 'int', Int($aPfad[$i]))
        $acElements = $sResult[0]
    Next

    Return $acElements
EndFunc ;<==/_JAB_GetElement

; Gibt alle Infos von "getAccessibleContextInfo" als Array zurück
Func _JAB_GetElementInfo($hWnd, $acElement)

    Local $aElementInfo[12][2] = [ _ 
                                    ['name',''], _ 
                                    ['description',''], _ 
                                    ['role',''], _ 
                                    ['role_en_US',''], _ 
                                    ['states',''], _ 
                                    ['states_en_US',''], _ 
                                    ['indexInParent',''], _ 
                                    ['childrenCount',''], _ 
                                    ['x',''], _ 
                                    ['y',''], _ 
                                    ['width',''], _ 
                                    ['height',''] _ 
                                 ]

    Local $tagAccessibleContextInfo = "WCHAR name[1024];WCHAR description[1024];WCHAR role[256];WCHAR role_en_US[256];WCHAR states[256];WCHAR states_en_US[256];INT indexInParent;INT childrenCount;INT x;INT y;INT width;INT height;BOOL accessibleComponent;BOOL accessibleAction;BOOL accessibleSelection;BOOL accessibleText;BOOL accessibleInterfaces"
    Local $tAccessibleContextInfo   = DllStructCreate($tagAccessibleContextInfo)

    If BitAND(WinGetState($hWnd), 8) = 0 Then
        WinActivate($hWnd)
        WinWaitActive($hWnd)
    EndIf

    $sAC_Info = DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleContextInfo','long', $vmId, 'long', $acElement, 'struct*', $tAccessibleContextInfo)
    $AccessibleContextInfo = $sAC_Info[3]
    For $i = 0 To Ubound($aElementInfo) -1
        $aElementInfo[$i][1] = DllStructGetData($sAC_Info[3], $aElementInfo[$i][0])
    Next

    Return $aElementInfo
EndFunc ;<==/JAB_GetElementInfo

Liest den Text des Elements aus
Func _JAB_getValue($hWnd, $acText)
    Local $tagAccessibleTextInfo      = "INT charCount;INT caretIndex;INT indexAtPoint"
    Local $tAccessibleTextInfo        = DllStructCreate($tagAccessibleTextInfo)
    Local $tagAccessibleTextItemsInfo = "WCHAR letter;WCHAR word[256];WCHAR sentence[1024]"
    Local $tAccessibleTextItemsInfo   = DllStructCreate($tagAccessibleTextItemsInfo)
    Local $sText

    If BitAND(WinGetState($hWnd), 8) = 0 Then
        WinActivate($hWnd)
        WinWaitActive($hWnd)
    EndIf

    $bCall = DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleTextInfo','long', $vmId, 'long', $acText, 'struct*', $tAccessibleTextInfo)
    $iCharCount = DllStructGetData($tAccessibleTextInfo, 'charCount')

    For $i = 0 To $iCharCount - 1
        DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleTextItems','long', $vmId, 'long', $acText, 'struct*', $tAccessibleTextItemsInfo, 'int', $i)
        $sText &= DllStructGetData($tAccessibleTextItemsInfo, 'letter')
    Next

    Return $sText
EndFunc ;<==/JAB_getValue

Alles anzeigen

Ich hoffe die Informationen helfen weiter.

Da ich noch relativ unerfahren mit DllCalls bin, kann natürlich auch eine falsche Interpretation meinerseits der Fehler sein

Danke und viele Grüße

Espyre

**BugFix**

Da werde ich später nochmal drüber schauen, Dll ist meist mit etwas Probieren verbunden und wenn man dann nicht selbst auf die Dll zugreifen kann, weiß man auch nicht ob die Überlegungen in die richtige Richtung gehen.

Ich habe vor Jahren mal die Nutzung von Arraystrukturen bei Dll in eine kleine Funktionssammlung gepackt. Vielleicht kannst du damit etwas anfangen: Arrays als Dll-Elemente

EDIT

Zitat von Espyre

$sAC_Info = DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleContextInfo','long', $vmId, 'long', $acElement, 'struct*', $tAccessibleContextInfo)

Funktioniert dieser Aufruf?

struct*, $tAccessibleContextInfo soll einen Pointer auf $tAccessibleContextInfo legen.

Falls der Aufruf nicht funktioniert kannst du auch probieren:

ptr, DllStructGetPtr($tAccessibleContextInfo)

EDIT-2

ich vermute mal, mit dem Byte-Array solltest du zum Ziel kommen, in etwa so:

AutoIt

Global Const $MAX_STRING_SIZE   = 1024
Global Const $SHORT_STRING_SIZE = 256
Global Const $MAX_ACTION_INFO   = 256
Global Const $MAX_ACTIONS_TO_DO = 32

Global $tagAccessibleActionInfo = 'wchar name[' & $SHORT_STRING_SIZE & ']'

; create Byte-Array "actionInfo"
Global $iSize = DllStructGetSize(DllStructCreate($tagAccessibleActionInfo, 1))
Global $a_actionInfo[$MAX_ACTION_INFO +1]
$a_actionInfo[0] = DllStructCreate('byte[' & $iSize *$MAX_ACTION_INFO & "]")
Global $ptr = DllStructGetPtr($a_actionInfo[0])
For $i = 0 To $MAX_ACTION_INFO -1
    $a_actionInfo[$i+1] = DllStructCreate($tagAccessibleActionInfo, $ptr + $i*$iSize)
Next

; Dll-Call
DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'ptr', DllStructGetPtr($a_actionInfo))
; evtl. muss der Pointer auf das Element[0] verweisen
; DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'ptr', DllStructGetPtr($a_actionInfo[0]))

Alles anzeigen

Espyre

Zitat von BugFix

EDIT

Funktioniert dieser Aufruf?

struct*, $tAccessibleContextInfo soll einen Pointer auf $tAccessibleContextInfo legen.

Ja, der funktioniert einwandfrei.

Ich habe für den Test jetzt ein Textfeld anstatt des Buttons genommen. Das Textfeld hat 56 actions.

AutoIt

Global Const $MAX_STRING_SIZE   = 1024
Global Const $SHORT_STRING_SIZE = 256
Global Const $MAX_ACTION_INFO   = 256
Global Const $MAX_ACTIONS_TO_DO = 32

Global $tagAccessibleActionInfo = 'wchar name[' & $SHORT_STRING_SIZE & ']'

; create Byte-Array "actionInfo"
Global $iSize = DllStructGetSize(DllStructCreate($tagAccessibleActionInfo, 1))
Global $a_actionInfo[$MAX_ACTION_INFO +1]
$a_actionInfo[0] = DllStructCreate('byte[' & $iSize *$MAX_ACTION_INFO & "]")
Global $ptr = DllStructGetPtr($a_actionInfo[0])
For $i = 0 To $MAX_ACTION_INFO -1
    $a_actionInfo[$i+1] = DllStructCreate($tagAccessibleActionInfo, $ptr + $i*$iSize)
Next

; Dll-Call
; DllCall($g_hAccessBridgeDll, 'BOOL:cdecl', 'getAccessibleActions','long', $vmId, 'long', $acButton, 'ptr', DllStructGetPtr($a_actionInfo[0]))

Alles anzeigen

Dein Beispiel hat anscheinend funktioniert.

Wenn ich _WinAPI_DisplayStruct($a_actionInfo[0]) ausführe, findet man auch die 56.

a_actionInfo_0.PNG

Vielen Dank Bugfix. Ich versuche jetzt deinen Code zu verstehen und mit der Struct weiter zu arbeiten. Damit möchte ich dann im nächsten Schritt eine bestimmte Aktion ausführen.

Viele Grüße

Espyre

**BugFix**

Zitat von Espyre

Ich versuche jetzt deinen Code zu verstehen und mit der Struct weiter zu arbeiten.

Wirf mal einen Blick in mein Tut, da habe ich das etwas mehr kommentiert: Dll-Tutorial