Position der Einfügemarke

AutoMit

Guten Abend,

ich suche die Position der Einfügemarke unter Windows 8 / 64 bezogen auf (a) das aktive Fenster (b) auf den Bildschirm.

Mit welcher Funktion / API kann ich die Position der Einfügemarke ermitteln?

Ich möchte die Position speichern und wiederherstellen.

Effektiv suche ich in Analogie sowas wie

MouseGetPos - Ermittelt die aktuelle Position des Mauscursors.

... für den Textcursor / die Einfügemarke.

vielen Dank

Tuxedo

Diese beiden Befehle dürften deine Wünsche perfekt erfüllen.

WinGetCaretPos()

#include <WinAPIRes.au3>
_WinAPI_GetCaretPos ( )

Hoffe das passt für dich.

AutoMit

Vielen Dank Tuxedo.

Ich habe das heute probiert - bei Notepad z.B. erhalte ich Fehler 10.

Auch bei anderen zuvor mit WinActivate aktivierten Fenstern - kein Erfolg.

#include <Array.au3>

#include <WinAPIRes.au3>

$aTextCursorPosition = _WinAPI_GetCaretPos ( )

ConsoleWrite (@ScriptLineNumber & @TAB & "@error = " & @error & @CRLF)

_ArrayDisplay ( $aTextCursorPosition )

Array wird nicht angezeigt.

Auch mit WinGetCaretPos() hatte ich keinen Erfolg.

Zu müde für heute - ich versuche es die nächsten Tage nochmal, wenn ich wieder AutoIt-Themen beackern kann

Danke

**Bitnugger**

Schau dir mal die Funktion _WinAPI_CreateCaret an... wird das Fenster inaktiv, wird das (rote) Caret ausgeblendet.

AutoIt

#include <Array.au3>
#include <WinAPIRes.au3>
#include <WinAPIError.au3>

$aTextCursorPosition = _WinAPI_GetCaretPos() ; Error 10
If @error Then
    Exit ConsoleWrite(StringFormat('! %-27s = %i\n! %-27s = %i\n! %-27s = %s\n', '@error', @error, '_WinAPI_GetLastError', _WinAPI_GetLastError(), '_WinAPI_GetLastErrorMessage', _WinAPI_GetLastErrorMessage()))
EndIf
_ArrayDisplay($aTextCursorPosition)

Tuxedo

Entschuldige AutoMit , das hätte ich eigentlich noch wissen können, habs aber wohl vergesssen.

Ich hatte mal damit expermimentiert einen Markierungsbereich auf dem Desktop abhängig vom

Textcursor zu verschieben, das hat damals nicht funktioniert.

Der Grund war, daß die Position ständig 15 bis 20 Zeichen oder mehr daneben lag, es hat nie richtig funktioniert und ich habs dann einfach

ohne Autoit auf andere Weise gelöst. Aber eine Fehlermeldung gabs bei mir niemals, war aber auch noch Version 3.3.8.1,

Dafür steht das mit den falschen Positionen jetzt sogar in der Hilfe.

AutoMit

Danke Tuxedo, ich habe das in der Hilfe gelesen. Ich schaffe es leider gar nicht, Positionswerte zu erhalten.

Danke Bitnugger, _WinAPI_CreateCaret schaue ich mir an - zuerst das, was nach mehreren Versuchen in unterschiedlichen Fenstern bei Deinem Code herausgekommen ist

Zitat von Bitnugger

