Fensterpostition beim Minimieren speichern.

Superdau

Habe folgendes Problem: beim schließen meines Fensters funktioniert das Positionsspeichern, doch beim Minimieren nicht!

Ich komm nicht drauf warum

Hat jemand eine Idee?

AutoIt

Select
      Case $msg = $GUI_EVENT_CLOSE
         _possave($version)
         _exit ("Standard-Exit")
      Case $msg = $GUI_EVENT_MINIMIZE
         _possave ($version)
.
.
.
Func _possave ($win)
   $pos=WinGetPos($win)
      if $pos[0]>0 then
         IniWrite($userconf,$win,"xpos",$pos[0])
         IniWrite($userconf,$win,"ypos",$pos[1])
      EndIf
EndFunc

Alles anzeigen

**autoiter**

Hallo Superdau

Das liegt daran, dass du die Fensterposition erst ausliest, wenn das Fenster bereits minimiert ist. Ich weiß nicht, wie man da die letzte Postion zuvor auslesen kann. Daher würde ich die Position immer speichern, wenn sich die Position verändert. In die Ini brauchst du das ja nur speichern, wenn das Fenster geschlossen wird. Am besten nutzt du WM_MOVE.

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("Test")


GUISetState()

GUIRegisterMsg($WM_MOVE, "_WM_MOVE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    $aPos = WinGetPos($hGUI)

    If IsArray($aPos) Then
        If $aPos[0] <> -32000 Then
            ConsoleWrite($aPos[0] & " " & $aPos[1] & @CRLF)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_MOVE

Alles anzeigen

**Bitnugger**

Zitat von autoiter

Ich weiß nicht, wie man da die letzte Postion zuvor auslesen kann.

Ermitteln mit _WinAPI_GetWindowPlacement bzw. setzen mit _WinAPI_SetWindowPlacement

Superdau

Super Lösung danke!

Zitat von autoiter
Hallo Superdau

Das liegt daran, dass du die Fensterposition erst ausliest, wenn das Fenster bereits minimiert ist. Ich weiß nicht, wie man da die letzte Postion zuvor auslesen kann. Daher würde ich die Position immer speichern, wenn sich die Position verändert. In die Ini brauchst du das ja nur speichern, wenn das Fenster geschlossen wird. Am besten nutzt du WM_MOVE.
C
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("Test")


GUISetState()

GUIRegisterMsg($WM_MOVE, "_WM_MOVE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    $aPos = WinGetPos($hGUI)

    If IsArray($aPos) Then
        If $aPos[0] <> -32000 Then
            ConsoleWrite($aPos[0] & " " & $aPos[1] & @CRLF)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_MOVE
Alles anzeigen

**alpines**

Zitat von Bitnugger

Ermitteln mit _WinAPI_GetWindowPlacement bzw. setzen mit _WinAPI_SetWindowPlacement

Sehr schöne Funktion! Viel eleganter als mit jedem WM_MOVE die Koordinaten zu speichern und zu prüfen ob sie < -32000 sind (wenn minimiert).

**autoiter**

Hallo Bitnugger

Zitat von Bitnugger

Ermitteln mit _WinAPI_GetWindowPlacement bzw. setzen mit _WinAPI_SetWindowPlacement

Nice! Danke für die Info.

Superdau

Zitat von Bitnugger

Ermitteln mit _WinAPI_GetWindowPlacement bzw. setzen mit _WinAPI_SetWindowPlacement

Vielen Dank, das ist noch eleganter.

Gelöst

Code

Func _possave ($winh,$win)
   $tRET = _WinAPI_GetWindowPlacement($winh)
   IniWrite($userconf,$win,"xpos",DllStructGetData($tRET, "rcNormalPosition", 1))
   IniWrite($userconf,$win,"ypos",DllStructGetData($tRET, "rcNormalPosition", 2))
EndFunc

**Bitnugger**

Zudem ist die X/Y-Position bei minimiertem Fenster (ptMinPosition) nicht unbedingt -32000, wie hier im Beispiel gut zu sehen ist.

C

;-- TIME_STAMP   2018-04-06 11:22:54   v 0.1

; AutoIt <= v3.3.14.2
;~ #include <WinAPI.au3>

; AutoIt >= v3.3.14.3
#include <WinAPISysWin.au3>
#include <WinAPIProc.au3>

_Example(WinGetHandle('[CLASS:SciTEWindow]'))
ConsoleWrite('---------------------------------------------------------------------------------------' & @CRLF)
_Example(WinGetHandle('[CLASS:Progman]'))

Func _Example($hWnd)
    Local $sMsg, $sTitle = WinGetTitle($hWnd), $iPID = WinGetProcess($hWnd), $sProcess = _WinAPI_GetProcessName($iPID)
    Local $tRET = _WinAPI_GetWindowPlacement($hWnd)
    $sMsg &= @TAB & "$hWnd     = " & $hWnd & @CRLF
    $sMsg &= @TAB & "$sTitle   = " & $sTitle & @CRLF
    $sMsg &=  & "$sProcess = " & $sProcess & @CRLF & @CRLF
    $sMsg &= "$stWindowPlacement: " & @CRLF
    $sMsg &= @TAB & "length    = " & DllStructGetData($tRET, "length") & @CRLF
    $sMsg &= @TAB & "flags     = " & DllStructGetData($tRET, "flags") & @CRLF
    $sMsg &= @TAB & "showCmd   = " & DllStructGetData($tRET, "showCmd") & @CRLF & @CRLF
    $sMsg &= "ptMinPosition:" & @CRLF
    $sMsg &= @TAB & "MinX      = " & DllStructGetData($tRET, "ptMinPosition", 1) & @CRLF
    $sMsg &= @TAB & "MinY      = " & DllStructGetData($tRET, "ptMinPosition", 2) & @CRLF & @CRLF
    $sMsg &= "ptMaxPosition:" & @CRLF
    $sMsg &= @TAB & "MaxX      = " & DllStructGetData($tRET, "ptMaxPosition", 1) & @CRLF
    $sMsg &= @TAB & "MaxY      = " & DllStructGetData($tRET, "ptMaxPosition", 2) & @CRLF & @CRLF
    $sMsg &= "rcNormalPosition:" & @CRLF
    $sMsg &= @TAB & "left      = " & DllStructGetData($tRET, "rcNormalPosition", 1) & @CRLF
    $sMsg &= @TAB & "top       = " & DllStructGetData($tRET, "rcNormalPosition", 2) & @CRLF
    $sMsg &= @TAB & "right     = " & DllStructGetData($tRET, "rcNormalPosition", 3) & @CRLF
    $sMsg &= @TAB & "bottom    = " & DllStructGetData($tRET, "rcNormalPosition", 4)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

Alles anzeigen

Ausgabe:

Code

    $hWnd     = 0x00160360
    $sTitle   = M:\Autoit\_GetWindowPlacement.au3 - SciTE [10 von 10]
    $sProcess = SciTE.exe

$stWindowPlacement: 
    length    = 44
    flags     = 2
    showCmd   = 3

ptMinPosition:
    MinX      = -32000
    MinY      = -32000

ptMaxPosition:
    MaxX      = -1
    MaxY      = -1

rcNormalPosition:
    left      = 858
    top       = 213
    right     = 1498
    bottom    = 879
---------------------------------------------------------------------------------------
    $hWnd     = 0x000103BA
    $sTitle   = Program Manager
    $sProcess = explorer.exe

$stWindowPlacement: 
    length    = 44
    flags     = 0
    showCmd   = 1

ptMinPosition:
    MinX      = -1
    MinY      = -1

ptMaxPosition:
    MaxX      = -1
    MaxY      = -1

rcNormalPosition:
    left      = -1920
    top       = 0
    right     = 1920
    bottom    = 1080

Alles anzeigen

**alpines**

Ich weiß, hatte bei mir vorher Abs($xPos) < 30000 weil ich das auch bemerkt hatte.