Du speicherst die Dateien in einem Ordner in $aFileList ab und verwendest das Array danach nicht mehr. Stattdessen holst du dir mit FileGetTime die Zeit von $sFilePath (was auch immer in $sFilePath drinne stehen mag).
Du musst dir alle Dateien holen, und dann anschließend die Zeiten vergleichen. Die Vergleiche kannst du mit den _Date*-Funktionen bewerkstelligen.
Wenn du dir die Mühe machen willst deinen Code zu verstehen, dann solltest du dir unbedingt die AutoIt-Grundlagen mal angucken und durcharbeiten.
Wenn du allerdings möchtest, dass dir jemand das vorcodet und du dir keine Mühe machen willst, dann poste bitte in der Programmieranfragen-Sektion.
Eine Antwort wie "Ok das krieg ich net zam:(" suggeriert mir, dass du dir keine Mühe machst sondern einfach alles vorgekaut hingesetzt haben möchtest.
Also bitte tu uns einen Gefallen und bring etwas Eigeninitiative mit oder lass deine Arbeit komplett von anderen erledigen.
Hallo Sascha123456 !
Ich gebe alpines völlig recht, dass Du Dir schon etwas mehr Mühe geben solltest. Die AutoIt-Hilfe enthält viele gute Beispiele ! Bei deinem Wissensstand ist die Aufgabe aber wohl nicht trivial (Sorry 
).
Daher hier ein Skript, welches die zuletzt modifizierte Datei in einem Verzeichnis ermittelt :
#include <File.au3>
#include <MsgBoxConstants.au3>
Global $sFilePath = @ScriptDir ; kompletten Pfad zum Basisverzeichnis eintragen
Global $sLatestFile
$sLatestFile = _FindLatestModifiedFile($sFilePath)
If @error Then
; Fehler 1 = Verzeichnis existiert nicht
; Fehler 2 = Verzeichnis ist leer
; Fehler 3 = Dateidatum kann nicht ermittelt werden
MsgBox($MB_SYSTEMMODAL, "Fehler", "Es ist ein Fehler aufgetreten : " & @error & @CRLF)
Exit
Else
MsgBox($MB_SYSTEMMODAL, "Datei gefunden", "Neueste Datei = " & $sLatestFile & @CRLF)
EndIf
; Funktionsbeschreibung :
; Findet die neueste Datei (nach Änderungsdatum) im angegebenen Verzeichnis.
; Parameter : $sBaseDir = Pfad zum Basisverzeichnis
Func _FindLatestModifiedFile($sBaseDir)
Local $hSearch, $sFile, $sFileTime
Local $aLatestFile[2] = [0, ""] ; [0]=Änderungsdatum / [1]=Dateiname
If StringRight($sBaseDir, 1) <> '\' Then $sBaseDir &= '\'
If Not FileExists($sBaseDir) Then Return SetError(1, 0)
$hSearch = FileFindFirstFile($sBaseDir & '*.*')
If $hSearch = -1 Then Return SetError(2, @error)
While 1
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
$sFileTime = FileGetTime($sBaseDir & $sFile, $FT_MODIFIED, $FT_STRING)
If $sFileTime > $aLatestFile[0] Then
$aLatestFile[0] = $sFileTime
$aLatestFile[1] = $sBaseDir & $sFile
EndIf
WEnd
FileClose($hSearch) ; Dateihandle schließen
If $aLatestFile[0] = 0 Then
Return SetError(3, 0)
Else
Return $aLatestFile[1]
EndIf
EndFunc ;==> _FindLastModifiedFileEdit :
Im Skript war noch ein kleiner Fehler : FileClose muss natürlich VOR die letzten Returns 
. ->Geändert !
Gruß Musashi
Oder so...
#Include <File.au3>
Local $sFilePath = @DesktopDir & "\Neuer Ordner\"
If Not FileExists($sFilePath) Then Exit ConsoleWrite('! $sFilePath existiert nicht!' & @CRLF)
; Dateiliste in Array einlesen
Local $aFileList = _FileListToArray($sFilePath, "*", $FLTA_FILES)
If @error Then Exit ConsoleWrite('! _FileListToArray Error: ' & @error & @CRLF)
; Erstellungsdatum der Dateien besorgen
_ArrayColInsert($aFileList, 0)
For $i = 1 To $aFileList[0][1] Step 1
$aFileList[$i][0] = FileGetTime($sFilePath & $aFileList[$i][1], $FT_CREATED, $FT_STRING)
If $aFileList[$i][0] = 0 Then Exit ConsoleWrite('! FileGetTime Error: ' & $sFilePath & $aFileList[$i][1] & @CRLF)
Next
_ArraySort($aFileList, 1, 1)
For $i = 1 To $aFileList[0][1] Step 1
ConsoleWrite(($i = 1 ? @CRLF & '! ' : $i = $aFileList[0][1] ? '- ' : '> ') & $aFileList[$i][0] & ' --> ' & StringRegExpReplace($aFileList[$i][0], '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})', '\3.\2.\1 \4:\5:\6 ') & $aFileList[$i][1] & @CRLF)
Next
ConsoleWrite(@CRLF)
;~ FileDelete($sFilePath & $aFileList[1][1]) ; <-- jüngste Datei
;~ FileDelete($sFilePath & $aFileList[$aFileList[0][1]][1]) ; <-- älteste DateiDanke für eure Mühe, ich habe jetzt das Skript zunächst einmal versucht zu verstehen von Bitnugger (da das kürzer ist), jedoch verstehe ich nicht was Zeile 12, 13, 17 und 18 genau tut? Den rest verstehe ich wenn ich es mir genau anschaue. 
Btw gibt es Übungen für Autoit Grundlagen etc?
Scripten, Scripten, Scripten. Übung macht den Meister.
entschuldigt bitte ich hab dann gestern Feierabend gemacht und es nicht mehr weiter probiert.
Hallo Sascha123456 !
Für einen wohlverdienten Feierabend muss man sich nicht entschuldigen .
Ich versuche aber es zu verstehen und gebe mir Mühe, allerdings wenn ich eure Scripte nun ansehe...da wäre ich nie so drauf gekommen mit dem Wissensstand.
Du kannst aber versuchen, sie schrittweise zu analysieren. Ob Du meinen Ansatz oder den von Bitnugger nimmst ist deine Entscheidung, und sowohl mir als sicher auch Bitnugger egal - Wir führen hier dbzgl. keinen Wettkampf. Hätte ich ein Skript für mich geschrieben, dann sähe es eher so aus wie das von Bitnugger !
Meine Variante dürfte für Dich aber vermutlich leichter nachvollziehbar sein, da ich, angesichts deiner momentanen Programmierfähigkeiten, auf z.B. Arrays und reguläre Ausdrücke verzichtet habe.
Das bedeutet aber ausdrücklich nicht, dass meine Variante 'besser' ist !
Danke für eure Hilfe und nochmal sry wenn ich nen unverschämten Eindruck hinterließ !
Btw. gibt es Übungen für Autoit Grundlagen etc ?
Freundlich gestellte Fragen sind nicht 'unverschämt'. Die Helfer hier im Forum möchten nur gerne sehen, dass sich der Fragesteller vorher in ausreichendem Maß selbst bemüht hat. Bereits nach 20 Minuten die Flinte ins Korn werfen wäre z.B. nicht ausreichend . Es ist nicht ungewöhnlich, dass man auch schon mal ein oder zwei Tage suchen muss, bevor man einen eigenen Skriptansatz hat. Den kann man dann posten, um nach Fehlern oder Anregungen zu fragen.
Ein komplettes 'AutoIt Buch' gibt es, meines Wissens, nicht (auf deutsch) zu kaufen.
Es gibt aber die Hilfe und viele Beispiele und Tutorials, sowohl hier, im englischen Forum als auch von Drittquellen wie z.B. Stackoverflow usw.
Falls Du mit englisch Probleme haben solltest, empfehle ich Dir den kostenlosen Online-Übersetzer unter https://www.deepl.com/translator . Nicht perfekt, aber zum Verstehen sind die übersetzten Texte, meiner Meinung nach, besser als die von Google.
P.S. :
ich habe jetzt das Skript zunächst einmal versucht zu verstehen von Bitnugger (da das kürzer ist)
Das ist völlig ok, aber verwechsle 'kürzer' nicht mit 'einfacher' 
Gruß Musashi
Ein komplettes 'AutoIt Buch' gibt es, meines Wissens, nicht (auf deutsch) zu kaufen.
peethebee hatte eins geschrieben und hier mal verlinkt aber das ist auch schon Ewigkeiten her (gab auch schon mehrfache Iterationen davon).
Der DL ist leider kaputt und vielleicht könnte das jemand ja nochmal hochladen, falls er es auf der Platte liegen hat.
Ich denke du meinstest dieses Buch von Johannes Mitlmeier, Bitteschön hier ist es.
Ich hoffe der Author hat nix gegen den Upload seines Buches.
Genau das meinte ich.
Oh super danke das werde ich mir mir anschauen!
Ich habe jetzt versucht das script von bItnugger noch ein wenig zu modifizieren, allerdings scheint es dort einen Fehler zu haben den ich nicht gefunden habe bisher.
Es kommt keine Fehlermeldung, es passiert einfach nach der Msgbox nix mehr.
#Include <File.au3>
Local $sFilePath = "T:\21. Messtechnik\Zeiss\Zeiss_Skripting\caq_vorbereitung"
If Not FileExists($sFilePath) Then Exit ConsoleWrite('! $sFilePath existiert nicht!' & @CRLF)
Global $bLoeschungabbruch
Switch MsgBox(64 + 4, "Bewertung", "War die Messung i.O?")
Case 6 ; Messung als i.O bewertet
$bLoeschungabbruch = True
Case 7 ; Messung als n.i.O bewertet
$bLoeschungabbruch = False
EndSwitch
If Not $bLoeschungabbruch Then
Local $aFileList = _FileListToArray($sFilePath, "*", $FLTA_FILES)
If @error Then Exit ConsoleWrite('! _FileListToArray Error: ' & @error & @CRLF)
; Erstellungsdatum der Dateien besorgen
_ArrayColInsert($aFileList, 0)
For $i = 1 To $aFileList[0][1] Step 1
$aFileList[$i][0] = FileGetTime($sFilePath & $aFileList[$i][1], $FT_CREATED, $FT_STRING)
If $aFileList[$i][0] = 0 Then Exit ConsoleWrite('! FileGetTime Error: ' & $sFilePath & $aFileList[$i][1] & @CRLF)
Next
_ArraySort($aFileList, 1, 1)
For $i = 1 To $aFileList[0][1] Step 1
ConsoleWrite(($i = 1 ? @CRLF & '! ' : $i = $aFileList[0][1] ? '- ' : '> ') & $aFileList[$i][0] & ' --> ' & StringRegExpReplace($aFileList[$i][0], '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})', '\3.\2.\1 \4:\5:\6 ') & $aFileList[$i][1] & @CRLF)
Next
ConsoleWrite(@CRLF)
FileDelete($sFilePath & $aFileList[1][1]) & MsgBox(16, "Info", "Letztes Protokoll wurde entfernt!") ; <-- jüngste Datei ;~ FileDelete($sFilePath & $aFileList[$aFileList[0][1]][1]) <-- älteste Datei
EndIf
Ich hab versucht mit einer Variblen ihm zu sagen ob er überhaupt löschen darf oder nicht, enstcheid durch die msgbox.
Btw wie fügt ihr Skripte im Forum ein ohne dabei den Thread ewig lang werden zu lassen?
PS: Englisch ist null problem nur ich raff einfach viele Funktionen noch net.
Kann höchstens daran liegen, dass dein Script schon bei dem 1. If sich beendet.
Du findest im Editor den "</>"-Button für Code, wähle als Sprache AutoIt aus und paste ihn dann rein.
MsgBox(64 + 4, "Bewertung", "War die Messung i.O?")
Naja, Du fragst, ob die Messung in Ordnung war und antwortest wahrscheinlich mit "Ja".
Ja, setzt aber die Variable $bLoeschungabbruch = True und If Not $bLoeschungabbruch Then führt den Code aber nur bei False aus.
Somit passiert also nichts.
Was willst Du denn erreichen?
Soll die letzte Datei gelöscht werden, wenn die Messung nicht in Ordnung war oder wenn sie in Ordnung war?
Was willst Du denn erreichen?
Soll die letzte Datei gelöscht werden, wenn die Messung nicht in Ordnung war oder wenn sie in Ordnung war?
Wenn sie nicht in Ordnung war soll sie gelöscht werden
Ich erreiche doch mit dem Status der Variablen ob es weiter läuft oder beendet wird, also true or false , oder irre ich mich da?
Versuche es mal damit :
#include <File.au3>
Global $sFilePath = "T:\21. Messtechnik\Zeiss\Zeiss_Skripting\caq_vorbereitung"
Global $sLatestFile, $bLoeschungabbruch
Switch MsgBox(32 + 4, "Bewertung", "War die Messung i.O ?")
Case 6 ; Messung als i.O bewertet
$bLoeschungabbruch = False
Case 7 ; Messung als n.i.O bewertet
$bLoeschungabbruch = True
EndSwitch
If Not $bLoeschungabbruch Then
$sLatestFile = _FindLatestModifiedFile($sFilePath)
FileDelete($sLatestFile) ; neueste Datei löschen
MsgBox(64, "Info", $sLatestFile & " wurde entfernt!") ;
EndIf
; ---------------------------------------------------------------
Func _FindLatestModifiedFile($sBaseDir)
Local $hSearch, $sFile, $sFileTime
Local $aLatestFile[2] = [0, ""] ; [0]=Änderungsdatum / [1]=Dateiname
If StringRight($sBaseDir, 1) <> '\' Then $sBaseDir &= '\'
If Not FileExists($sBaseDir) Then Return SetError(1, 0)
$hSearch = FileFindFirstFile($sBaseDir & '*.*')
If $hSearch = -1 Then Return SetError(2, @error)
While 1
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
$sFileTime = FileGetTime($sBaseDir & $sFile, $FT_MODIFIED, $FT_STRING)
If $sFileTime > $aLatestFile[0] Then
$aLatestFile[0] = $sFileTime
$aLatestFile[1] = $sBaseDir & $sFile
EndIf
WEnd
FileClose($hSearch) ; Dateihandle schließen
If $aLatestFile[0] = 0 Then
Return SetError(3, 0)
Else
Return $aLatestFile[1]
EndIf
EndFunc ;==> _FindLastModifiedFile