Label zeigt Änderung nur auf Klick

bigeasy76

Hallo zusammen

ich komme bei einem Script einfach nicht weiter, gemäss allen Infos, die ich finden konnte, sollte das eigentlich funktionieren. Ich habe eine SMS-Box erstellt für den Versand von SMS. Die Idee ist nun, dass bei einem Label neben dem Feld für den Text die Anzahl eingegebener Zeichen erscheinen soll, zudem eine Anzeige, wieviel SMS es werden, jedes fasst 160 Zeichen, 800 ist die max. Anzahl Zeichen, also 5 SMS.

Dazu schrieb ich folgendes, damits nicht zuviel wird, nur der relevante Teil:

Code

Switch GUIGetMsg()
         Case $GUI_EVENT_CLOSE, $idENDE
            ExitLoop

         Case $idTEXT
            Local $ZAEHLER = 0
            $TEXTtemp = GUICtrlRead(6)
            $ZAEHLER = StringLen($TEXTtemp)
            GUICtrlSetData($idLABEL2, $ZAEHLER)

            Select
            Case $ZAEHLER <=160
               GUICtrlSetData($idLABEL4, 1)

            Case $ZAEHLER >160 And $ZAEHLER <=320
               GUICtrlSetData($idLABEL4, 2)

            Case $ZAEHLER >320 And $ZAEHLER <=480
               GUICtrlSetData($idLABEL4, 3)

            Case $ZAEHLER >480 And $ZAEHLER <=640
               GUICtrlSetData($idLABEL4, 4)

            Case $ZAEHLER >640
               GUICtrlSetData($idLABEL4, 5)
            EndSelect


         Case $idDEL
            GUICtrlSetData($idTEXT, "")
            GUICtrlSetData($idNR, "")

         Case $idSENDEN
            $NR = "0041"&GUICtrlRead(4)&GUICtrlRead(5)
            $TEXT = GUICtrlRead(6)
            MsgBox($MB_OKCANCEL, "Senden?", "http://www.lox24.eu/API/httpsms.php?konto=xxxxx&password=xxxxx&service=11171&from=0041442222222&to="& $NR &"&text="& $TEXT)

            $oIE.navigate("http://www.lox24.eu/API/httpsms.php?konto=xxxxx&password=xxxxx&service=11171&from=0041442222222&to="&$NR&"&text="&$TEXT)

      EndSwitch

Alles anzeigen

Nun ändert sich während der Texteingabe aber keines der zwei Labels, nur wenn man mit der Maus auf das Label klickt, kommt sofort die richtige Anzahl Zeichen und SMS, die Funktion an sich scheint also zu arbeiten.

Aber ich komme einfach nicht drauf, warum sich der Wert in den Labels nur auf Mausklick ändert.

Kann hier bitte jemand weiterhelfen? Vielen Dank jetzt schonmal!

LG Dani

**Bitnugger**

Hier eine kleine Demo...

AutoIt

;-- TIME_STAMP   2018-04-27 19:20:23   v 0.1

#Region    ;************ Includes ************
#Include <EditConstants.au3>
#Include <WinAPIConv.au3>
;~ #include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#EndRegion ;************ Includes ************

Global $g_idLabel, $g_idInput

_Main()

Func _Main()
    #Region - GUI Create
    GUICreate('WM_COMMAND-Demo', 180, 80)
    $g_idLabel = GUICtrlCreateLabel('Tippe hier irgendwas ein...', 10, 10, 160, 25)
    $g_idInput = GUICtrlCreateInput('', 10, 30, 160, 25)
    GUISetState()
    #EndRegion

    ; Sent when the user selects a command item from a menu, when a control sends a notification message to its parent window, or when an accelerator keystroke is translated.
    GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

    #Region - GUI SwitchLoop
    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
    #EndRegion
