TreeView Suche

mirko2002

Hallo AutoIt-Gemeinde,

ich stecke mal wieder etwas in der Klemme

Ich hab für meinen TreeView eine Suchfunktion über eine Input/Button Schaltfläche eingebaut. Er sucht den entsprechenden String und selektiert diesen bei erfolgreicher Suche auch. Ansich funktioniert die Suche also wunderbar. Wenn der gesuchte String im Treeview u.U. mehrmals vorhanden ist, möchte ich gern, dass er bei jeder weiteren Suche auf den nächsten Eintrag springt.

Als Beispiel:

Treeview:

- Hallo 1

- Hallo 2

- Auf Wiedersehen 1

- Hallo 3

- Test 1

Ich suche z.B. den String "hallo" - so selektiert er mir derzeit den ersten Treffer - sprich "Hallo 1". Ich möchte aber nun, dass er bei einem weiteren Klick auf "Hallo 2" springt damit ich sehen kann, ob mehrere Treffer vorhanden sind. Jedoch bleibt er bei jedem weiteren klick auf dem Button natürlich weiterhin beim ersten Treffer hängen.

Mein "Button"-Code dazu:

AutoIt

Case $button_ticket_suche
            $hItemFound = _GUICtrlTreeView_FindItem($hTreeView, GUICtrlRead($input_button_suchen), True)
            If $hItemFound Then
;~                 MsgBox($MB_SYSTEMMODAL, "Information", "Item gefunden:" & @CRLF & "Handle: " & $hItemFound & @CRLF & "Text: " & _GUICtrlTreeView_GetText($hTreeView, $hItemFound))
                _GUICtrlTreeView_SelectItem($hTreeView, $hItemFound)
;~                GUICtrlSetData($input_button_suchen,"")
            Else
                MsgBox($MB_SYSTEMMODAL, "Information", "Ticket nicht gefunden")
;~                GUICtrlSetData($input_button_suchen,"")
            EndIf

Gibt's da irgend nen Trick für?

LG

Mirko

**Oscar**

Zitat von mirko2002

Gibt's da irgend nen Trick für?

$hItemFound muss global sein. Dann kannst Du das bei der nächsten Suche bei "_GUICtrlTreeView_FindItem" als vierten Parameter angeben.

**autoiter**

Hallo Mirko,

Du kannst bei der Suche das Handle mitgeben, bei dem die Suche gestartet wird. Also vor der nächsten Suche das nächste Element suchen und als erstes Item der Suche nutzen. Hier habe ich dir eine kleine Anpassung des Beispiels zu _GUICtrlTreeView_FindItem gemacht.

C

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[11], $hItemFound, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Find Item", 400, 300)

    $idTreeButton = GUICtrlCreateButton("Suche", 2, 275, 100, 20)
    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 3
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
        Next
    Next
    $aidItem[4] = GUICtrlCreateTreeViewItem(StringFormat("Looking for me?", $x), $idTreeView)
    For $x = 5 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
        Next
        GUICtrlCreateTreeViewItem(StringFormat("Looking for me?", $y), $aidItem[$x])
    Next
    $aidItem[10] = GUICtrlCreateTreeViewItem(StringFormat("Looking for me?", $x), $idTreeView)
    _GUICtrlTreeView_EndUpdate($idTreeView)


    Local $hItemSearch = 0 ; Hierin wird die Position gespeichert

    While 1
        $idMsg = GUIGetMsg()
        Select
            Case $idMsg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $idMsg = $idTreeButton
                $hItemFound = _GUICtrlTreeView_FindItem($idTreeView, "Looking for me?", False, $hItemSearch) ; Hier wird zuerst von Position 0 gesucht...
                $hItemSearch = _GUICtrlTreeView_GetNext($idTreeView, $hItemFound); später von der Position des Items nach dem letzten Treffer.
                If Not @error Then _GUICtrlTreeView_SelectItem($idTreeView, $hItemFound)
        EndSelect
    WEnd
    GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

mirko2002

Perfekt, danke ihr beiden das war der nötige Hinweis den ich brauchte

Vielen Dank.