1+2+3+4 nun will ich ein Bildchen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Moinsen,

meine Aufgabenstellung ist etwa wie folgt: Ich möchte auf ein PDf einen Stempel aufbringen, der als z.B. *.jpg vorliegt. Das ist soweit klar, ich regle das mit externen Programmen, die per autoit aufgerufen werden --> Das funktioniert.

Nun möchte ich aber einen durchnummerierten Stempel aufbringen. Dokument 1 bekommt Stempel 1 usw. Wie kann ich aus Autoit heraus eine *.jpg chen erzeugen,das einen dynamischen Inhalt hat. z.B. eine laufende Nummer? Oder wie kombiniere ich Text und *.jpg. Ein Beispielbildchen habe ich hochgeladen....

Sofern ich das mangelhaft beschrieben habe -- > Sorry ich liefere die Fragen gerne nach...

Danke

Peter

**alpines**

Du kannst die Gdi+ UDF dafür nehmen, damit kannst du auch Strings zeichnen. Z.B. so:

AutoIt

#include <GDIPlus.au3>

_GDIPlus_Startup()

$hBitmap = _GDIPLUS_BitmapCreateFromScan0(300, 150)
$hImage = _GDIPlus_ImageGetGraphicsContext($hBitmap)

_GDIPlus_GraphicsClear($hImage, 0xFFFCFCFC)
_GDIPLus_GraphicsDrawString($hImage, "Rechnung", 5, 10, "Arial", 42)
_GDIPlus_GraphicsDrawString($hImage, "00001", 55, 80, "Arial", 40)

_GDIPlus_ImageSaveToFile($hBitmap, "Rechnung 1.jpg")
_GDIPlus_ImageDispose($hImage)
_GDIPlus_BitmapDispose($hBitmap)

_GDIPlus_Shutdown()

Alles anzeigen

misterspeed

Sollte mit GDI+ kein Problem sein. Hier hat sich jemand dran versucht einfachen Text auf ein Bild zu legen:

https://www.autoitscript.com/forum/topic/65…-text-to-image/

EDIT: Da war alpines wohl schneller...

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Ich bin wieder mal sprachlos - ja sowas habe ich gesucht...... Danke

Hat noch jemand eine Idee wie ich den Rahmen darum bekomme ? Vorlage einlesen mit Rahmen und nur Text reinschreiben ???

Danke

Ps.: Ja schon klar die Frage wird von Zeitmangel geprägt ... sorry -- trotzdem nett wenn jemand....

**alpines**

Rahmen kannst du mit _GDIPlus_GraphicsDrawRect zeichnen.

Für das Schreiben in bereits existente Bilder lädst du diese am besten mit _GDIPlus_ImageLoadFromFile und bearbeitest sie dann direkt.

AutoIt

#include <GDIPlus.au3>

_GDIPlus_Startup()

$hRedPen = _GDIPlus_PenCreate(0xFFFF0000, 5, 2)
$hBitmap = _GDIPLUS_BitmapCreateFromScan0(300, 150)
$hImage = _GDIPlus_ImageGetGraphicsContext($hBitmap)

_GDIPlus_GraphicsClear($hImage, 0xFFFCFCFC)

_GDIPlus_GraphicsDrawRect($hImage, 2, 2, 300 - 5, 150 - 5, $hRedPen)
_GDIPLus_GraphicsDrawString($hImage, "Rechnung", 5, 10, "Arial", 42)
_GDIPlus_GraphicsDrawString($hImage, "00001", 55, 80, "Arial", 40)

_GDIPlus_ImageSaveToFile($hBitmap, "Rechnung 1.jpg")
_GDIPlus_ImageDispose($hImage)
_GDIPlus_BitmapDispose($hBitmap)

_GDIPlus_Shutdown()

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

alpines

Mille Grazie... Das verwende ich direkt Sollten wir uns mal über den Weg laufen.... ich geb einen aus.

Leiben Dank

Peter

--> Closed

**Oscar**

Ich hatte gerade mal etwas Zeit über:

AutoIt

#include <GDIPlus.au3>

_SaveNumberPic('e-Rechnung', 4711, 0xFF0000DD, 0xFF202020) ; Farben im ARGB-Format

