Tool zur Linkverwaltung

AnMa

Hallo zusammen,

ich weiß gar nicht wie lange ich schon nach einem guten Tool zur Verwaltung von Links suche, zwar spuckt das Netz so einiges aus, aber ehrlich gesagt nichts was ich als wirklich brauchbar sehe. Zum einen möchte ich meine Links lokal verwalten und nicht im Netz, zum anderen sollt das System recht einfach und schnell, trotzdem aber übersichtlich und informativ sein.

Daher meine Frage:
Ist es grundsätzlich möglich Links entweder per Drag&Drop in ein entsprechendes Programm zu ziehen oder wäre es sogar möglich dem Submenü (Rechtsklick) innerhalb von Firefox einen entsprechenden Menüpunkt hinzuzufügen?
Allgemein sollten die Links recht simpel verwaltbar sein, zum Beispiel ändern sich oft Projekte sie werden größer oder haben andere Voraussetzungen und dann will man natürlich nicht alles mühevoll ändern, kopieren oder ähnliches, sondern am besten den Link einfach in eine neue Kategorie verschieben können.

Ein Link sollte zu schnelleren Erkennung ein Icon haben und einen eindeutigen Titel und eventuell eine kurze Beschreibung. Das Ganze dann, wie schon erwähnt in Kategorien und Untergruppen gepackt und mit einer Suchfunktion versehen.

Wäre etwas entsprechendes mit AutoIt realisierbar?

Grüße Anna

**autoBert**

Zitat von AnMa

Daher meine Frage:
Ist es grundsätzlich möglich Links entweder per Drag&Drop in ein entsprechendes Programm zu ziehen oder wäre es sogar möglich dem Submenü (Rechtsklick) innerhalb von Firefox einen entsprechenden Menüpunkt hinzuzufügen?

teste dieses Script:

AutoIt

;https://autoit.de/index.php/Thread/22579-Dropbox-f%C3%BCr-Links-aus-Browsern/?postID=185846#post185846
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Local $hGui, $iMsg
$hGui = GUICreate("Dropbox", 150, 150, -1, -1, BitOR($WS_SIZEBOX, $WS_BORDER), BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
GUICtrlSetState(-1, $GUI_ONTOP)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 0, 0, 150, 150, -1)
GUISetState()
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
_GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_SELCHANGE)
While True
    $iMsg = GUIGetMsg()
    Select
        Case $iMsg = $GUI_EVENT_CLOSE
            _GUICtrlRichEdit_Destroy($hRichEdit)
            GUIDelete()
            Exit
    EndSelect
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
    #forceref $hWnd, $iMsg, $iWparam
    Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
    $tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hRichEdit
            Select
                Case $iCode = $EN_SELCHANGE
                    Checklink()
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY


Func Checklink()
    Local $sURL, $arrValidURL
    $sURL = _GUICtrlRichEdit_GetText($hRichEdit)
    ConsoleWrite($sURL&@CRLF)
    $arrValidURL = StringRegExp($sURL, "(?s)((ftp|http|https):\/\/(\w+:{0,1}\w*@)?(\S+)(:[0-9]+)?(\/|\/([\w#!:.?+=&%@!\-\/]))?)", 2)

    #comments-start
    _GUICtrlRichEdit_GetSelText($hRichEdit)
    _GUICtrlRichEdit_SetText($hRichEdit, "")
    If UBound($arrValidURL) > 0 Then
        ;// Gueltige URL ok, mach irgendwas damit
        ConsoleWrite($arrValidURL[0] & @CRLF)
        InetGet($arrValidURL[0],'test.jpg')
        ShellExecute('test.jpg')
        ;//
    EndIf
    #comments-end
EndFunc   ;==>Checklink

Alles anzeigen

als GUI welche URL's per Drag&Drop entgegennimmt. Das Rechtsklickmenü des Firefox zu erweitern geht sicher auch, ich kenne aber die Lösung nicht.

Für den Rest würde ich eine GUI mit Treeview und Listview vorschlagen. Um die Daten zu speichern wäre eine SQLite-DB ideal, eine Lösung mit Inidateien oder eine eigene Text-DB ist aber aber einfacher. Eine sehr einfach gehaltene Version mit Ini findest du in meiner Signatur.

mfg (auto)Bert

**autoBert**

Wenn dir der Menüpunkt "Kopieren" im Rechtsklick-Menü des Browsers nicht stört, kannst du auch folgendes Skript:

AutoIt: Mit _ClipgetData kopierte URL's abfangen

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Global $g_idMemo, $g_hNext = 0

Example()

Func Example()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialize clipboard viewer
    $g_hNext = _ClipBoard_SetViewer($hGUI)

    GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
    GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Shut down clipboard viewer
    _ClipBoard_ChangeChain($hGUI, $g_hNext)
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Handle $WM_CHANGECBCHAIN messages
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Check the message was received
    ;MemoWrite("***** $WM_CHANGECBCHAIN *****")

    ; If the next window is closing, repair the chain
    If $wParam = $g_hNext Then
        $g_hNext = $lParam
        ; Otherwise pass the message to the next viewer
    ElseIf $g_hNext <> 0 Then
        _SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
    EndIf
EndFunc   ;==>WM_CHANGECBCHAIN

; Handle $WM_DRAWCLIPBOARD messages
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Display any text on clipboard
    ; Check the received message is a URL
    $sURL = _ClipBoard_GetData()
    $arrValidURL = StringRegExp($sURL, "(?s)((ftp|http|https):\/\/(\w+:{0,1}\w*@)?(\S+)(:[0-9]+)?(\/|\/([\w#!:.?+=&%@!\-\/]))?)", 2)
    If Not @error Then MemoWrite($sURL)
    ; Pass the message to the next viewer
    If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc   ;==>WM_DRAWCLIPBOARD

Alles anzeigen

als Grundlage benutzen.

mfg (auto)Bert