EndFunc

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
;~     ConsoleWrite('Return 0 $GUI_RUNDEFMSG' & @CRLF)
;~     Return $GUI_RUNDEFMSG
    Local $hWndFrom, $iIDFrom, $iCode, $sText
    $hWndFrom = $lParam
    $iIDFrom = _WinAPI_LoWord($wParam)
    $iCode = _WinAPI_HiWord($wParam)

    Switch $iIDFrom
        Case $g_idInput
            Switch $iCode
                Case $EN_CHANGE
                    $sText = GUICtrlRead($g_idInput)
                    GUICtrlSetData($g_idLabel, $sText ? $sText : 'Tippe hier irgendwas ein...')
            EndSwitch
        Case Else
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Alles anzeigen

bigeasy76

Hi Bitnugger

ich seh hier, dass der Aufruf der Funktion über GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND") gemacht wird, ich versteh die Funktionsweise hier noch nicht ganz. Laut Referenz sind $lParam und $wParam der 1. und 2. "Message Parameter" als Hex-Wert. Leider ist mir hier nicht ganz klar, was diese Parameter genau beinhalten, 1. und 2. Message Parameter.

Und bei den Funktionen _WinAPI_LoWord($wParam) und _WinAPI_HiWord($wParam) steht, diese liefern "the high/low word of a longword value". Mein Englisch ist hier leider nicht so gut, aber ich vermute, dass es hier nicht um Klein/Grossschrift geht, was sind denn High/Low Word?

**alpines**

Zitat von bigeasy76

ich versteh die Funktionsweise hier noch nicht ganz.

Das Event WM_COMMAND wird registriert und immer wenn die GUI von dem Betriebssystem die Nachricht WM_COMMAND erhält, wird die Funktion _WM_COMMAND ausgeführt.

Dabei beinhalten die Parameter wichtige Informationen wie z.B. welche GUI angeklickt, welche Nachricht abgeschickt wurde und noch andere Informationen.

$wParam und $lParam beinhalten wichtige Informationen zu dem Event, diese sind aber von Nachricht zu Nachricht unterschiedlich und können in der msdn nachgeschlagen werden.

Da man nur einen 4-Byte Wert in $wParam und $lParam zur Verfügung hat, versucht man z.B. X- und Y-Koordinaten (bei WM_MOUSEMOVE) in eine Variable zu packen indem man die Variable aufteilt.

Einige Nachrichten übergeben auch in den Variablen Pointer zu Strukturen um mehr Informationen zu übergeben.

Dabei teilt man einen 4-Byte Wert (was ein DWORD ist, DOUBLE WORD) in 2x 2-Byte Werte auf (2x WORD).

Mit _WinAPI_LoWord und _WinAPI_HiWord kriegt man dann die unterschiedlichen Bytes die dort gespeichert sind.

DWORD = FF FF FF FF, WORD = FF FF.

Rot = Low-Order Word, Blau = High-Order Word

In diesem Fall beinhaltet das LoWord von $wParam die ID des Controls an dem ein Event ausgelöst wurde und das HiWord von $wParam den genauen Eventcode.

Das wäre EN_CHANGE ~ EditNotify_Change(dInput).

bigeasy76

Vielen Dank schonmal. Müsste ich aber anstatt des Events WM_COMMAND in meinem Fall nicht den Event WM_KEYDOWN verwenden? Ich hab nun mal folgendes zusammengeschustert, ich glaube, man merkt, dass ich ein blutiger Anfänger bin, ist erst mein zweites Script:

Code

GUIRegisterMsg($WM_KEYDOWN, "SCHREIBEN")

   While 1
      Switch GUIGetMsg()
         Case $GUI_EVENT_CLOSE, $idENDE
            Exit
      EndSwitch
   WEnd
EndFunc