Func _SaveNumberPic($sText, $iNumber, $iTextColor = 0xFF000000, $iNumberColor = 0xFF000000, $iBkColor = 0xFFFFFFFF, $iWidth = 260, $iHeight = 110)
    _GDIPlus_Startup()
    Local $sFilename, $sNumber, $hBitmap, $hGfxCtxt, $hBrushText, $hBrushNumber, $hFormat, $hFamily, $hFont, $tLayout
    $sFilename = StringFormat('%s\%s_%06i.png', @ScriptDir, $sText, $iNumber) ; Dateiname generieren (als png = bessere Qualitaet und kleinere Dateigroesse)
    $sNumber = StringFormat('%06i', $iNumber) ; die Nummer formatieren
    $hBitmap = _GDIPLUS_BitmapCreateFromScan0($iWidth, $iHeight) ; Bitmap erstellen
    $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Graphic-Context der Bitmap
    _GDIPlus_GraphicsClear($hGfxCtxt, $iBkColor) ; die Graphic mit der Hintergrundfarbe fuellen
    _GDIPlus_GraphicsSetInterpolationMode($hGfxCtxt, 7) ; Interpolationsmodus auf beste Qualitaet setzen
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtxt, 3) ; Textrendering auf "antialiased glyph bitmap and hinting"
    $hPen = _GDIPlus_PenCreate($iTextColor, 4) ; die Farbe und Staerke fuer den Rahmen festlegen
    _GDIPlus_GraphicsDrawRect($hGfxCtxt, 2, 2, $iWidth - 4, $iHeight - 4, $hPen) ; den Rahmen auf die Graphic zeichnen
    $hBrushText = _GDIPlus_BrushCreateSolid($iTextColor) ; die Farbe fuer den Text festlegen
    $hBrushNumber = _GDIPlus_BrushCreateSolid($iNumberColor) ; die Farbe fuer die Nummer festlegen
    $hFormat = _GDIPlus_StringFormatCreate() ; Textformat erstellen
    _GDIPlus_StringFormatSetAlign($hFormat, 1) ; Text horizontal zentrieren
    $hFamily = _GDIPlus_FontFamilyCreate('Arial') ; Zeichensatz festlegen
    $hFont = _GDIPlus_FontCreate($hFamily, 24, 1) ; Zeichensatzgroesse und -stil fuer den Text festlegen
    $tLayout = _GDIPlus_RectFCreate(0, 5, $iWidth, 40) ; RECT-Struktur fuer _GDIPlus_GraphicsDrawStringEx erstellen
    _GDIPlus_GraphicsDrawStringEx($hGfxCtxt, $sText, $hFont, $tLayout, $hFormat, $hBrushText) ; den Text in die Graphic zeichnen
    _GDIPlus_FontDispose($hFont) ; die Zeichensatzeigenschaften freigeben
    $hFont = _GDIPlus_FontCreate($hFamily, 42, 1) ; Zeichensatzgroesse und -stil fuer die Nummer festlegen
    $tLayout = _GDIPlus_RectFCreate(0, 45, $iWidth, 60) ; RECT-Struktur fuer _GDIPlus_GraphicsDrawStringEx erstellen
    _GDIPlus_GraphicsDrawStringEx($hGfxCtxt, $sNumber, $hFont, $tLayout, $hFormat, $hBrushNumber) ; die Nummer in die Graphic zeichnen
    _GDIPlus_ImageSaveToFile($hBitmap, $sFilename) ; die Bitmap speichern
    ; die verwendeten Ressourcen wieder freigeben
    $tLayout = 0
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrushNumber)
    _GDIPlus_BrushDispose($hBrushText)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGfxCtxt)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Als PNG wird's kleiner und sieht besser aus.

Außerdem habe ich mal alles kommentiert, damit Du das evtl. noch anpassen kannst. So nebenbei lernst Du gleich noch einiges über GDI+.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Oscar

Hallo Oscar,

das ist ja ein "verspäteter" Nikolaus. Lieben Dank. Du hast Dir wirklich Mühe gemacht. Hatte ich nicht erwartet. Aber mir fehlt z.Z. die Zeit an allen Ecken und Enden. Ich schau mir das mal an - da kann ich meine Kentnisse über GDI sicher verbessern - was nicht schwer ist bis heute =0. Das blau jedenfalls ist chic

Wir haben tatsächlich etwas gemeinsam - wie es scheint - die Vorliebe für *.png. Ist eigentlich mein lieblings Grafikformat.

Nochmals Danke für den Code.

Peter

Striker2010

Oscar : ich wollte nur auch kurz Danke sagen! Ich hatte ein ähnliches Problem wie Peter S. Taler und mit Hilfe deines Beitrags (und denen von alpines und misterspeed) komme ich der Lösung ein gutes Stück näher! Vielen Dank euch!