Fenster ohne Titelleiste

Mikki

Hallo zusammen,

ich habe da mal eine Frage.

Wenn ich mir ein Fenster erzeugt habe ohne die Titelleiste, wie kann ich dann das Fenster wieder verschieben? Also packen und an eine andere Position auf dem Monitor verschieben.

Anbei der Code. Der dient nur als Beispiel.

C

#include <StaticConstants.au3>
#include <WindowsConstants.au3>


#Region Deklaration

Global $Window_Main

Global $Button[3]

#EndRegion Deklaration




Opt("GUIOnEventMode", 1)
Opt("MustDeclareVars", 1)

$Window_Main = GUICreate("lmc", 510, 500, Default, Default, BitOr($WS_BORDER, $WS_POPUP))
GUISetBkColor(0x7f8c8d, $Window_Main)

$Button[0] = GUICtrlCreateLabel("Test", 10, 460, 160, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetFont($Button[0], 11, 900)
GUICtrlSetColor($Button[0], 0xFFFFFF)
GUICtrlSetBkColor($Button[0], 0xFF690F)

$Button[1] = GUICtrlCreateLabel("_", 400, 0, 50, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetOnEvent($Button[1], "MINIMIZE_clicked_Window_Main")
GUICtrlSetFont($Button[1], 11, 900)
GUICtrlSetColor($Button[1], 0xFFFFFF)
GUICtrlSetBkColor($Button[1], 0x3498db)

$Button[2] = GUICtrlCreateLabel("X", 460, 0, 50, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetOnEvent($Button[2], "CLOSE_clicked_Window_Main")
GUICtrlSetFont($Button[2], 11, 900)
GUICtrlSetColor($Button[2], 0xFFFFFF)
GUICtrlSetBkColor($Button[2], 0xe74c3c)

GUISetState(@SW_SHOW)

While 1
    Sleep(50)
WEnd


Func CLOSE_clicked_Window_Main()
    Exit
EndFunc

Func MINIMIZE_clicked_Window_Main()
    GUISetState(@SW_MINIMIZE, $Window_Main)
EndFunc

Alles anzeigen

Mit freundlichen Grüßen

Mikki

**alpines**

Da bietet sich der Extended Style $GUI_WS_EX_PARENTDRAG an, damit kannst du Labels nutzen um dein Fenster zu verschieben.

Allerdings legt sich dann das Label über die anderen Controls und die kannst das Fenster nicht mehr verschieben, wenn du es über die gesamte GUI streckst.

In deinem Beispiel bietet sich an oben ein Labelrechteck zu definieren und es als Titelleiste zu nutzen.

AutoIt

#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>


#Region Deklaration

Global $Window_Main

Global $Button[3]

#EndRegion Deklaration




Opt("GUIOnEventMode", 1)
Opt("MustDeclareVars", 1)

$Window_Main = GUICreate("lmc", 510, 500, Default, Default, BitOr($WS_BORDER, $WS_POPUP))
GUISetBkColor(0x7f8c8d, $Window_Main)

GUICtrlCreateLabel("", 0, 0, 390, 30, $SS_WHITERECT, $GUI_WS_EX_PARENTDRAG)

$Button[0] = GUICtrlCreateLabel("Test", 10, 460, 160, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetFont($Button[0], 11, 900)
GUICtrlSetColor($Button[0], 0xFFFFFF)
GUICtrlSetBkColor($Button[0], 0xFF690F)

$Button[1] = GUICtrlCreateLabel("_", 400, 0, 50, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetOnEvent($Button[1], "MINIMIZE_clicked_Window_Main")
GUICtrlSetFont($Button[1], 11, 900)
GUICtrlSetColor($Button[1], 0xFFFFFF)
GUICtrlSetBkColor($Button[1], 0x3498db)

$Button[2] = GUICtrlCreateLabel("X", 460, 0, 50, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetOnEvent($Button[2], "CLOSE_clicked_Window_Main")
GUICtrlSetFont($Button[2], 11, 900)
GUICtrlSetColor($Button[2], 0xFFFFFF)
GUICtrlSetBkColor($Button[2], 0xe74c3c)

GUISetState(@SW_SHOW)
ControlFocus($Window_Main, "", $Button[2])

While 1
    Sleep(50)
WEnd


Func CLOSE_clicked_Window_Main()
    Exit
EndFunc

Func MINIMIZE_clicked_Window_Main()
    GUISetState(@SW_MINIMIZE, $Window_Main)
EndFunc

Alles anzeigen

**autoiter**

Hallo Mikki

Darüber hinaus, ist dieser Artikel für dich interessant: https://www.autoitscript.com/wiki/Moving_an…zing_PopUp_GUIs

Mikki

Hallo zusammen,

alpines : Vielen lieben Dank. Genau das was ich gesucht habe. Ich wollte das auch so machen, dass ich nur da oben dann packen und verschieben kann.

autoiter : Danke für den Hinweis. Werde ich mir nachher mal genauer anschauen ,-)

Mit freundlichen Grüßen

Mikki