Infinite Image Zoom Flight build 2018-01-10

**UEZ** · 5. Januar 2018

Hier zwei kleine Skripte zum Jahreswechsel!

Zoomquilt:

AutoIt

;coded by UEZ build 2018-01-10, idea and images taken from http://zoomquilt.org/
;thanks to spudw2k for the MouseZoom function
#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\au3.ico")
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/so /pe /rm
#AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_stripped.au3"
#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit, $iW, $iH
Global Const $sTitle = "GDI Image Zoom v2.1.2 coded by UEZ"
AutoItSetOption("GUIOnEventMode", 1)
Downloader()
GDIPlus_ZoomImage()
AutoItSetOption("GUIOnEventMode", 0)
_GDIPlus_Shutdown()
Func GDIPlus_ZoomImage($bMultimonitor = False)
$bExit = False
Local $i, $aImages[46], $hImage, $hObj
ConsoleWrite("Loading images from local disk..." & @CRLF)
Local $fTimer = TimerInit()
For $i = 0 To UBound($aImages) - 1
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\Images\TheZoomquilt" & StringFormat("%02i.jpg", $i))
$aImages[$i] = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
_GDIPlus_ImageDispose($hImage)
Next
ConsoleWrite(UBound($aImages) & " images loaded in " & TimerDiff($fTimer) & " ms" & @CRLF)
Local $tDim = DllStructCreate($tagBITMAP)
DllCall("GDI32.dll", 'int', 'GetObject', 'int', $aImages[0], 'int', DllStructGetSize($tDim), 'ptr', DllStructGetPtr($tDim))
$iW = $tDim.bmWidth
$iH = $tDim.bmHeight
Local $hFullScreen = WinGetHandle("[TITLE:Program Manager;CLASS:Progman]"), $aFullScreen[4], $iW_Dt, $iH_Dt
$aFullScreen = WinGetPos($hFullScreen)
If $bMultimonitor Then
$iW_Dt = $aFullScreen[2]
$iH_Dt = $aFullScreen[3]
Else
$iW_Dt = @DesktopWidth
$iH_Dt = @DesktopHeight
$aFullScreen[0] = ""
$aFullScreen[1] = ""
EndIf
$hGUI = GUICreate($sTitle, $iW_Dt, $iH_Dt, $aFullScreen[0], $aFullScreen[1], $WS_POPUP, $WS_EX_TOPMOST)
GUISetState(@SW_SHOW, $hGUI)
GUISetCursor(16, 1)
;create canvas elements
Local Const $hDC = _WinAPI_GetDC($hGUI)
Local Const $hHBitmap = _WinAPI_CreateCompatibleBitmap($hDC, $iW_Dt, $iH_Dt)
Local Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
Local Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
Local Const $hMemDC = _WinAPI_CreateCompatibleDC($hDC)
_WinAPI_SetStretchBltMode($hDC_backbuffer, $STRETCH_DELETESCANS)
Local Const $hCanvas = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
_GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
_GDIPlus_GraphicsSetPixelOffsetMode($hCanvas, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
Local Const $hBrush_Clr = _GDIPlus_BrushCreateSolid(0xFF000000), _
$hBrush_FPS = _GDIPlus_BrushCreateSolid(0xFFFFFFFF), _
$hFormat_FPS = _GDIPlus_StringFormatCreate(), _
$hFamily_FPS = _GDIPlus_FontFamilyCreate("Arial"), _
$hFont_FPS = _GDIPlus_FontCreate($hFamily_FPS, 8), _
$tLayout_FPS = _GDIPlus_RectFCreate(0, 0, 130, 16)
$iFPS = 0
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit_About")
AdlibRegister("CalcFPS", 1000)
Local $a[3], $b = 1, $c, $x, $e, $y, $w, $h, $w2 = $iW_Dt / 2, $h2 = $iH_Dt / 2, $q, $r
If $iW_Dt > 1.5 * $iH_Dt Then
$q = $iW_Dt
$r = 0.75 * $iW_Dt
Else
$q = 1.5 * $iH_Dt
$r = 0.75 * $iH_Dt
EndIf
Do
For $e = 0 To 2
$a[$e] = $aImages[Mod(Floor($b) + $e, UBound($aImages))]
Next
$c = 2^(Mod($b, 1))
For $e = 0 To 2
$x = $w2 - $q / 2 * $c
$y = $h2 - $r / 2 * $c
$w = $q * $c
$h = $r * $c
$hObj = _WinAPI_SelectObject($hMemDC, $a[$e])
_WinAPI_StretchBlt($hDC_backbuffer, $x, $y, $w, $h, $hMemDC, 0, 0, $iW, $iH, $SRCCOPY)
$c *= 0.5
Next
$b += MouseZoom()
IF $b < 0 Then $b = UBound($aImages) - $b
_GDIPlus_GraphicsDrawStringEx($hCanvas, "FPS: " & $iShowFPS & " @ " & $iW_Dt & "x" & $iH_Dt & " px", $hFont_FPS, $tLayout_FPS, $hFormat_FPS, $hBrush_FPS)
_WinAPI_BitBlt($hDC, 0, 0, $iW_Dt, $iH_Dt, $hDC_backbuffer, 0, 0, $SRCCOPY)
$iFPS += 1
If $bExit Then ExitLoop
Until Not Sleep(0)
AdlibUnRegister("CalcFPS")
;release resources
_GDIPlus_FontDispose($hFont_FPS)
_GDIPlus_FontFamilyDispose($hFamily_FPS)
_GDIPlus_StringFormatDispose($hFormat_FPS)
_GDIPlus_BrushDispose($hBrush_Clr)
_GDIPlus_BrushDispose($hBrush_FPS)
_GDIPlus_GraphicsDispose($hCanvas)
_WinAPI_SelectObject($hMemDC, $hObj)
_WinAPI_DeleteDC($hMemDC)
_WinAPI_SelectObject($hDC_backbuffer, $DC_obj)
_WinAPI_DeleteDC($hDC_backbuffer)
_WinAPI_DeleteObject($hHBitmap)
_WinAPI_ReleaseDC($hGUI, $hDC)
For $i = 0 To UBound($aImages) - 1
_WinAPI_DeleteObject($aImages[$i])
Next
GUIDelete($hGUI)
EndFunc ;==>GDIPlus_ZoomImage
Func MouseZoom()
;https://www.arduino.cc/reference/en/language/functions/math/map/
Local $iInput = MouseGetPos(1), $iInMin = 0, $iInMax = @DesktopHeight, $iOutMin = 1, $iOutMax = -1, $iStep = 0.025
Return (($iInput - $iInMin) * ($iOutMax - $iOutMin) / ($iInMax - $iInMin) + $iOutMin) * $iStep
EndFunc ;MouseZoom()
Func _Exit_About()
$bExit = True
EndFunc ;==>_Exit_About
Func CalcFPS() ;display FPS
$iShowFPS = $iFPS
$iFPS = 0
EndFunc ;==>CalcFPS
Func Downloader()
Local $i, $A = StringSplit("FUjD9hf gbHhxTR 8YyzJdR xP3aNkR 2Qi4fQr E6pW5Ky zmtWIBF Af7LtYp TuXy30d 3nKGLr2 hNoWscB mSBvv3K f4wJ70e mIt9XmM M4TkAyh P4L4qhd hNM6bTv VoT8JXM jqcGH0B DYVoN8n bOPQkOI NeaTfJ1 18ppMNr FZ3d8Jv HsoX2RP mjv4kzI 6rpJbef pySKauq WjNQYRV Ffooo8y Xei5XfD T5A415r LiV0VNB nGcwiO4 b1Gdjjy GE828iy eSQ7SLe 1mPyGgL GNtwJIr KxBlU7E aKXhms5 9Quu2wu Y07quDf r0yC5Qa 273fCkD 2wMyCUw FUjD9hf", " ", 2)
Local $sURL
For $i = 0 To UBound($A) - 1
If Not FileExists(@ScriptDir & "\Images\TheZoomquilt" & StringFormat("%02i.jpg", $i)) Then
If Not FileExists(@ScriptDir & "\Images") Then DirCreate(@ScriptDir & "\Images")
$sURL = "http://imgur.com/" & $A[Mod(20 + $i, 46)] & ".jpg"
ConsoleWrite("Downloading " & $sURL & ": " & InetGet($sURL, @ScriptDir & "\Images\TheZoomquilt" & StringFormat("%02i.jpg", $i), 8) & " bytes" & @CRLF)
ToolTip("Downloading images...Please wait! -> " & $i + 1 & " / " & UBound($A), MouseGetPos(0), MouseGetPos(1))
EndIf
Next
ToolTip("")
EndFunc ;==>Downloader

Alles anzeigen

Arkadia:

AutoIt

;coded by UEZ build 2018-01-10, idea and images taken from http://arkadia.xyz
;thanks to spudw2k for the MouseZoom function
#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\au3.ico")
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/so /pe /rm
#AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_stripped.au3"
#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit, $iW, $iH
Global Const $sTitle = "GDI Image Zoom v2.2.1 coded by UEZ"
AutoItSetOption("GUIOnEventMode", 1)
Downloader()
GDIPlus_ZoomImage()
AutoItSetOption("GUIOnEventMode", 0)
_GDIPlus_Shutdown()
Func GDIPlus_ZoomImage($bMultimonitor = False)
$bExit = False
Local $i, $aImages[49], $hImage, $hObj
ConsoleWrite("Loading images from local disk..." & @CRLF)
Local $fTimer = TimerInit()
For $i = 0 To UBound($aImages) - 1
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\Images\Arkadia" & $i & ".jpg")
$aImages[$i] = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
_GDIPlus_ImageDispose($hImage)
Next
ConsoleWrite(UBound($aImages) & " images loaded in " & TimerDiff($fTimer) & " ms" & @CRLF)
Local $tDim = DllStructCreate($tagBITMAP)
DllCall("GDI32.dll", "int", "GetObject", "int", $aImages[0], "int", DllStructGetSize($tDim), "ptr", DllStructGetPtr($tDim))
$iW = $tDim.bmWidth
$iH = $tDim.bmHeight
Local $hFullScreen = WinGetHandle("[TITLE:Program Manager;CLASS:Progman]"), $aFullScreen[4], $iW_Dt, $iH_Dt
$aFullScreen = WinGetPos($hFullScreen)
If $bMultimonitor Then
$iW_Dt = $aFullScreen[2]
$iH_Dt = $aFullScreen[3]
Else
$iW_Dt = @DesktopWidth
$iH_Dt = @DesktopHeight
$aFullScreen[0] = ""
$aFullScreen[1] = ""
EndIf
$hGUI = GUICreate($sTitle, $iW_Dt, $iH_Dt, $aFullScreen[0], $aFullScreen[1], $WS_POPUP, $WS_EX_TOPMOST)
GUISetState(@SW_SHOW, $hGUI)
GUISetCursor(16, 1)
;create canvas elements
Local Const $hDC = _WinAPI_GetDC($hGUI)
Local Const $hHBitmap = _WinAPI_CreateCompatibleBitmap($hDC, $iW_Dt, $iH_Dt)
Local Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
Local Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
Local Const $hMemDC = _WinAPI_CreateCompatibleDC($hDC)
_WinAPI_SetStretchBltMode($hDC_backbuffer, $STRETCH_DELETESCANS)
Local Const $hCanvas = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
_GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
_GDIPlus_GraphicsSetPixelOffsetMode($hCanvas, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
Local Const $hBrush_Clr = _GDIPlus_BrushCreateSolid(0xFF000000), _
$hBrush_FPS = _GDIPlus_BrushCreateSolid(0xFFFFFFFF), _
$hFormat_FPS = _GDIPlus_StringFormatCreate(), _
$hFamily_FPS = _GDIPlus_FontFamilyCreate("Arial"), _
$hFont_FPS = _GDIPlus_FontCreate($hFamily_FPS, 8), _
$tLayout_FPS = _GDIPlus_RectFCreate(0, 0, 130, 16)
$iFPS = 0
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit_About")
AdlibRegister("CalcFPS", 1000)
Local $a[3], $b = 1, $c, $x, $e, $y, $w, $h, $w2 = $iW_Dt / 2, $h2 = $iH_Dt / 2, $q, $r
If $iW_Dt > 1.5 * $iH_Dt Then
$q = $iW_Dt
$r = 0.75 * $iW_Dt
Else
$q = 1.5 * $iH_Dt
$r = 0.75 * $iH_Dt
EndIf
Do
For $e = 0 To 2
$a[$e] = $aImages[Mod(Floor($b) + $e, UBound($aImages))]
Next
$c = 2^(Mod($b, 1))
For $e = 0 To 2
$x = $w2 - $q / 2 * $c
$y = $h2 - $r / 2 * $c
$w = $q * $c
$h = $r * $c
$hObj = _WinAPI_SelectObject($hMemDC, $a[$e])
_WinAPI_StretchBlt($hDC_backbuffer, $x, $y, $w, $h, $hMemDC, 0, 0, $iW, $iH, $SRCCOPY)
$c *= 0.5
Next
$b += MouseZoom()
IF $b < 0 Then $b = UBound($aImages) - $b
_GDIPlus_GraphicsDrawStringEx($hCanvas, "FPS: " & $iShowFPS & " @ " & $iW_Dt & "x" & $iH_Dt & " px", $hFont_FPS, $tLayout_FPS, $hFormat_FPS, $hBrush_FPS)
_WinAPI_BitBlt($hDC, 0, 0, $iW_Dt, $iH_Dt, $hDC_backbuffer, 0, 0, $SRCCOPY)
$iFPS += 1
If $bExit Then ExitLoop
Until Not Sleep(0)
AdlibUnRegister("CalcFPS")
;release resources
_GDIPlus_FontDispose($hFont_FPS)
_GDIPlus_FontFamilyDispose($hFamily_FPS)
_GDIPlus_StringFormatDispose($hFormat_FPS)
_GDIPlus_BrushDispose($hBrush_Clr)
_GDIPlus_BrushDispose($hBrush_FPS)
_GDIPlus_GraphicsDispose($hCanvas)
_WinAPI_SelectObject($hMemDC, $hObj)
_WinAPI_DeleteDC($hMemDC)
_WinAPI_SelectObject($hDC_backbuffer, $DC_obj)
_WinAPI_DeleteDC($hDC_backbuffer)
_WinAPI_DeleteObject($hHBitmap)
_WinAPI_ReleaseDC($hGUI, $hDC)
For $i = 0 To UBound($aImages) - 1
_WinAPI_DeleteObject($aImages[$i])
Next
GUIDelete($hGUI)
EndFunc ;==>GDIPlus_ZoomImage
Func MouseZoom()
;https://www.arduino.cc/reference/en/language/functions/math/map/
Local $iInput = MouseGetPos(1), $iInMin = 0, $iInMax = @DesktopHeight, $iOutMin = 1, $iOutMax = -1, $iStep = 0.025
Return (($iInput - $iInMin) * ($iOutMax - $iOutMin) / ($iInMax - $iInMin) + $iOutMin) * $iStep
EndFunc ;MouseZoom()
Func _Exit_About()
$bExit = True
EndFunc ;==>_Exit_About
Func CalcFPS() ;display FPS
$iShowFPS = $iFPS
$iFPS = 0
EndFunc ;==>CalcFPS
Func Downloader()
Local $sURL, $i
For $i = 0 To 48
If Not FileExists(@ScriptDir & "\Images\Arkadia" & $i & ".jpg") Then
If Not FileExists(@ScriptDir & "\Images") Then DirCreate(@ScriptDir & "\Images")
$sURL = "http://arkadia.xyz/images/arkadia" & $i & ".jpg"
ConsoleWrite("Downloading " & $sURL & ": " & InetGet($sURL, @ScriptDir & "\Images\Arkadia" & $i & ".jpg", 8) & " bytes" & @CRLF)
ToolTip("Downloading images...Please wait! -> " & $i + 1 & " / " & $i, MouseGetPos(0), MouseGetPos(1))
EndIf
Next
ToolTip("")
EndFunc ;==>Downloader

Alles anzeigen

Quelle der Inspirationen / Bilder: http://zoomquilt.org/, http://arkadia.xyz

Ist schon ziemlich krass, wie flüssig der Zoom im Browser läuft...

PS: Zu Risiken und Nebenwirkungen lesen Sie die Packungsbeilage und fragen Sie Ihren Arzt oder Apotheker!

**Oscar** · 5. Januar 2018

Wow!

Das sieht echt klasse aus! Sowohl im Browser, als auch in Deinem Script.

Aber ich habe das Sleep in Zeile 98 auskommentiert: Until Not 1; Sleep(10)

So habe ich ca. 120 fps und das ruckeln zwischendurch tritt nicht mehr auf.

**UEZ** · 5. Januar 2018

Danke Oscar!

Ich habe noch ein zweites Beispiel hinzugefügt. Beide Scripte laufen jetzt im Vollbildmodus ab.

**Andy** · 5. Januar 2018

Das Stretchblt() ist, GDI+-typisch SCH***-langsam

Bei mir ( i7-7500U CPU @ 2.70GHz FullHD) dauert der Stretchblt() sagenhafte 25-35ms. Das BitBlt() gerade mal 1 ms....

Das wäre doch für Oscar ne schöne Übung für SSE-Befehle in ASM

**UEZ** · 5. Januar 2018

Andy schrieb:

Das Stretchblt() ist, GDI+-typisch SCH***-langsam

Stretchblt() ist GDI und nicht GDI+ (Klugshitting )

Na dann schaue dir mal die GDI+ Variante an.

Btw, ich habe die Source Codes ein bissl optimiert.

**xSunLighTx3** · 6. Januar 2018

Kuhle Sache!

Mir fällt auf, dass das Bild immer leicht unscharf wird beim Reinzoomen, bis das nächste Bild kommt.

Ist bei der Homepage Version nicht so.

Mein Prozessor packt gerade so 30-40 FPS.

Mit Irrlicht würde das bestimmt mit paar 1000 FPS laufen.

**Mars** · 6. Januar 2018

Eine AlphaBlend Funktion mit Skalierungsmethode haben wir vor ca. 5 Jahren doch mal irgendwo in ASM gebastelt... Ich finde sie aber nicht mehr

**Andy** · 6. Januar 2018

Alphablend hatte ich u.a. gecoded, war SEHR schnell, aber Skalierung? Bestimmt hatte ich aber auch so eine Funktion irgendwo....schaumamal, ansonsten bietet sich SSE wirklich an, 4 (in 64-Bit wären es Pixel gleichzeitig in einer Handvoll Takte zu berechnen hätte was.

xSunLighTx3 schrieb:

Mein Prozessor packt gerade so 30-40 FPS.

Mit Irrlicht würde das bestimmt mit paar 1000 FPS laufen.

OpenCL/OpenGL ftw.

**UEZ** · 6. Januar 2018

Alpha Blend kann man auch mit GDI+ hinbekommen.

Ich muss mal den JS Code genauer anschauen, wie dort die Implementierung ist.

xSunLighTx3 du kannst die Zeile

AutoIt

_WinAPI_SetStretchBltMode($hDC, $STRETCH_HALFTONE)

auskommentieren, dann wird's schneller.

**Bitnugger** · 6. Januar 2018

UEZ schrieb:

_WinAPI_SetStretchBltMode($hDC, $STRETCH_HALFTONE)

Wow... da schießt die v2.1 bei mir von 25 auf 250 Frames... und die v2.2 auf 400+... sehr schön gemacht!!!

**UEZ** · 7. Januar 2018

Wer Lust hat den JS Code zu analysieren, um zu sehen, warum in JS die Animation jeweils beim nächsten Bild nicht so aussieht, wie es oben aussieht, kann hier reinschauen:

https://codepen.io/Dunced/pen/ygNVeM

Habe ich per Zufall entdeckt.

Ich versuche gerade den Code zu verstehen...

Edit: Krass, die zeichnen 3 Bilder parallel, sodass nicht beim Wechsel zum nächsten Bild dies sichtbar wird. CleverDemnächst kommt das Update!

**UEZ** · 7. Januar 2018

Ok, ich habe die Trippel Bilder Technik implementiert -> siehe Post #1.

**Oscar** · 8. Januar 2018

Genial!

Die neuen Versionen sind unglaublich schnell (auf meinem Rechner mit 2560x1440 px Auflösung, bei beiden ca. 120 fps).

Und Deine Arkadia-Version gefällt mir besser als die JS-Version, weil sie nicht diesen Farbfilter darüberlegt.

**Xenobiologist** · 8. Januar 2018

Sehr schön, aber das Angucken macht einen auf Dauer irgendwie wahnsinnig.

**UEZ** · 8. Januar 2018

Oscar schrieb:

Genial!

Die neuen Versionen sind unglaublich schnell (auf meinem Rechner mit 2560x1440 px Auflösung, bei beiden ca. 120 fps).

Und Deine Arkadia-Version gefällt mir besser als die JS-Version, weil sie nicht diesen Farbfilter darüberlegt.

Du brauchst also nicht in die Hände spucken und eine schnelle ASM Version coden.

Xenobiologist schrieb:

Sehr schön, aber das Angucken macht einen auf Dauer irgendwie wahnsinnig.

Hmm, sollte noch einen Hinweis posten, dass das anschauen auf Dauer wahnsinnig machen kann, und ich dafür nicht haftbar gemacht werden kann.

**Andy** · 9. Januar 2018

UEZ schrieb:

Du brauchst also nicht in die Hände spucken und eine schnelle ASM Version coden.

...abwarten^^

Bei mir ist auf 3 Rechnern trotz 80-120FPS bei der AutoItversion immer noch eine unterschiedliche Geschwindigkeit im Endloszoom festzustellen. Im Browser gibt es weder (Mikro-) Ruckler noch dieses "pumpen".

Ich habe jetzt die schleife eingehend ausgestoppt und festgestellt, dass die Schleife

Code

For $e = 0 To 2
$d = $v - $q / 2 * $c
$f = $w - $r / 2 * $c
$g = $q * $c
$l = $r * $c
$hObj = _WinAPI_SelectObject($hMemDC, $a[$e])
_WinAPI_StretchBlt($hDC_backbuffer, $d, $f, $g, $l, $hMemDC, 0, 0, $iW, $iH, $SRCCOPY)
$c *= 0.5
Next

massive Unterschiede bei den einzelnen Stretchblt-Zeiten hat! Massiv heisst, der jeweils erste Stretchblt dauert ca. 5-10x länger als die beiden folgenden?!

Ich untersuche das mal genauer, inwieweit _WinAPI_SelectObject($hMemDC, $a[$e]) da einen Anteil dran hat. Ich vermute stark einen Zusammenhang mit dem darauffolgenden _GDIPlus_GraphicsDrawStringEx bzw. Bitblt.

**UEZ** · 9. Januar 2018

Ich vermute, dass die Unterschiede in der Größe der Bilder entstehen:

Code

1364.21582682873 x 1023.16187012155
682.107913414366 x 511.580935060774
2755.03740268449 x 2066.27805201337
1377.51870134225 x 1033.13902600669
688.759350671124 x 516.569513003343
2781.90259228807 x 2086.42694421605
1390.95129614404 x 1043.21347210803
695.475648072018 x 521.606736054013
2809.02975235046 x 2106.77231426285
1404.51487617523 x 1053.38615713142
702.257438087616 x 526.693078565712
2836.42143742358 x 2127.31607806768
1418.21071871179 x 1063.65803903384
709.105359355894 x 531.829019516921
2864.08022696951 x 2148.06017022714
1432.04011348476 x 1074.03008511357
716.020056742378 x 537.015042556784
2892.00872560348 x 2169.00654420261
1446.00436280174 x 1084.5032721013
723.002181400869 x 542.251636050652
2920.20956333905 x 2190.15717250429
1460.10478166952 x 1095.07858625214
730.052390834762 x 547.539293126071
2948.68539583585 x 2211.51404687689
1474.34269791793 x 1105.75702343845
737.171348958964 x 552.878511719223
2977.43890464965 x 2233.07917848724
1488.71945232483 x 1116.53958924362
744.359726162413 x 558.26979462181
3006.47279748484 x 2254.85459811363
1503.23639874242 x 1127.42729905681
751.61819937121 x 563.713649528407
3035.78980844945 x 2276.84235633709
1517.89490422473 x 1138.42117816855
758.947452112364 x 569.210589084273
3065.39269831263 x 2299.04452373447
1532.69634915632 x 1149.52226186724
766.348174578158 x 574.761130933618
3095.28425476458 x 2321.46319107344
1547.64212738229 x 1160.73159553672
773.821063691146 x 580.36579776836
3125.46729267913 x 2344.10046950935
1562.73364633956 x 1172.05023475467
781.366823169782 x 586.025117377337
3155.94465437875 x 2366.95849078406
1577.97232718938 x 1183.47924539203
788.986163594688 x 591.739622696016
3186.71920990227 x 2390.0394074267
1593.35960495113 x 1195.01970371335
796.679802475567 x 597.509851856675
1608.89692863755 x 1206.67269647816
804.448464318775 x 603.336348239081
402.224232159388 x 301.668174119541
1624.58576139109 x 1218.43932104332
812.292880695544 x 609.219660521658
406.146440347772 x 304.609830260829

Alles anzeigen

Btw, ich habe den Code aktualisiert. Nun kann man per Maus in beide Richtungen "fliegen".

**NO1 :-)** · 12. Januar 2018

Ja ist dir echt richtig gut gelungen... Habs gleich als Bildschirmschoner genommen... Schaut super aus

Infinite Image Zoom Flight build 2018-01-10

Statement zur DSGVO im Forum

Teilen

Tags