GDIPlus Grafik speichern funktioniert nicht korrekt

Trubadour

Hallo zusammen,

eigentlich sagt der Titel schon alles. Ich erhalte nur eine schwarze jpg-Datei. Auch wenn ich vorher auf die Grafik noch etwas draufmale, die abgespeicherte Datei ist nur schwarz. Meine anderen Versuche muß ich hier ja gar nicht erst vorstellen....

Für die Lösung des Problems benötigt man anscheinend umfassendere GDIplus Kenntnisse.

Beste Grüße, Jens

C

#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GuiConstantsEx.au3>

_Main()

Func _Main()
    Local $hGUI
    global $hGraphic
    global $iWidth=600
    global $iHeight=400
    ;Local $iARGB_BG="0x22ffff22"
    $hGUI = GUICreate("Grafik",$iWidth, $iHeight)
    GUISetState()

    _GDIPlus_Startup()

    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsClear($hGraphic,0x88ef0f22 )

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

     $hSaveBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; Bitmap aus Grafik zum Speichern erstellen
    _GDIPlus_ImageSaveToFile($hSaveBitmap,@ScriptDir& "\Rechteck.jpg")

; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_GraphicsDispose($hSaveBitmap)

    _GDIPlus_Shutdown()

EndFunc   ;==>_Main

Alles anzeigen

**alpines**

Du musst ImageGetContext verwenden und das zurückgegebene Bild davon beschreiben (als Buffer), dann kannst du deine $hSaveBitmap auch speichern.

Sieh dir mal das Beispiel zu _GDIPlus_BitmapCreateFromGraphics aus der Hilfe an: https://www.autoitscript.com/autoit3/docs/l…romGraphics.htm

AutoIt

#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GuiConstantsEx.au3>

_Main()

Func _Main()
    Local $hGUI
    global $hGraphic
    global $iWidth=600
    global $iHeight=400
    ;Local $iARGB_BG="0x22ffff22"
    $hGUI = GUICreate("Grafik",$iWidth, $iHeight)
    GUISetState()

    _GDIPlus_Startup()

    $hGraphic = _GDIPlus_GraphicsCreateFromHWND(WinGetHandle($hGUI))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    $hSaveBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; Bitmap aus Grafik zum Speichern erstellen
    $himage = _GDIPlus_ImageGetGraphicsContext($hSaveBitmap)

    _GDIPlus_GraphicsClear($himage,0x884565EA )
    _GDIPlus_GraphicsDrawString($himage, "test test", 50, 50, "Arial", 100)

    _GDIPlus_ImageSaveToFile($hSaveBitmap,@ScriptDir& "\Rechteck.png")
; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_GraphicsDispose($hSaveBitmap)

    _GDIPlus_Shutdown()

EndFunc   ;==>_Main

Alles anzeigen

Trubadour

Vielen Dank, Alpines.

Auch wenn ich mir noch nicht erklären kann, wieso auf ich auf $hIamage zeichnen kann und das Gezeichnete in der vorher deklarierten Variablen $hSaveImage auch vorhanden ist. AAH, es handelt sich um handles, aber wofür brauch ich dann noch den Context?

Naja, auch wenn ich es leider nicht verstehe, ich kann jetzt erstellte Grafiken speichern und das war das Wichtigste.

**alpines**

Mit ImageGetGraphicsContext erzeugst du einen Buffer zu deinem BitmapObjekt welches auf ein GraphicsObjekt zeigt.

GdiPlus flusht dann den Buffer automatisch auf die Bitmap und du musst es nur noch auf die Graphics mit _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap) zeichnen.

Wenn man ImageSaveToFile mal an die Beispielfunktion von _GDIPlus_BitmapCreateFromGraphics hinzufügt, dann funktioniert das ganze auch:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Global $g_hGUI, $g_hBrush, $g_hGfx, $g_hGfxCtxt, $g_hBitmap

Example()

Func Example()
    AutoItSetOption("GUIOnEventMode", 1)

    _GDIPlus_Startup() ;initialize GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ;$iBGColor format RRGGBB

    $g_hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
    GUISetBkColor($iBgColor, $g_hGUI) ;set GUI background color
    GUISetState(@SW_SHOW)

    ;create buffered graphics frame set for smoother gfx object movements
    $g_hGfx = _GDIPlus_GraphicsCreateFromHWND($g_hGUI) ;create a graphics object from a window handle
    $g_hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $g_hGfx) ;create a Bitmap object based on a graphics object
    $g_hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($g_hBitmap) ;get the graphics context of the image / bitmap to draw on image / bitmap
    _GDIPlus_GraphicsSetSmoothingMode($g_hGfxCtxt, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;sets the graphics object rendering quality (antialiasing)

    $g_hBrush = _GDIPlus_BrushCreateSolid(0xFF8080FF) ;create a solid Brush object

    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

    Local Const $iDeg = ACos(-1) / 180 ;ACos(-1) is nearly pi
    Local $iSize = 50, $iX_Center = ($iWidth - $iSize) / 2, $iY_Center = ($iHeight - $iSize) / 2, $iXPos, $iYPos, $iAngle = 0
    Local Const $iDots = 16, $iAngelDist = 360 / $iDots, $iRadius = 200

    Do
        _GDIPlus_GraphicsClear($g_hGfxCtxt, 0xFF000000 + $iBgColor) ;clear bitmap with given color (AARRGGBB format)
        For $i = 1 To $iDots
            $iXPos = $iX_Center + Cos($iAngle * $iDeg) * $iRadius
            $iYPos = $iY_Center + Sin($iAngle * $iDeg) * $iRadius
            _GDIPlus_GraphicsFillEllipse($g_hGfxCtxt, $iXPos, $iYPos, $iSize, $iSize, $g_hBrush) ;draw dots in a circle
            $iAngle += $iAngelDist ;increase angle to next dot
        Next
        $iAngle += 1 ;increase overall angle
        _GDIPlus_GraphicsDrawImageRect($g_hGfx, $g_hBitmap, 0, 0, $iWidth, $iHeight) ;copy drawn bitmap to GUI
    Until Not Sleep(20) ;Sleep() always returns 1 and Not 1 is 0
EndFunc   ;==>Example

Func _Exit() ;cleanup GDI+ resources
    _GDIPlus_ImageSaveToFile($g_hBitmap, "test.png")
    _GDIPlus_BrushDispose($g_hBrush)
    _GDIPlus_GraphicsDispose($g_hGfxCtxt)
    _GDIPlus_GraphicsDispose($g_hGfx)
    _GDIPlus_BitmapDispose($g_hBitmap)
    _GDIPlus_Shutdown()
    GUIDelete($g_hGUI)
    Exit
EndFunc   ;==>_Exit

Alles anzeigen

Trubadour

Dann noch einmal herzlichen Dank! So einfach wär das also gewesen. Vielleicht sollte mal jemand von euch ein Beispiel irgendwo gut erreichbar/sichtbar und erklärt positionieren oder ihr integriert das in die Hilfe, und zwar mit deiner Erklärung. So toll und einfach ich Autoit finde, die Grafikprogammierung mit GDI+ ist für Laien fast nicht nachzuvollziehen.

Ich habe mir deshalb jahrelang mit Screenshots geholfen, aber jetzt unter WIN10 mit der Möglichkeit der scalierbaren Bildschirminhalte funktionierte das auch nicht mehr zufriedenstellend.