Func SCHREIBEN()
   Switch GUIGetMsg()
      Case $idTEXT
         Local $ZAEHLER = 0
         $TEXTtemp = GUICtrlRead($idTEXT)
         $ZAEHLER = StringLen($TEXTtemp)
         GUICtrlSetData($idLABEL2, $ZAEHLER)

         Select
            Case $ZAEHLER <=160
               GUICtrlSetData($idLABEL4, 1)

            Case $ZAEHLER >160 And $ZAEHLER <=320
               GUICtrlSetData($idLABEL4, 2)

            Case $ZAEHLER >320 And $ZAEHLER <=480
               GUICtrlSetData($idLABEL4, 3)

            Case $ZAEHLER >480 And $ZAEHLER <=640
               GUICtrlSetData($idLABEL4, 4)

            Case $ZAEHLER >640
               GUICtrlSetData($idLABEL4, 5)
         EndSelect


      Case $idDEL
         GUICtrlSetData($idTEXT, "")
         GUICtrlSetData($idNR, "")

      Case $idSENDEN
         $NR = "0041"&GUICtrlRead(4)&GUICtrlRead(5)
         $TEXT = GUICtrlRead(6)
         MsgBox($MB_OKCANCEL, "Senden?", "http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041442222222&to="& $NR &"&text="& $TEXT)

         $oIE.navigate("http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041442222222&to="&$NR&"&text="&$TEXT)

   EndSwitch
   GUIDelete()
EndFunc

Alles anzeigen

Nun passiert aber gar nichts mehr, auch bei Klick ins Label bleibt die Null. Meine Vermutung ist, dass die Funktion SCHREIBEN schon gar nicht aufgerufen wird, aber warum, ist mir nicht ganz klar. In der Referenz steht zu GUIRegisterMsg(), dass in der aufzurufenden Funktion nicht mehr als 4 Variablen definiert sein dürften, sonst werde die Funktion nicht aufgerufen. Aber müssen denn überhaupt Variablen definiert sein oder gehts auch ohne? Oder liegt der Fehler vielleicht doch woanders?

**Oscar**

Zitat von bigeasy76

Ich hab nun mal folgendes zusammengeschustert, ich glaube, man merkt, dass ich ein blutiger Anfänger bin, ist erst mein zweites Script:

Dieser ganze Script-Teil ist Quatsch (Entschuldigung, für die harten Worte)!

Poste bitte Dein ganzes Script, sonst kann man Dir nicht vernünftig helfen.

bigeasy76

Hallo Oscar

kein Problem, hab das schon selber befürchtet. Hier das ganze Script:

C

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>
#include <GDIPlus.au3>


SMSFenster()

Func SMSFenster()

   $hGUI = GUICreate("SMS Box", 600, 600)
   $idLC = GUICtrlCreateInput("0041(0)", 10, 5, 45, 20, $ES_READONLY)
   $idVORWAHL = GUICtrlCreateCombo("76", 55, 5, 40, 20)
   GUICtrlSetData(-1, "77|78|79")
   Global $idNR = GUICtrlCreateInput("", 93, 5, 60, 20, $ES_NUMBER)
   GUICtrlSetLimit(-1, 7)
   Global $idTEXT = GUICtrlCreateEdit("", 10, 40, 300, 200, $ES_MULTILINE)
   GUICtrlSetLimit(-1, 800)
   Global $idSENDEN = GUICtrlCreateButton("Senden", 30, 250, 85, 25)
   $idENDE = GUICtrlCreateButton("Schliessen", 130, 250, 85, 25)
   Global $idDEL = GUICtrlCreateButton("Löschen", 230, 250, 85, 25)
   $idLABEL1 = GUICtrlCreateLabel("Natelnummer eingeben", 155, 8, 150, 20)
   Global $idLABEL2 = GUICtrlCreateLabel("0", 320, 40, 30, 20)
   $idLABEL3 = GUICtrlCreateLabel("Anzahl Zeichen (max. 800)", 360, 40, 130, 20)
   Global $idLABEL4 = GUICtrlCreateLabel("0", 320, 70, 30, 20)
   $idLABEL5 = GUICtrlCreateLabel("Anzahl SMS (max. 5)", 360, 70, 100, 20)
   Global $oIE = ObjCreate("Shell.Explorer.2")
   $GUIActiveX = GUICtrlCreateObj ($oIE, 10, 300, 580, 285)

   GUISetState(@SW_SHOW, $hGUI)

   GUIRegisterMsg($WM_KEYDOWN, "SCHREIBEN")

   While 1
      Switch GUIGetMsg()
         Case $GUI_EVENT_CLOSE, $idENDE
            Exit
      EndSwitch
   WEnd
