Mit Checkbox eine Combobox aktivieren / deaktivieren

Mikki

Hallo zusammen,

hier ein Beispiel und unten stehend meine Frage.

Code

While 1
    For $c = 0 To 11
    $aREAD_Checkbox[$c] = GUICtrlRead($aCheckbox[$c])
    $aREAD_Combobox[$c] = GUICtrlRead($aCombobox[$c])
    Next

    Switch GUIGetMsg()
        Case $aCheckbox[0]
            If $aREAD_Checkbox[0] = $GUI_CHECKED Then
                GUICtrlSetState($aCombobox[0], $GUI_ENABLE)
                GUICtrlSetState($aInput_Stk[0], $GUI_ENABLE)
            Else
                GUICtrlSetState($aCombobox[0], $GUI_DISABLE)
                GUICtrlSetState($aInput_Stk[0], $GUI_DISABLE)
            EndIf

         Case $aCheckbox[1]
            If $aREAD_Checkbox[1] = $GUI_CHECKED Then
                GUICtrlSetState($aCombobox[1], $GUI_ENABLE)
                GUICtrlSetState($aInput_Stk[1], $GUI_ENABLE)
            Else
                GUICtrlSetState($aCombobox[1], $GUI_DISABLE)
                GUICtrlSetState($aInput_Stk[1], $GUI_DISABLE)
            EndIf

        Case $aCheckbox[2]
            If $aREAD_Checkbox[2] = $GUI_CHECKED Then
                GUICtrlSetState($aCombobox[2], $GUI_ENABLE)
                GUICtrlSetState($aInput_Stk[2], $GUI_ENABLE)
            Else
                GUICtrlSetState($aCombobox[2], $GUI_DISABLE)
                GUICtrlSetState($aInput_Stk[2], $GUI_DISABLE)
            EndIf

        Case $GUI_EVENT_CLOSE
        Exit
    EndSwitch
WEnd

Alles anzeigen

Hier meine Frage:

Ist es möglich, per For-Schleife sämtliche Comboboxen mit der Checkbox zu aktivieren. Also so, dass ich nicht 12 mal Case..... schreiben muss, sondern nur ein mal mit Schleife? Ich habe schon vieles versucht aber mehr will mir im Moment nicht einfallen.

LG Mikki

**autoiter**

Hallo Mikki

bspw. könnte man das so machen:

Code

#include <Array.au3>

_test(15) ; erste Message
_test(55) ; zweite Message

Func _test($iMsg)

    Local $aArray[] = [10, 15, 29, 37, 38, 90] ; wenn zwischen den einzelnen Combos andere Controls erstellt wurden, sieht es eher so aus.
    Local $aArray2[] = [55, 56, 57, 58, 59, 60] ; wenn du die Controls alle nacheinander erstellt hast, haben sie aufeinander folgende Nummern (IDs).

    Switch $iMsg
        Case _ArraySearch($aArray, $iMsg) <> -1
            MsgBox(0, "Treffer $aArray mit $iMsg: " & $iMsg, "Message ist im Array-Index " & _ArraySearch($aArray, $iMsg) & " gespeichert.")

        Case $aArray2[0] To $aArray2[5] ; bzw $aArray2[Ubound($aArray2)-1]
            For $i = 0 To 5 ; Kannst du auch mit _ArraySearch ersetzen.
                If $iMsg = $aArray2[$i] Then
                    MsgBox(0, "Treffer $aArray2 mit $iMsg: " & $iMsg, "Message ist im Array-Index " & $i & " gespeichert.")
                    ExitLoop
                EndIf
            Next
        Case Else
            MsgBox(0, "Fehler", "Kein Treffer.")
    EndSwitch
EndFunc   ;==>_test

Alles anzeigen

**autoBert**

Warum sollte dies nicht möglich sein? Allerdings fehlt der Teil mit der GUI-erstellung und ich bin zu bequem diesen zu erstellen. Du kannst

Zitat von Hilfe

Case <value> [To <value>] [,<value> [To <value>] ...]

verwenden und den Schleifenzählwert $i als Elementwert verwenden. Wenn du damit nicht weiter kommst stell den GUI-Teil des Skriptes ein.

Mikki

Hallo ihr Zwei,

vielen Dank. Das war der richtige Denkanstoß. Es sieht jetzt so aus:

Code

While 1

    Switch GUIGetMsg()
        Case $aCheckbox[0] To $aCheckbox[11]
            For $c = 0 To 11
                $aREAD_Checkbox[$c] = GUICtrlRead($aCheckbox[$c])
                $aREAD_Combobox[$c] = GUICtrlRead($aCombobox[$c])

                If $aREAD_Checkbox[$c] = $GUI_CHECKED Then
                    GUICtrlSetState($aCombobox[$c], $GUI_ENABLE)
                    GUICtrlSetState($aInput_Stk[$c], $GUI_ENABLE)
                Else
                    GUICtrlSetState($aCombobox[$c], $GUI_DISABLE)
                    GUICtrlSetState($aInput_Stk[$c], $GUI_DISABLE)
                EndIf
            Next

        Case $Button

            For $d = 0 To 3
                $aREAD_Input_Sattel[$d] = GuiCtrlRead($aInput_Sattel[$d])
            Next

            For $e = 0 To UBound($aCheckbox) -1
                $aGetState_Checkbox[$e] = GUICtrlRead($aCheckbox[$e])
                    If $aGetState_Checkbox[$e] = 1 Then
                        $aREAD_Combobox[$e] = GUICtrlRead($aCombobox[$e])
                        $aREAD_Input_Stk[$e] = GUICtrlRead($aInput_Stk[$e])
                        MsgBox(0, "", "" & $aREAD_Combobox[$e] & " / " & $aREAD_Input_Stk[$e])
                    EndIf
            Next


        Case $GUI_EVENT_CLOSE
        Exit
    EndSwitch
WEnd

Alles anzeigen

Die Abfrage der Werte in der Combobox und in der Inputbox funktionieren auch.

Vielen Dank und ein sonniges Wochenende!

LG Mikki