Listview - jede 2te Reihe Farbig hinterlegen

TheDeath24

Hallo zusammen,

ich habe seit langem mal wieder Zeit gefunden mit ein bisschen mit AutoIT auseinander zusetzen.

Ich bin dabei auf ein Problem gestoßen und hoffe das mir jemand weiterhelfen kann.

Ich habe ein Listview und wollte gerne jede 2te Reihe Farbig hinterlegt.

Klar geht das:

Code

 For $y= _FileCountLines( @ScriptDir & "\" & $datei) To 1 Step -1
   GUICtrlCreateListViewItem(FileReadLine ( @ScriptDir & "\" & $datei, $y), $listviewtmp)
   if $tmpfarbe=1 then
      GUICtrlSetBkColor(-1, 0x848484)
      $tmpfarbe=0
   Else
      $tmpfarbe=1
   Endif
Next

Leider geht das nicht wenn man dann hinterher das Listview mit _GUICtrlListView_AddItem zb erweitert.

Vielleicht habe ich auch einfach ein Denkfehler?

**alpines**

Du musst das neue Item logischerweise auch färben, da musst du den Zähler auch verwenden.

TheDeath24

Aber leider färbt sich der neu Eintrag oder der 2te nicht. Kommt auf den Status der $tmpfarbe Variable an.

Code

if $msg = $neuenauftraganlegen then
            _GUICtrlListView_AddItem($idListview, "", 0)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "", 1)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "Neu", 2)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "Neu", 3)
            if $tmpfarbe=1 then
                  GUICtrlSetBkColor(-1, 0x848484)
                  $tmpfarbe=0
            Else
                  $tmpfarbe=1
            Endif

Endif

Alles anzeigen

Ich denke das -1 das Problem sein wird oder?

Code

GUICtrlSetBkColor(-1, 0x848484)

**alpines**

Probiers mal aus, ersetz das -1 mit dem Rückgabewert (dem Handle) von _GUICtrlListView_AddItem.

TheDeath24

Erstmal danke für die schnellen Antworten alpines.

Ich habe deinen Rat befolgt aber leider keine Änderung.

Ich habe nochmal kontrolliert ob sich beim Drücken des Buttons die $tmpfarbe auch ändert und habe mit die Ausgabe in die Console geschrieben.

Der Wert ändert sich doch leider bringt der Befehl zum ändern der Farbe nix.

Code

if $msg = $neuenauftraganlegen then
            Local $hlistviewadditem = _GUICtrlListView_AddItem($idListview, "", 0)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "", 1)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "Neu", 2)
            _GUICtrlListView_SetItemText($idListview, _GUICtrlListView_GetItemCount($idListview)-1, "Neu", 3)
            ConsoleWrite("Farbe= " & $tmpfarbe)
            if $tmpfarbe=1 then
               GUICtrlSetBkColor($hlistviewadditem, 0x848484)
               $tmpfarbe=0
            Else
               $tmpfarbe=1
            Endif
         Endif

Alles anzeigen

timee000

Theoretisch könntest du auch mit GUICtrlCreateListViewItem arbeiten. Dort werden alle Werte auf einmal eingetragen die durch | getrennt sein müssen.

Und jede zweite Zeile zu markieren kannst du einfacher machen, in dem du einfach die Zahlen im For-Loop auf gerade/ungerade überprüfst mit Mod.

Code

if $msg = $neuenauftraganlegen then
    $id = GUICtrlCreateListViewItem("Feld 1|Feld 2|Feld 3", $idListView)
    If Mod($y, 2) Then GUICtrlSetBkColor($id, 0x848484)
Endif

**alpines**

Dann probiers mal mit der internen Funktion, damit klappts ganz sicher:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Form1", 394, 298, 192, 124)
$ListView1 = GUICtrlCreateListView("|||||", 8, 8, 378, 230)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 4, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 5, 50)
$Button1 = GUICtrlCreateButton("Button1", 8, 248, 377, 41)
GUISetState(@SW_SHOW)

$b = False

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            $hItem = GUICtrlCreateListViewItem("a", $ListView1)
            GUICtrlSetBkColor($hItem, $b ? 0xFF0000 : 0x00FF00)
            $b = Not $b

    EndSwitch
WEnd

Alles anzeigen

**autoiter**

Sorry OT:

Das finde ich ja einen coolen Einsatz des ternären Operators alpines. Werde ich mir merken.

Zitat von alpines

GUICtrlSetBkColor($hItem, $b ? 0xFF0000 : 0x00FF00)

TheDeath24

Hey zusammen,

vielen Dank für die Antworten.

Ich habe das Script von dir alpines genommen aber muss leider sagen verstehen nicht ganz den Teil:

GUICtrlSetBkColor($hItem, $b ? 0xFF0000 : 0x00FF00)

Den ersten Teil versteh ich noch aber $b ? 0xFF0000 : 0x00FF00) der Teil ist mir neu. So noch nicht gesehen.

Die beiden Farben sind mir auch noch Klar.

Danke für die Hilfe.

**alpines**

Zitat von TheDeath24

Den ersten Teil versteh ich noch aber $b ? 0xFF0000 : 0x00FF00) der Teil ist mir neu. So noch nicht gesehen.

Das ist der sogenannte "ternäre Operator". Der wurde mit 3.3.10.2(?) eingeführt und erlaubt es If-Abfragen inline zu schreiben.

Der Teil links von dem Fragezeichen entspricht der Bedingung eines If-Blocks und der danach sind die jeweiligen Werte.

Vor dem Doppelpunkt wird das zurückgegeben, wenn die Bedingung True ist und nach dem Doppelpunkt, wenn sie Bedingung false ist.

Damit kann man sich ein paar Zeilen sparen:

AutoIt

$bZustand = ...
$sVariable = ""

If $bZustand = True Then
    $sVariable = 4
Else
    $sVariable = 5
EndIf

;Und mit dem ternären Operatoren sieht das ganze so aus:
$sVariable = $bZustand ? 4 : 5

Alles anzeigen

TheDeath24

Zitat von alpines
Das ist der sogenannte "ternäre Operator". Der wurde mit 3.3.10.2(?) eingeführt und erlaubt es If-Abfragen inline zu schreiben.

Der Teil links von dem Fragezeichen entspricht der Bedingung eines If-Blocks und der danach sind die jeweiligen Werte.

Vor dem Doppelpunkt wird das zurückgegeben, wenn die Bedingung True ist und nach dem Doppelpunkt, wenn sie Bedingung false ist.

Damit kann man sich ein paar Zeilen sparen:
AutoIt
$bZustand = ...
$sVariable = ""

If $bZustand = True Then
    $sVariable = 4
Else
    $sVariable = 5
EndIf

;Und mit dem ternären Operatoren sieht das ganze so aus:
$sVariable = $bZustand ? 4 : 5
Alles anzeigen

Super vielen Dank für die Erklärung.

**Raupi**

Das wichtigste ist aber immer zu beachten das man die UDF Funktionen auf Standard Controls anwenden kann, aber nicht andersrum.

Standard Controls geben in der Regel immer beim erstellen eine ControlID und kein Handle zurück.

UDF Funktionen hingegen geben beim erstellen ein Handle zurück und keine ConrolID.

GUICtrlSetBkColor wir also niemals bei einem ListviewItem funktionieren, das per UDF Funktion erstellt wurde.