EndFunc

Func SCHREIBEN()
   Switch GUIGetMsg()
      Case $idTEXT
         Local $ZAEHLER = 0
         $TEXTtemp = GUICtrlRead($idTEXT)
         $ZAEHLER = StringLen($TEXTtemp)
         GUICtrlSetData($idLABEL2, $ZAEHLER)

         Select
            Case $ZAEHLER <=160
               GUICtrlSetData($idLABEL4, 1)

            Case $ZAEHLER >160 And $ZAEHLER <=320
               GUICtrlSetData($idLABEL4, 2)

            Case $ZAEHLER >320 And $ZAEHLER <=480
               GUICtrlSetData($idLABEL4, 3)

            Case $ZAEHLER >480 And $ZAEHLER <=640
               GUICtrlSetData($idLABEL4, 4)

            Case $ZAEHLER >640
               GUICtrlSetData($idLABEL4, 5)
         EndSelect


      Case $idDEL
         GUICtrlSetData($idTEXT, "")
         GUICtrlSetData($idNR, "")

      Case $idSENDEN
         $NR = "0041"&GUICtrlRead(4)&GUICtrlRead(5)
         $TEXT = GUICtrlRead(6)
         MsgBox($MB_OKCANCEL, "Senden?", "http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041444444444&to="& $NR &"&text="& $TEXT)

         $oIE.navigate("http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041444444444&to="&$NR&"&text="&$TEXT)

   EndSwitch
   GUIDelete()
EndFunc

Alles anzeigen

**Oscar**

Probier's mal so:

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("SMS Box", 600, 600)
Global $idLC = GUICtrlCreateInput("0041(0)", 10, 5, 45, 20, $ES_READONLY)
Global $idVORWAHL = GUICtrlCreateCombo("76", 55, 5, 40, 20)
GUICtrlSetData(-1, "77|78|79")
Global $idNR = GUICtrlCreateInput("", 93, 5, 60, 20, $ES_NUMBER)
GUICtrlSetLimit(-1, 7)
Global $idTEXT = GUICtrlCreateEdit("", 10, 40, 300, 200, BitOR($GUI_SS_DEFAULT_EDIT, $ES_MULTILINE))
GUICtrlSetLimit(-1, 800)
Global $idSENDEN = GUICtrlCreateButton("Senden", 30, 250, 85, 25)
Global $idENDE = GUICtrlCreateButton("Schliessen", 130, 250, 85, 25)
Global $idDEL = GUICtrlCreateButton("Löschen", 230, 250, 85, 25)
Global $idLABEL1 = GUICtrlCreateLabel("Natelnummer eingeben", 155, 8, 150, 20)
Global $idLABEL2 = GUICtrlCreateLabel("0", 320, 40, 30, 20)
Global $idLABEL3 = GUICtrlCreateLabel("Anzahl Zeichen (max. 800)", 360, 40, 130, 20)
Global $idLABEL4 = GUICtrlCreateLabel("0", 320, 70, 30, 20)
Global $idLABEL5 = GUICtrlCreateLabel("Anzahl SMS (max. 5)", 360, 70, 100, 20)
Global $oIE = ObjCreate("Shell.Explorer.2")
Global $GUIActiveX = GUICtrlCreateObj($oIE, 10, 300, 580, 285)

GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idENDE
            Exit
        Case $idDEL
            GUICtrlSetData($idTEXT, "")
            GUICtrlSetData($idNR, "")

        Case $idSENDEN
            $NR = "0041" & GUICtrlRead(4) & GUICtrlRead(5)
            $TEXT = GUICtrlRead(6)
            MsgBox($MB_OKCANCEL, "Senden?", "http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041444444444&to=" & $NR & "&text=" & $TEXT)

            $oIE.navigate("http://www.lox24.eu/API/httpsms.php?konto=xxx&password=xxx&service=11171&from=0041444444444&to=" & $NR & "&text=" & $TEXT)
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode, $sText, $iLen
    $hWndFrom = $lParam
    $iIDFrom = _WinAPI_LoWord($wParam)
    $iCode = _WinAPI_HiWord($wParam)
    Switch $iIDFrom
        Case $idTEXT
            Switch $iCode
                Case $EN_CHANGE
                    $sText = GUICtrlRead($idTEXT)
                    $iLen = StringLen($sText)
                    GUICtrlSetData($idLABEL2, $iLen)
                    GUICtrlSetData($idLABEL4, Int($iLen / 160) + 1)
            EndSwitch
        Case Else
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Alles anzeigen

**Bitnugger**

Zitat von bigeasy76

Müsste ich aber anstatt des Events WM_COMMAND in meinem Fall nicht den Event WM_KEYDOWN verwenden?

Mit WM_KEYDOWN wird die dafür registrierte Funktion bei jedem Tastendruck aufgerufen, wenn deine GUI aktiv ist - aber nur dann, wenn kein Control den Fokus hat, dass diese Nachricht selbst auswertet, wie z.B. ein Input/Edit Control.

WM_COMMAND wird gesendet, wenn der Benutzer ein Control (Item) aus einem Menü auswählt, wenn ein Control eine Benachrichtigungsmeldung an sein übergeordnetes Fenster sendet oder wenn ein Tastenanschlag mit einem Accelerator übersetzt wird.

Der fett markierte Teil von WM_COMMAND... genau das brauchen wir in deinem Fall... wobei uns aber nur die Nachricht $EN_CHANGE interessiert... wenn sie von einem Input/Edit Control kommt.

Wir müssen in der für WM_COMMAND registrierten Funktion also nur überprüfen, von welchem Input/Edit Control die Nachricht gesendet wurde und ob es $EN_CHANGE ist.

Input/Edit Control - der hauptsächliche Unterschied ist wohl, dass ein Input Control auf nur eine Zeile beschränkt ist. Windows kennt nur Edit Controls... Input Controls gibt es nur in AutoIt. Deshalb findest du auch die Notification Constants für Input in EditConstants.au3 - somit auch $EN_CHANGE. $EN steht dann wohl für Edit Notify.

Deine Funktion SCHREIBEN() ist aus mehreren Gründen Quatsch...

weil du darin die Nachrichten verarbeitest, die von GUIGetMsg() empfangen wurden und nicht die, die du durch WM_COMMAND von dem Control bekommst. Den Inhalt der Funktion kannst du also auch in deiner While-Schleife verarbeiten.
weil du in der Funktion keine Parameter angegeben hast, die du verarbeiten kannst: $hWnd, $iMsg, $wParam, $lParam

$hWnd und $iMsg werden von AutoIt bereitgestellt, $wParam und $lParam von WM_COMMAND - genau in dieser Reihenfolge - und bei jedem Aufruf an diese Funktion übergeben, oder nur $hWnd und $iMsg, wenn deine Funktion nur zwei Parameter hat.

Die Funktion wird auch aufgerufen, wenn du keinen Parameter angegeben hast, macht aber dann keinen Sinn. Den macht es nur, wenn du zumindest $wParam und/oder $lParam auswertest... und bei mehreren GUIs auch $hWnd - dass aber auch nur bedingt, wenn du $iMsg nicht auswertest.

