Während Whileschleife keine Buttons mehr drückbar

Headsniper1997

Hallo zusammen,

ich bin gerade dabei ein kleines Spielchen zu machen.

Hierbei müsst ihr als Chef eines Unternehemns Geld verdienen und so wirtschafen.

Nun komme ich aber leider nicht mehr weiter aktuell

Im Script (Zeile 80) zählt er dann zwar alle 2 Sekunden die 500 € auf das Konto, nur kann man dann keine Buttons mehr drücken.

z.B. der "Geld verdienen" Button geht dann nicht mehr

ebeneso der Beenden Button auch nicht mehr.

Hat von euch vielleicht einer ein Lösung für mich wie er pro ( z.b. 5 Sekunden mir immer 500€ auf dieses "Konto" macht aber die Buttons noch bedienbar sind.

Vielen Dank im Vorfeld !!

Gruß

Headsniper1997

C

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Firmenmanager Simulator", 615, 438, 192, 124)
$Label1 = GUICtrlCreateLabel("Aktueller Firmenkontostand " & "0.00" & " €", 72, 60, 188, 41)
$Label2 = GUICtrlCreateLabel("Eine Firma kostet 1000.00€", 72, 20, 188, 41)
$Button1 = GUICtrlCreateButton("Geld verdienen", 352, 60, 201, 33)
$Button2 = GUICtrlCreateButton("Eine Firma kaufen", 352, 140, 201, 33)
$Button3 = GUICtrlCreateButton("Mitarbeiter", 952, 140, 201, 33)
$Button4 = GUICtrlCreateButton("Beenden", 352, 340, 201, 33)
GUISetState(@SW_SHOW)


#EndRegion ### END Koda GUI section ###


Global $Input2 = 0
Global $Mitarbeiter = 0
Global $Gekauft = false
Global $i = 0


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

Case $Button1

         $Input2 += 550.91
         GUICtrlCreateLabel("Aktueller Firmenkontostand " & $Input2  & " €", 72, 60, 188, 41)

Case $Button2
      If $Input2 > 999 Then
      $Input2 = $Input2 -999.91
      Local $iRound1 = Round($Input2, 2)
      GUICtrlCreateLabel("Aktueller Firmenkontostand " & $Input2 & " €", 72, 60, 188, 41)
      GUICtrlCreateLabel("Sie haben erfolgreich eine Frima gekauft gekauft!", 72, 140, 188, 41)
      $Firmenname = InputBox ("Name der Firma", "Geben Sie den Namen ihrer Frima ein","")
      GUICtrlCreateLabel(" Ihre Firma heißt nun " & $Firmenname, 472, 20, 170, 20)
      GUICtrlSetBkColor(-1, 0x00FFFF)
      GUISetState(@SW_SHOW)

      GUICtrlDelete ($Button2)
      GUICtrlDelete ($Label2)
      GUISetState(@SW_HIDE)



      GUICreate("Firmenmanager Simulator", 615, 438, 192, 124)
      GUISetState(@SW_SHOW)
      GUICtrlCreateLabel(" Firmenname " & $Firmenname, 472, 20, 170, 20)
      GUICtrlSetBkColor(-1, 0x00FFFF)
      GUICtrlCreateLabel("Aktueller Firmenkontostand " & $Input2 & " €", 72, 60, 188, 41)
      $Button3 = GUICtrlCreateButton("Mitarbeiter", 352, 140, 201, 33)
      $Button1 = GUICtrlCreateButton("Geld verdienen", 352, 60, 201, 33)
      $Button4 = GUICtrlCreateButton("Beenden", 352, 340, 201, 33)



      EndIf

Case $Button3
               If  $Input2 > 500 Then
                  $Input2 = $Input2 - 500
                  $Mitarbeiter = $Mitarbeiter + 10
                  GUICtrlCreateLabel("Aktueller Firmenkontostand " & $Input2 & " €", 72, 60, 188, 41)
                  GUICtrlCreateLabel("Aktuelle Mitarbeiter " & $Mitarbeiter, 72, 140, 188, 41)
                  Local $iRound1 = Round($Input2, 2)
                  Global $Gekauft = true
               ElseIf $Input2 < 500 Then
                  MsgBox (2, "Kein Kapital", "Sie besitzen nicht genügend Geld um sich einen Mitarbeiter zu kaufen")
               EndIf

                     While 1
                     $Input2 = $Input2 + 500
                     GUICtrlCreateLabel("Aktueller Firmenkontostand " & $Input2 & " €", 72, 60, 188, 41)
                     Sleep (2000)



                     WEnd




Case $Button4
   Exit



    EndSwitch
 WEnd

Alles anzeigen

Yjuq

Du hast eine While Schleife in der While Schleife. Dadurch können die Events nicht mehr verarbeitet werden da du diese Schleife niemals verlässt. Du bist hängst quasi in der zweiten While Schleife drin ohne diese jemals zu verlassen.

Sleep() eignet sich allgemein nicht um mit Zeiten (in dem Fall 2 Sekunden) zu arbeiten. Die bessere Alternative wäre hier mit TimerInit() und TimerDiff() zu arbeiten.

Außerdem sehe ich noch ein paar Sachen die ich persönlich bemängeln würde. Das ist aber der Code Stil und hat weniger mit der Funktionalität des Programmes zu tun.

Headsniper1997

Wie könnte ich das dann anstellen (bin relativ neu) ?

sagen wir ich Drücke den Button "Mitarbeiter kaufen"

Dann soll er im Label ausgeben

Aktueller MItarbeiterstand: 10

und soll dann in einer schleife pro Sekunde 500 € auf das Konto rechnen

und im Firmenkontostand wieder ausgeben.

später dann bei 20 z.b. 1000 € pro Sekunde auf das Konto

**alpines**

Zitat von Headsniper1997

und soll dann in einer schleife pro Sekunde 500 € auf das Konto rechnen

Du kannst auch eine Funktion mit AdlibRegister registrieren die alle x Millisekunden ausgeführt wird.

Dann hast du auch keine blockierende Schleife.

Grundsätzlich solltest du dein Programm nicht-blockend programmieren, das bedeutet, dass die GUI-Elemente separat abgefangen werden sollten.

Das kannst du am einfachsten erreichen indem du den OnEvent-Modus verwendest.

Wenn du trotzdem bei der GUIGetMsg() Variante bleiben willst wäre die einfachste Lösung, mit dem Buttonklick eine Variable auf True zu setzen und dann in der

GUIGetMsg()-Schleife das Geld zuzuweisen, so fängst du immer noch die Buttonklicks ab aber fügst deinem Konto Geld hinzu.

Yjuq

Zitat von alpines

Du kannst auch eine Funktion mit AdlibRegister registrieren die alle x Millisekunden ausgeführt wird.

Dann hast du auch keine blockierende Schleife.

Nein, auf keinen Fall!

So wie sein Code momentan aussieht wird das nur noch schlimmer. Hast du mal genauer rein geschaut?

---

Naja, du könntest beispielsweise in deiner Hauptschleife mit TimerInit() und TimerDiff() arbeiten, um die Zeitdifferenz zu messen. Darauf basierend kannst du alle x Sekunden den Kontostand erhöhen:

AutoIt

Global $timer = TimerInit()

; Deine Hauptschleife:
While True
    If TimerDiff($timer) >= 2000 Then
        ConsoleWrite("2 Sekunden sind vergangen..." & @CRLF)
        $timer = TimerInit()
    EndIf
WEnd

Dein Code ist die reinste Katastrophe. Du erstellt 2 GUIs und löscht GUI Elemente. Ich würde dir erst mal empfehlen von Koda die Finger zu lassen und selber so eine GUI mal aufzubauen. Folgende Funktionen könnten dir von Hilfe sein:

GUICtrlSetData()

GUICtrlSetStata()

Dann musst du nicht ständig die GUI Elemente löschen und neu erstellen.

Headsniper1997

Okay also ich verstehe, dass eine While schleife in einer While schleife nicht funktionieren kann.

Dennoch kann ich noch nicht recht nachvollziehen, wie das nun mein Problem löst, bzw. wie ich deinen Code Yjuq in meinem anwenden kann

Hat jemand vielleicht ein plastischeres Bsp. ?

Code

Global $Mitarbeiter = 0
Global $Geld = 0 

Case $Button 
    $Geld = $Geld + 1

Case $Button1
    $Mitarbeiter = $Mitarbeiter + 5
    $Geld = $Geld -5


    If $Mitarbeiter > 10
       hier soll er loopen immer $Geld 5 mehr zuzuweisen, sodass $Button weiterhin funktionieren würde
       => an dieser stelle hänge ich fest
       
    EndIf

Alles anzeigen

Yjuq

AutoIt

Global $gui, $button, $label, $timer, $counter

$gui = GUICreate("", 120, 70)
$button = GUICtrlCreateButton("Klick", 10, 10, 100, 20)
$label = GUICtrlCreateLabel("", 10, 40, 100, 20)
GUISetState()

While True
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $button
            If Not $timer Then $timer = TimerInit()
    EndSwitch

    If $timer And TimerDiff($timer) >= 1000 Then
        $counter += 1
        $timer = TimerInit()
        GUICtrlSetData($label, $counter)
    EndIf
WEnd

Alles anzeigen

Ich könnte dir auch natürlich die fertige Lösung geben. Allerdings bezweifel ich, dass dies in irgend einer Weise weiterhilft. Hilfe zur Selbsthilfe - Fangen wir erst mal damit an dass du lernst Beispiele und Prinzipien von fremden Code in den eigenen einzuarbeiten.

Headsniper1997

Zitat

Ich könnte dir auch natürlich die fertige Lösung geben. Allerdings bezweifel ich, dass dies in irgend einer Weise weiterhilft.

Da finde ich hast du vollkommen recht.

zumindest funktioniert das was du mir da geschickt hast nun in kombi mit dem meinen

Habe noch hizugefügt (wie es später dann auch funktionieren soll)

Code

Global $gui, $button, $label, $timer, $counter
$gui = GUICreate("", 120, 70)
$button = GUICtrlCreateButton("Klick", 10, 10, 100, 20)
$label = GUICtrlCreateLabel("", 10, 40, 100, 20)
GUISetState()
While True
    Switch GUIGetMsg()
        Case -3
            Exit
         Case $button
            $counter = $counter + 10
            If Not $timer Then $timer = TimerInit()
    EndSwitch
    If $timer And TimerDiff($timer) >= 1000 Then
        $counter += 1
        $timer = TimerInit()
        GUICtrlSetData($label, $counter)
    EndIf
WEnd

Alles anzeigen

Zumindest damit kann ich jetzt mal weiterarbeiten.

Hast du mir denn noch Tipps, da du anfänglich meinst mein Script sei sehr schlecht aufgebaut was man dort für die übersicht machen kann ?

hab schon son bisschen rausgefunden ;==> hinter die einzelnen dinge zu schreiben um sie zu definieren

und in verschiedenen ebenen zu arbeiten.

Gibts da noch mehr ?

Dennoch vielen Dank !!!

**Kanashius**

Ich hab dein Script aus dem ersten Post mal so überarbeitet, dass es deutlich ansehnlicher und übersichtlicher ist.

Zu den Änderungen:

1. Variablen passend benennen, damit man weiß, was sie bedeuten. Bei $label1 weiß keiner was sich dahinter verbirgt. Dabei auch gerne am Anfang der Variable den Typ nennen. So zum Beispiel i für eine Zahl, b für ein Bool,...

2. Die Hauptschleife so übersichtlich halten wie möglich. Daher alles in Funktionen auslagern, sodass deine Hauptschleife schlank bleibt und du auf einen blick siehst, was beim Klick auf den Button passiert.

3. Alles was redundant ist (sich wiederholt) ebenfalls in Funktionen auslagern. Da hab ich hier zum Beispiel das _setCompanyMoney definiert. Dadurch wird beim ändern des Geldes jedesmal auch das Label aktualisiert. Änderst du irgendwann mal das Label musst du es nicht überall im Code ändern, sondern nur an dieser einen Stelle.

4. Das Fenster am Anfang vollständig erstellt und die Controls nur ein/ausblenden. Da du ein Spiel programmierst solltest du den Overhead des ständigen neuerstellens vermeiden, da das, wenn dein Spiel größer wird, ausbremsen kann!

5. Ich hab das hier jetzt nicht umgesetzt, aber schau dir auf jedenfall Arrays an. Gerade beim erstellen von Fenstern sind diese eine sehr größe Hilfe. Auch sonst wirst du vermutlich irgendwann nichtmehr drumrumkommen

Der Code:

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
$hMainGui = GUICreate("Firmenmanager Simulator", 615, 438, 192, 124)
$iLabelCompanyMoney = GUICtrlCreateLabel("Aktueller Firmenkontostand " & "0.00" & " €", 72, 60, 188, 41)
$iLabelCompanyPrice = GUICtrlCreateLabel("Eine Firma kostet 1000.00€", 72, 20, 188, 41)
$iLabelCompanyNameInfo = GUICtrlCreateLabel(" Ihre Firma heißt nun ", 472, 20, 170, 20)
$iLabelCompanyBoughtInfo = GUICtrlCreateLabel("Sie haben erfolgreich eine Frima gekauft gekauft!", 72, 140, 188, 41)
$iLabelCompanyEmployee = GUICtrlCreateLabel("Aktuelle Mitarbeiter " & 0, 72, 140, 188, 41)
$iLabelCompanyName = GUICtrlCreateLabel(" Firmenname ", 472, 20, 170, 20)
$iButtonEarnMoney = GUICtrlCreateButton("Geld verdienen", 352, 60, 201, 33)
$iButtonBuyCompany = GUICtrlCreateButton("Eine Firma kaufen", 352, 140, 201, 33)
$iButtonEmployee = GUICtrlCreateButton("Mitarbeiter", 352, 180, 201, 33)
$iEnd = GUICtrlCreateButton("Beenden", 352, 340, 201, 33)
GUICtrlSetState($iLabelCompanyNameInfo,$GUI_HIDE)
GUICtrlSetState($iLabelCompanyName,$GUI_HIDE)
GUICtrlSetState($iLabelCompanyBoughtInfo,$GUI_HIDE)
GUICtrlSetState($iLabelCompanyEmployee,$GUI_HIDE)
GUICtrlSetState($iButtonEmployee,$GUI_HIDE)
GUISetState(@SW_SHOW)


Global $iCompanyMoney = 0,$iEmployeeCount = 0,$bCompanyEarnsMoney=false,$iTimerCompanyEarnsMoney

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $iButtonEarnMoney
            _setCompanyMoney($iCompanyMoney+550.91)
        Case $iButtonBuyCompany
            _buyCompany()
        Case $iButtonEmployee
            _buyEmployies()
        Case $iEnd
           Exit
    EndSwitch
    If $iTimerCompanyEarnsMoney and TimerDiff($iTimerCompanyEarnsMoney)>2000 Then
        _setCompanyMoney($iCompanyMoney+500)
        $iTimerCompanyEarnsMoney=TimerInit()
    EndIf
WEnd4. 

Func _setCompanyMoney($iMoney)
    $iCompanyMoney=$iMoney
    GUICtrlSetData($iLabelCompanyMoney,"Aktueller Firmenkontostand " & $iCompanyMoney & " €")
EndFunc

Func _setEmployeeCount($iCount)
    $iEmployeeCount=$iCount
    GUICtrlSetData($iLabelCompanyEmployee,"Aktuelle Mitarbeiter " & $iEmployeeCount)
EndFunc

Func _buyCompany()
    If $iCompanyMoney<1000 Then return -1 ;If there is not enough money, skip here
    _setCompanyMoney($iCompanyMoney-999.91)
    GUICtrlSetState($iLabelCompanyBoughtInfo,$GUI_SHOW)
    GUICtrlSetState($iLabelCompanyEmployee,$GUI_SHOW)
    GUICtrlSetState($iLabelCompanyNameInfo,$GUI_SHOW)
    GUICtrlSetState($iLabelCompanyName,$GUI_SHOW)
    GUICtrlSetState($iButtonEmployee,$GUI_SHOW)
    $Firmenname = InputBox ("Name der Firma", "Geben Sie den Namen ihrer Frima ein","")
    GUICtrlSetData($iLabelCompanyName," Firmenname " & $Firmenname)
EndFunc

Func _buyEmployies()
    If  $iCompanyMoney > 500 Then
        _setCompanyMoney($iCompanyMoney - 500)
        _setEmployeeCount($iEmployeeCount + 10)
    ElseIf $iCompanyMoney < 500 Then
        MsgBox (0, "Kein Kapital", "Sie besitzen nicht genügend Geld um sich einen Mitarbeiter zu kaufen")
    EndIf
    If NOT $iTimerCompanyEarnsMoney Then $iTimerCompanyEarnsMoney=TimerInit()
EndFunc

Alles anzeigen

MfG Kanashius

Headsniper1997

Wow okay vielen neue dinge die ich erst noch verstehen muss.

Hab den ganzen morgen und mittag jetzt drangesessen und versucht das selbst hinzubekommen, mit erfolg.

Dank der hilfe von Yjuqs kleinem Script funktionert es jetzt so wie das von dir Kanashius (zwar leider nicht so übersichtlich wie deins) aber immerhin ein großer Erfolg für mich.

Trotzdem vielen dank für deine Mühe, werde mir ein wenig von deinem Stiel versuchen anzueignene

Gruß

Headsniper1997

xSunLighTx3

Ich kann dir auch die TimerDiff() Methode empfehlen. Wenn es ein wenig "besser" sein soll, muss man in der Hauptschleife

einen Iterator, FPS Variable und Speed Variable einbauen und kalkulieren. Ist aber nur bei aufwendigen Spielen nötig.

Yjuq

Zitat von xSunLighTx3

Ich kann dir auch die TimerDiff() Methode empfehlen. Wenn es ein wenig "besser" sein soll, muss man in der Hauptschleife

einen Iterator, FPS Variable und Speed Variable einbauen und kalkulieren. Ist aber nur bei aufwendigen Spielen nötig.

Wozu? Kannst du mir ggf. genauer erklären was du meinst? Ich sehe da keinen Sinn in deiner Aufzählung...

Ich hatte dir doch auch schon mal dazu was verfasst:

PandaRunner Reworked - Ein Autoit Game

xSunLighTx3

Zitat von Yjuq

Wozu? Kannst du mir ggf. genauer erklären was du meinst? Ich sehe da keinen Sinn in deiner Aufzählung...

Ich hatte dir doch auch schon mal dazu was verfasst:

PandaRunner Reworked - Ein Autoit Game

Hi, ja danke das war echt hilfreich damals.

Ich meinte das so, dass man anstelle der direkten Verwendung

des Timers auch die Durchläufe des Skripts nehmen kann. Wobei

man im Endeffekt auch einen Timer benötigt, so wie du es mir gesagt hast.

Aber dadurch das man den Timer nicht direkt nimmt, hat man mehrere Möglichkeiten,

wie z.B das man jetzt einfach mal sagt, ich ändere die Geschwindigkeit von 1 auf 0,5 oder auf 0 (pausiert).

Und dafür kann man dann eine einheitliche Variable benutzen.

Edit:

Achja jetzt weiß ich wieder, wo ich das Problem hatte mit den Timern. Also ich wollte z.B jede 1000ms einen

Gegner spawnen lassen. Wenn 1000ms erreicht wurden, wurde der Timer eben wieder zurückgesetzt.

Wenn das Spiel jedoch mal 2 Sekunden laggt, entsteht ja eine Differenz von einer Sekunde. Dadurch wird

ein Gegner weniger gespawnt. Wenn ich beim Rundenstart aber einen Iterator starte und diesen mit dem Speed Timer

multipliziere, habe ich immer einen exakten Wert und kann so die Gegner Bild für Bild optimal spawnen lassen.

Yjuq

So richtig kann ich mir unter deiner Beschreibung nicht vorstellen was du meinst. Vielleicht hab ich auch was anderes im Sinn als du versuchst du erläutern. Wärst du so freundlich und würdest ein minimalistisches Beispiel dazu verfassen?

**alpines**

Zitat von xSunLighTx3

Ich meinte das so, dass man anstelle der direkten Verwendung

des Timers auch die Durchläufe des Skripts nehmen kann.

Das ist aber an die Geschwindigkeit der CPU gebunden wenn man keine Sleeps verwendet.

Verwendet man Sleeps, so blockiert man wieder alles.