ConsoleWrite(StringFormat('! %-27s = %i\n! %-27s = %i\n! %-27s = %s\n', '@error', @error, '_WinAPI_GetLastError', _WinAPI_GetLastError(), '_WinAPI_Get

Vielen Dank für Deine Zeilen. Ich habe den Code bei Notepad ausprobiert und erhielt folgende Fehlermeldung:

! @error = 10

! _WinAPI_GetLastError = 998

! _WinAPI_GetLastErrorMessage = Unzulässiger Zugriff auf einen Speicherbereich.

Eine härtere Nuss, als ich dachte. Der Textcursor ist fast ständig zu sehen und nicht zu erwischen

Gibt es noch eine alternative Möglichkeit seine Position zu ermitteln?

Windows muss doch ständig wissen, wo er sich befindet, sonst könnte der Text nicht an der richtigen Stelle eingegeben werden.

Tuxedo

Na Endlich, irgendein Ergebnis muss ja möglich sein, hab dir hier ein Script

mit Ergebnissen und ohne Fehler, und merkwürdigen Ergebnissen , aber immerhin gibts ein Ergebnis.

Mehr Infos musst selbst rausfinden

Achja mein System ist Win7 x64, hoffe es funzt auch bei deinem Win 8 x64.

**BugFix**

_WinApi_GetCaretPos scheint falsch implementiert zu sein, liefert immer einen Fehler.

Zur Positionsbestimmung des Cursors aber auch völlig unnötig:

AutoIt

ShellExecute('notepad')
Local $hWndNotepad = WinWait('[CLASS:Notepad]', '', 5)
Local $aCaret = WinGetCaretPos()
Local $xCaret = $aCaret[0]
Local $yCaret = $aCaret[1]

; zum Vergleich Maus auf Cursorpos bewegen
MouseMove($xCaret, $yCaret, 30)

**Bitnugger**

Zitat von BugFix

_WinApi_GetCaretPos scheint falsch implementiert zu sein, liefert immer einen Fehler.

Schau dir mal die Funktion _WinAPI_CreateCaret an...

WinGetCaretPos liefert zumindest bei mir auf Win 10 X64 nicht die korrekte y-Pos.

So stimmt die Position:

AutoIt

;-- TIME_STAMP   2018-04-27 18:41:21   v 0.1

_Example1()
_Example2()

Func _Example1()
    Local $hWnd = WinWait('[CLASS:SciTEWindow]', '', 5)
    Local $aCaret = _GetCaretPos($hWnd)

    ; Maus zu Caretpos bewegen
    If Not @error Then MouseMove($aCaret[0], $aCaret[1], 30)
    Sleep(2222)
EndFunc

Func _Example2()
    ShellExecute('notepad')
    Local $hWnd = WinWait('[CLASS:Notepad]', '', 5)
    Local $aCaret = _GetCaretPos($hWnd)

    ; Maus zu Caretpos bewegen
    If UBound($aCaret) Then MouseMove($aCaret[0], $aCaret[1], 30)
    Sleep(2222)
    ProcessClose(WinGetProcess($hWnd))
EndFunc

Func _GetCaretPos($hWnd)
    Local $sFocus, $hCtrl, $aPos, $aCaret
    $sFocus = StringRegExpReplace(ControlGetFocus($hWnd), '(.+[^0-9])(.+)', '[CLASS:\1; INSTANCE:\2]')
    If Not @extended Then Return SetError(1)
    $hCtrl = ControlGetHandle($hWnd, '', $sFocus)
    If @error Then Return SetError(2)
    $aPos = ControlGetPos($hCtrl, '', '')
    $aCaret = WinGetCaretPos()
    If @error Then Return SetError(3)
    $aCaret[0] += $aPos[0]
    $aCaret[1] += $aPos[1]
    Return $aCaret
EndFunc

Alles anzeigen

Edit: Zeile hinzugefügt: $aCaret[0] += $aPos[0]

AutoMit

Ich danke Euch 3 für die tolle Hilfe.

~~Das Beispiel von BugFix lief hier auf Anhieb. Bei den anderen beiden muss ich mich noch einarbeiten.~~

Problem doch nicht gelöst - dennoch ein wunderbares Wochenende

Zu früh gefreut - mit Notepad funktioniert es.

Code

Sleep (5000)                                                ;     Pause - um in ein x beliebiges Fenster zu klicken und die Maus zu verschieben
Local $aCaret = WinGetCaretPos()
Local $xCaret = $aCaret[0]
Local $yCaret = $aCaret[1]
; zum Vergleich Maus auf Cursorpos bewegen
MouseMove($xCaret, $yCaret, 30)

Schon bei bekannten Programmen wie dem Total Commander 9.x - TextCursor in der cmd-Zeile vom Total Commander - findet das Script den Cursor nicht.

Auch andere ( weniger bekannte ) Programme habe ich getestet, und gleiches Ergebnis - der Textcursor wird nicht gefunden.

Auch im FireFox - Cursor im Text hier im Forum - findet das Script den TextCursor nicht.

Gleiches gilt für die URL-Zeile von Chrome und FireFox.

Wer mag und den Total Commander hat, probiere es bitte, ob der TextCursor in der cmd-Zeile gefunden wird.

Dei URL-Zeile von Chrome und FireFox bieten sich ebenfalls für einen Test an.

Ich probiere die anderen Scripte eingehender aus - auf Anhieb funktionierte keines beim Total Commander.

Yjuq

Gibt es einen Grund warum du den Textmarker Position in der CMD erfassen willst? Was hast du denn überhaupt vor, bzw. was willst du erreichen. Für mich liest sich das so, als ob dein Lösungsweg zu deinem eigentlichen Problem komplett unpassend ist.

**Bitnugger**

Zitat von AutoMit

Schon bei bekannten Programmen wie dem Total Commander 9.x - TextCursor in der cmd-Zeile vom Total Commander - findet das Script den Cursor nicht.

Doch...

AutoIt

;-- TIME_STAMP   2018-04-27 23:39:51   v 0.1

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

If Not HotKeySet('{F5}', '_HotKey') Then Exit 111
If Not HotKeySet('{F6}', '_HotKey') Then Exit 222

#Region - GUI Create
GUICreate('', 400, 100)
GUICtrlCreateLabel('F5 = Move mouse to caret pos from active window', 10, 10, 380, 22)
GUICtrlCreateLabel('F6 = Exit', 10, 30, 380, 22)
GUISetState()
#EndRegion

#Region - GUI SwitchLoop
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            HotKeySet('{F5}')
            HotKeySet('{F6}')
            Exit
    EndSwitch
WEnd
#EndRegion

Func _GetCaretPos($hWnd)
    Local $sFocus, $hCtrl, $aPos, $aCaret
    $sFocus = StringRegExpReplace(ControlGetFocus($hWnd), '(.+[^0-9])(.+)', '[CLASS:\1; INSTANCE:\2]')
    If Not @extended Then Return SetError(1)
    $hCtrl = ControlGetHandle($hWnd, '', $sFocus)
    If @error Then Return SetError(2)
    $aPos = ControlGetPos($hCtrl, '', '')
    $aCaret = WinGetCaretPos()
    If @error Then Return SetError(3)
    $aCaret[0] += $aPos[0]
    $aCaret[1] += $aPos[1]
    Return $aCaret
EndFunc

Func _HotKey()
    Switch @HotKeyPressed
        Case '{F5}'
            Local $hWnd = WinGetHandle('[ACTIVE]')
            Local $aCaret = _GetCaretPos($hWnd)

            ; Maus zu Caretpos bewegen
            If UBound($aCaret) Then MouseMove($aCaret[0], $aCaret[1], 30)
        Case '{F6}'
            Exit
    EndSwitch
EndFunc

Alles anzeigen

Zitat von AutoMit

Dei URL-Zeile von Chrome und FireFox bieten sich ebenfalls für einen Test an.

Wenn du mit Au3Info keine Infos zu dem Control bekommst, dann funktioniert WinGetCaretPos auch nicht, weil es dann wohl keine Standard-Controls (Input/Edit) sind.

AutoMit

Zitat von Bitnugger

Wenn du mit Au3Info keine Infos zu dem Control bekommst, dann funktioniert WinGetCaretPos auch nicht, weil es dann wohl keine Standard-Controls (Input/Edit) sind.

Vielen Dank Bitnugger für Dein Script auf Basis von WinGetCaretPos.

Test-Taste F5 - eine gute Idee, so konnte ich viele Fenster unkompliziert testen.

Hast Du eine Idee, wie man die Einfügemarke in der URL-Zeile von Chrome / FireFox findet?

Die Windows API Funktion habe ich dafür nicht zum Laufen gebracht.

Zitat von Yjuq

Was hast du denn überhaupt vor, bzw. was willst du erreichen.

Es wurde gefragt, was der Hintergrund ist. Es gibt viele Anwendungszwecke, für die ich das nutzen möchte - einen hier stellvertretend:

Bei einer Textverarbeitung ist im Suchfeld eine DropDownListe integriert, für die die Au3Info keine Information liefert ( für das Suchfeld auch nicht).

Wenn sich die Einfügemarke in dem Suchfeld befindet, dann sollen automatisch die DropDownListe geöffnet werden und z.B. die Option "Alle" ausgewählt werden..

[Blockierte Grafik: https://i.imgur.com/w8yunPk.jpg]

Zum besseren Verständnis ein Bild

Gibt es eine bessere Möglichkeit, als das über die Position der Einführungsmarke zu realisieren?

PS:

Gibt es in den API Untiefen noch eine andere Möglichkeit, die Einfügemarke abzufragen, wenn es kein Standardkontrol ist?

Hoffentlich

**Bitnugger**

Zitat von AutoMit

Hast Du eine Idee, wie man die Einfügemarke in der URL-Zeile von Chrome / FireFox findet?

https://developer.mozilla.org/en-US/docs/Web/API/CaretPosition

Zitat von AutoMit

Bei einer Textverarbeitung ist im Suchfeld eine DropDownListe integriert, für die die Au3Info keine Information liefert ( für das Suchfeld auch nicht).

Hört sich an, als wenn du von einer ComboBox redest. Wenn du mit Au3Info keine Infos zu dem Control bekommst, dann ist es wohl auch keine Standard-Control, oder aber, die "ComboBox" befindet sich innerhalb eines Group-Controls... in dem Fall liefert Au3Info leider nur Infos zu diesem. Da wir aber nicht wissen, welche Textverarbeitung es ist, können wir nicht mehr dazu sagen.

Zitat von AutoMit

Wenn sich die Einfügemarke in dem Suchfeld befindet, dann sollen automatisch die DropDownListe geöffnet werden und z.B. die Option "Alle" ausgewählt werden..

Zitat von AutoMit

Gibt es eine bessere Möglichkeit, als das über die Position der Einführungsmarke zu realisieren?

Wenn es entscheidend ist, wo genau die Einfügemarke steht, dann nicht... aber das scheint nicht der Fall zu sein. In dem Fall würde es reichen danach zufragen, welches Control den Fokus hat.

ControlGetFocus ( "title" [, "text"] )

Bei einer ComboBox ginge das etwa so:

_GUICtrlComboBox_SetCurSel ( $hWnd [, $iIndex = -1] )

_GUICtrlComboBox_ShowDropDown ( $hWnd [, $bShow = False] )