Ich würde dir empfehlen, immer alle Parameter anzugeben... auch wenn du sie in der Funktion nicht auswertest.

WM_COMMAND: https://msdn.microsoft.com/de-de/library/…esktop/ms647591

bigeasy76

Vielen Dank an Oscar und Bitnugger, wirklich toll, wie man hier in diesem Forum unterstützt wird, auch wenns bescheuerte Anfängerfragen sind! Nun funktionierts wunderbar.

Eine Frage noch an Oscar: Die Anzeige der Anzahl SMS hast Du ja zur Funktion Int($iLen / 160) + 1 geändert. Nun gibts aber einen kleinen Fehler: Pro SMS kann man 160 Zeichen verwenden, dh. der SMS-Zähler sollte eigentlich erst bei 161 Zeichen zu 2 SMS wechseln, bei 321 zu 3, usw. Wenn ich Int($iLen / 161) + 1 verwende, kommts ja ab dem 2. SMS auch falsch raus. Hast Du evtl. noch eine Idee, man kann das sicher eleganter lösen, als ich es zu Anfang tat, oder?

**Oscar**

Zitat von bigeasy76

Nun gibts aber einen kleinen Fehler: Pro SMS kann man 160 Zeichen verwenden, dh. der SMS-Zähler sollte eigentlich erst bei 161 Zeichen zu 2 SMS wechseln

Dann ändere das folgendermassen: GUICtrlSetData($idLABEL4, Int(($iLen - 1) / 160) + 1)

bigeasy76

Zitat von Oscar

Dann ändere das folgendermassen: GUICtrlSetData($idLABEL4, Int(($iLen - 1) / 160) + 1)

Tiptop, nun läufts prima!

Nochmals Besten Dank an die Herren für die Hilfe!

rudi

Hi.

Dieser Ansatz fragt zyklisch das Edit ab und wenn die max. Länge überschritten wird, dann wird's einfach wieder abgeschnitten.

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

    $CharPerSMS=160
    $MaxSMS=5
    $Text=""
    $Len=0
    $SMS=0


$w=300
$h=600
$MyGui=GUICreate("SMS",$w,$h)

$iTel=GUICtrlCreateInput("",10,10,$w-20,30)
$eSMS=GUICtrlCreateEdit("",10,40,$w-20,$h-90,$ES_MULTILINE)
$LCounters=GUICtrlCreateLabel("Zeichen/SMS",10,$h-30,$w/2-10,30)
$BtnDoit=GUICtrlCreateButton("Abschicken",$w/2+5,$h-40,$w/2-20,30)
GUISetState()

AdlibRegister("Auslesen",100)


while 1
    $msg=GUIGetMsg()
    Switch $msg
        case $GUI_EVENT_CLOSE
            Exit
        case $BtnDoit
            ; abschicken
            Exit
    EndSwitch
WEnd


Func Auslesen()
    $Text=GUICtrlRead($eSMS)
    $NewLen=StringLen($Text)
    if $NewLen<>$Len Then
        $Len=$NewLen
    $SMS=Ceiling($Len/$CharPerSMS)
    if $SMS > 5 Then
        GUICtrlSetData($eSMS,StringLeft($Text,$CharPerSMS*$MaxSMS))
    EndIf
    GUICtrlSetData($LCounters,$SMS & " SMS / " & $Len & " Zeichen")
    EndIf
EndFunc

Alles anzeigen

Schöne Grüße, Rudi.

**Bitnugger**

rudi

Das ist keine gute Lösung... denn so wird die Länge ständig in Intervallen (Polling) abgefragt, auch wenn sich der Inhalt des Input-Controls nicht geändert hat. Oscar hat doch bereits gezeigt, wie es richtig gemacht wird... denn so wird die Funktion nur aufgerufen, wenn sich der Inhalt des Input-Controls geändert hat.