_GUICtrlComboBoxEx_Create - ausgewählten Wert ermitteln

**Tweaky**

Ich habe ein Problem mit _GUICtrlComboBoxEx_Create.

Ich möchte erst beim auswählen eines Eintrags diesen ermitteln.

Nun wird jedoch bei jedem überfahren eines Eintrags eine Wert ausgegeben.

Außerdem funktioniert es überhaupt nicht, wenn man noch ein Bild in der ComboBox hat.

Dann wird gar nichts ausgegeben.

Hat jemand einen Tipp für mich?

AutoIt

#Region    ;************ Includes ************
#Include <WindowsConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#EndRegion ;************ Includes ************

Opt("GUIOnEventMode", 1)

$hGui = GUICreate("Test", 400, 300)
GUISetState(@SW_SHOW)

Global $idCombo = _GUICtrlComboBoxEx_Create($hGui, "", 10, 10, 170, 200, $CBS_DROPDOWNLIST)
Global $hImagelist = _GUIImageList_Create(32, 32, 5, 3)
_GUICtrlComboBoxEx_SetImageList($idCombo, $hImagelist)
_GUIImageList_AddIcon($hImagelist, "shell32.dll", 10, True)
_GUICtrlComboBoxEx_AddString($idCombo, "Test", 0, 0)

Global $idCombo2 = _GUICtrlComboBoxEx_Create($hGui, "", 10, 100, 170, 200, $CBS_DROPDOWNLIST)
_GUICtrlComboBoxEx_AddString($idCombo2, "Test")

GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


While 1
    Sleep(10)
WEnd


Func _exit()
    Exit
EndFunc   ;==>_exit



Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $idCombo
            Switch $iCode
                Case $CBEN_GETDISPINFOA, $CBEN_GETDISPINFOW ; Gesendet, um Anzeigeinformationen über das Callback-Item abzurufen
                    ConsoleWrite($iCode & @tab & $CBEN_GETDISPINFOW & @CRLF)
                    Return 0
            EndSwitch

        Case $idCombo2
            Switch $iCode
                Case $CBEN_GETDISPINFOA, $CBEN_GETDISPINFOW ; Gesendet, um Anzeigeinformationen über das Callback-Item abzurufen
                    ConsoleWrite($iCode & @tab & $CBEN_GETDISPINFOW & @CRLF)
                    Return 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

**alpines**

WM_NOTIFY ist die falsche Nachricht um das Klicken eines Eintrages abzufangen, WM_COMMAND ist das was du suchst.

Damit kannst du klicks auf die ComboBox, die ImageList und beim Klicken des Eintrages abfangen. Je nachdem was passiert ist, wird der Notification Code gesetzt:

https://msdn.microsoft.com/en-us/library/…1(v=vs.85).aspx das CBN_SELCHANGE kommt als WM_COMMAND an.

AutoIt

#Region    ;************ Includes ************
#Include <WindowsConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#EndRegion ;************ Includes ************

Opt("GUIOnEventMode", 1)

$hGui = GUICreate("Test", 400, 300)
GUISetState(@SW_SHOW)

Global $idCombo = _GUICtrlComboBoxEx_Create($hGui, "", 10, 10, 170, 200, $CBS_DROPDOWNLIST)
Global $hImagelist = _GUIImageList_Create(32, 32, 5, 3)
_GUICtrlComboBoxEx_SetImageList($idCombo, $hImagelist)
_GUIImageList_AddIcon($hImagelist, "shell32.dll", 10, True)
_GUICtrlComboBoxEx_AddString($idCombo, "Test", 0, 0)

Global $idCombo2 = _GUICtrlComboBoxEx_Create($hGui, "", 10, 100, 170, 200, $CBS_DROPDOWNLIST)
_GUICtrlComboBoxEx_AddString($idCombo2, "Test")

GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While 1
    Sleep(10)
WEnd


Func _exit()
    Exit
EndFunc   ;==>_exi

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    ConsoleWrite("Control Identifier: " & _WinAPI_LoWord($wParam) & @CRLF)
    ConsoleWrite("Notification Code: " & _WinAPI_HiWord($wParam) & @CRLF)
    ConsoleWrite("Control Handle: " & $lParam & @CRLF)
    ConsoleWrite(@CRLF)

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

**Kanashius**

Was du suchst geht mit WM_COMMAND (Schau mal bei _GuiCtrlComboBox_Create)

So funktionierts:

AutoIt

#Region    ;************ Includes ************
#Include <WindowsConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#EndRegion ;************ Includes ************

Opt("GUIOnEventMode", 1)
$hGui = GUICreate("Test", 400, 300)
GUISetState(@SW_SHOW)
Global $idCombo = _GUICtrlComboBoxEx_Create($hGui, "", 10, 10, 170, 200, $CBS_DROPDOWNLIST)
Global $hImagelist = _GUIImageList_Create(32, 32, 5, 3)
_GUICtrlComboBoxEx_SetImageList($idCombo, $hImagelist)
_GUIImageList_AddIcon($hImagelist, "shell32.dll", 10, True)
_GUICtrlComboBoxEx_AddString($idCombo, "Test", 0, 0)
Global $idCombo2 = _GUICtrlComboBoxEx_Create($hGui, "", 10, 100, 170, 200, $CBS_DROPDOWNLIST)
_GUICtrlComboBoxEx_AddString($idCombo2, "Test")
GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    Sleep(10)
WEnd
Func _exit()
    Exit
EndFunc   ;==>_exit

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    $iCode = BitShift($wParam, 16) ; Hi Word
    ;ConsoleWrite($iCode&@crlf)
    Switch $hWndFrom
        Case $idCombo
            Switch $iCode
                Case $CBN_SELCHANGE
                    ConsoleWrite("SelectedIndex: "& _GUICtrlComboBoxEx_GetCurSel($idCombo) & @CRLF)
                    Return 0
            EndSwitch
        Case $idCombo2
            Switch $iCode
                Case $CBN_SELCHANGE
                    ConsoleWrite("SelectedIndex: "& _GUICtrlComboBoxEx_GetCurSel($idCombo) & @CRLF)
                    Return 0
            EndSwitch
    EndSwitch
EndFunc

Alles anzeigen

**Tweaky**

Danke euch beiden. Funktioniert