Error-Handling in meinem Skript

Mikki

Hallo zusammen,

ich habe ein kleines Problem.

Hier ein Ausschnitt aus meinem Code:

Code

Global $aMsgBox[32][2]
        $aMsgBox[0][1] = "1.Kein Umwandlungsordner angegeben!"
        $aMsgBox[1][1] = "2.Kein Verzeichnis für die Stuecklisten angegeben!"
        $aMsgBox[2][1] = "3.Kein Verzeichnis für die NC-Daten (nc-blech) angegeben!"
        $aMsgBox[3][1] = "4.Kein Verzeichnis für die NC-Daten (nc-profil) angegeben!"
        $aMsgBox[4][1] = "5.Kein Pfad im Zielverzeichnis für das Fertigungspaket angegeben!"
        $aMsgBox[5][1] = "6.Kein Pfad im Auftragsordner für die bmf´s angegeben!"
        $aMsgBox[6][1] = "7.Kein Server-Verzeichnis für die Stuecklisten angegeben!"
        $aMsgBox[7][1] = "8.Kein Server-Verzeichnis für die pdf-Dateien angegeben!"
        $aMsgBox[8][1] = "9.Kein Server-Verzeichnis für die dwg-Dateien angegeben!"
        $aMsgBox[9][1] = "10.Kein Server-Verzeichnis für die bmf-Dateien angegeben!"
        $aMsgBox[10][1] = "11.Kein Server-Verzeichnis für die Teilsystemperspektive als pdf angegeben!"
        $aMsgBox[11][1] = "12.Kein Server-Verzeichnis für die Teilsystemperspektive als dwg angegeben!"
        $aMsgBox[12][1] = "13.Kein Server-Verzeichnis für die Teilsystemperspektive als bmf_ angegeben!"
        $aMsgBox[13][1] = "14.Kein Server-Verzeichnis für die NC-Daten angegeben!"
        $aMsgBox[14][1] = "15.Kein Server-Verzeichnis für die Abwicklungen-Kantteile angegeben!"        
        $aMsgBox[15][1] = "1.Pfad für den Umwandlungsordner (lokal) ungültig!"
        $aMsgBox[16][1] = "2.Pfad für die Stücklisten (lokal) ungültig!"
        $aMsgBox[17][1] = "3.Pfad für die NC-Daten (nc-blech, lokal) ungültig!"
        $aMsgBox[18][1] = "4.Pfad für die NC-Daten (nc-profil, lokal) ungültig!"
        $aMsgBox[19][1] = "5.Pfad für das Fertigungspaket (lieferungen, lokal) ungültig!"
        $aMsgBox[20][1] = "6.Pfad für die bmf´s (plaene, lokal) ungültig!"
        $aMsgBox[21][1] = "7.Pfad für die Stücklisten (Server) ungültig!"
        $aMsgBox[22][1] = "8.Pfad für die Werkstattpläne (pdf´s, Server) ungültig!"
        $aMsgBox[23][1] = "9.Pfad für die Werkstattpläne (dwg´s, Server) ungültig!"
        $aMsgBox[24][1] = "10.Pfad für die Werkstattpläne (bmf´s, Server) ungültig!"
        $aMsgBox[25][1] = "11.Pfad für die Teilsystemperspektive (pdf´s, Server) ungültig!"
        $aMsgBox[26][1] = "12.Pfad für die Teilsystemperspektive (dwg´s, Server) ungültig!"
        $aMsgBox[27][1] = "13.Pfad für die Teilsystemperspektive (bmf´s, Server) ungültig!"
        $aMsgBox[28][1] = "14.Pfad für die NC-Daten (Server) ungültig!"
        $aMsgBox[29][1] = "15.Pfad für die Abwicklungen Kantteile (dxf, Server) ungültig!"
        $aMsgBox[30][1] = "16.Umwandlungsordner kann nicht gleich dem Ordner 'plaene' sein!"
        $aMsgBox[31][1] = "Sie haben einen Sicherungsauftrag gewählt! Die Aktion wird abgebrochen! Bitte wählen Sie einen Sortierauftrag."


;weiterer Code.....


Func Sortierauftrag_anlegen()

    GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
    GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)

    $READ_Checkbox_Fremdauftrag = GUICtrlRead($Checkbox_Fremdauftrag)

    If $READ_Checkbox_Fremdauftrag = $GUI_UNCHECKED Then
;~     Input auslesen und auf Vollständigkeit und Gültigkeit prüfen.
        For $i = 0 To 14
            $aRead_Inputbox[$i] = GUICtrlRead($aInputbox[$i])

            If Not $aRead_Inputbox[$i] Then
                $aMsgBox[$i][0] = MsgBox(16, "Error", "" & $aMsgBox[$i][1])
                GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
                GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)

                If $aMsgBox[$i][0] = 1 Then
                    GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_ENABLE)
                    GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_ENABLE)
                EndIf
                Return
            EndIf        
                
            For $j = 15 To 29                                                
                If Not FileExists($aRead_Inputbox[$i]) Then
                    $aMsgBox[$j][0] = MsgBox(16, "Error", "" & $aMsgBox[$j][1])
                        GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
                        GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)                    

                    If $aMsgBox[$j][0] = 1 Then
                        GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_ENABLE)
                        GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_ENABLE)                        
                    EndIf    
                    Return        
                EndIf
            Next
        Next    

        For $k = 0 To 5
            $aRead_Inputbox[$k] = GUICtrlRead($aInputbox[$k])
                If $aRead_Inputbox[0] = $aRead_Inputbox[5] Then
                    $aMsgBox[30][0] = MsgBox(16, "Error", "" & $aMsgBox[30][1])
                    GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
                    GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)

                    If $aMsgBox[30][0] = 1 Then
                        GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_ENABLE)
                        GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_ENABLE)
                        Return
                    EndIf
                EndIf
        Next

Alles anzeigen

Mein Problem ist jetzt, dass wenn ich bei einem Pfad ein paar Zeichen lösche / Pfad ungültig mache, dass er mir dann immer den String von $MsgBox[15][1] anzeigt. Es ist auch egal in welcher Inputbox ich den Pfad ungültig mache.

Allerdings: Wenn eine von den 15 Inputboxen leer ist, dann sagt er mir auch welche leer ist. So wie es sein soll.

Könnt Ihr mir da helfen?

Danke im Voraus.

LG Mikki

**autoiter**

Hallo Mikki

Code

For $j = 15 To 29
                If Not FileExists($aRead_Inputbox[$i]) Then

Hier prüfst du statt $j immer auf $i (also auf den Inhalt einer Inputbox, die du hier nicht mehr bearbeitet hast).

Mikki

Hallo autoiter

das habe ich auch schon versucht. Das Ergebnis ist das selbe.

Ich muss aber mit $i prüfen, da nur 15 Inputboxen vorhanden sind. Deshalb ja die zweite Schleife, da sich der erste Zähler $i von 0 bis 14 bezieht und der zweite Zähler $j von 15 bis 29. $i für den Fall, dass die Boxen leer sind und $j für den Fall, dass die Pfade ungültig sind.

Oder habe ich deine Antwort jetzt falsch gedeutet?

LG Mikki

**Bitnugger**

So in etwa würde ich es machen...

AutoIt

Func Sortierauftrag_anlegen()
    Local Static $aState = [$GUI_ENABLE, $GUI_DISABLE]
    Local $j

    GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
    GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)

    $READ_Checkbox_Fremdauftrag = GUICtrlRead($Checkbox_Fremdauftrag)

    If $READ_Checkbox_Fremdauftrag = $GUI_UNCHECKED Then
;~     Input auslesen und auf Vollständigkeit und Gültigkeit prüfen.
        For $i = 0 To 14
            $j = $i + 15
            $aRead_Inputbox[$i] = GUICtrlRead($aInputbox[$i])

            Switch True
                Case $aRead_Inputbox[$i] = ''
                    $aMsgBox[$i][0] = MsgBox(16, "Error", "" & $aMsgBox[$i][1])
                    GUICtrlSetState($Button_Auftrag_bearbeiten, $aState[$aMsgBox[$i][0]])
                    GUICtrlSetState($Button_Auftrag_Anlegen, $aState[$aMsgBox[$i][0]])
                    Return
                Case FileExists($aRead_Inputbox[$i]) = 0
                    $aMsgBox[$j][0] = MsgBox(16, "Error", "" & $aMsgBox[$j][1])
                    GUICtrlSetState($Button_Auftrag_bearbeiten, $aState[$aMsgBox[$j][0]])
                    GUICtrlSetState($Button_Auftrag_Anlegen, $aState[$aMsgBox[$j][0]])
                    Return
                Case $i = 6
                    For $k = 1 To 5
                        If $aRead_Inputbox[$k] = $aRead_Inputbox[0] Then
                            $aMsgBox[30][0] = MsgBox(16, "Error", "" & $aMsgBox[30][1])
                            GUICtrlSetState($Button_Auftrag_bearbeiten, $aState[$aMsgBox[30][0]])
                            GUICtrlSetState($Button_Auftrag_Anlegen, $aState[$aMsgBox[30][0]])
                            Return
                        EndIf
                    Next
            EndSwitch
        Next
    EndIf
EndFunc   ;==>Sortierauftrag_anlegen

Alles anzeigen

Mikki

Hallo Bitnugger

jawoll genau so soll´s sein. Vielen Dank!

Aber kannst du mir denn sagen, wo der Fehler bei meiner Methode liegt?

LG Mikki

**Bitnugger**

Zitat von Mikki

Aber kannst du mir denn sagen, wo der Fehler bei meiner Methode liegt?

Nicht der, sondern die Fehler... wobei dein schlimmster wohl ist, das du den For $j-Loop innerhalb des For $i-Loops ausführst. Der For $j-Loop wird im ungünstigsten Fall also 15x ausgeführt und schlimmer noch, bei jedem Durchgang prüfst du immer dasselbe Inputfeld =>> $aRead_Inputbox[$i]!

In dem For $k-Loop liest du die ersten fünf Inhalte der Inputfelder nochmals ein, was gar nicht nötig ist, denn du hast sie ja bereits eingelesen! Sinnfrei wird dieser Loop durch die nächste Zeile, denn somit prüfst du 6x, ob $aRead_Inputbox[0] = $aRead_Inputbox[5] ist.

Übersichtlicher und leichter verständlich wäre es etwa so...

AutoIt

;-- TIME_STAMP   2018-08-12 12:56:49   v 0.1

Global $aMsgBox = [
        ["1.Kein Umwandlungsordner angegeben!"                                          , "1.Pfad für den Umwandlungsordner (lokal) ungültig!"], _
        ["2.Kein Verzeichnis für die Stuecklisten angegeben!"                           , "2.Pfad für die Stücklisten (lokal) ungültig!"], _
        ["3.Kein Verzeichnis für die NC-Daten (nc-blech) angegeben!"                    , "3.Pfad für die NC-Daten (nc-blech, lokal) ungültig!"], _
        ["4.Kein Verzeichnis für die NC-Daten (nc-profil) angegeben!"                   , "4.Pfad für die NC-Daten (nc-profil, lokal) ungültig!"], _
        ["5.Kein Pfad im Zielverzeichnis für das Fertigungspaket angegeben!"            , "5.Pfad für das Fertigungspaket (lieferungen, lokal) ungültig!"], _
        ["6.Kein Pfad im Auftragsordner für die bmf´s angegeben!"                       , "6.Pfad für die bmf´s (plaene, lokal) ungültig!"], _
        ["7.Kein Server-Verzeichnis für die Stuecklisten angegeben!"                    , "7.Pfad für die Stücklisten (Server) ungültig!"], _
        ["8.Kein Server-Verzeichnis für die pdf-Dateien angegeben!"                     , "8.Pfad für die Werkstattpläne (pdf´s, Server) ungültig!"], _
        ["9.Kein Server-Verzeichnis für die dwg-Dateien angegeben!"                     , "9.Pfad für die Werkstattpläne (dwg´s, Server) ungültig!"], _
        ["10.Kein Server-Verzeichnis für die bmf-Dateien angegeben!"                    , "10.Pfad für die Werkstattpläne (bmf´s, Server) ungültig!"], _
        ["11.Kein Server-Verzeichnis für die Teilsystemperspektive als pdf angegeben!"  , "11.Pfad für die Teilsystemperspektive (pdf´s, Server) ungültig!"], _
        ["12.Kein Server-Verzeichnis für die Teilsystemperspektive als dwg angegeben!"  , "12.Pfad für die Teilsystemperspektive (dwg´s, Server) ungültig!"], _
        ["13.Kein Server-Verzeichnis für die Teilsystemperspektive als bmf_ angegeben!" , "13.Pfad für die Teilsystemperspektive (bmf´s, Server) ungültig!"], _
        ["14.Kein Server-Verzeichnis für die NC-Daten angegeben!"                       , "14.Pfad für die NC-Daten (Server) ungültig!"], _
        ["15.Kein Server-Verzeichnis für die Abwicklungen-Kantteile angegeben!"         , "15.Pfad für die Abwicklungen Kantteile (dxf, Server) ungültig!"], _
        ["16.Umwandlungsordner kann nicht gleich dem Ordner 'plaene' sein!"], _
        ["Sie haben einen Sicherungsauftrag gewählt! Die Aktion wird abgebrochen! Bitte wählen Sie einen Sortierauftrag."]] ; Was ist mit dieser Meldung?


;weiterer Code.....


Func Sortierauftrag_anlegen()
    Local Static $aState = [$GUI_ENABLE, $GUI_DISABLE]
    Local $iState = -1

    GUICtrlSetState($Button_Auftrag_bearbeiten, $GUI_DISABLE)
    GUICtrlSetState($Button_Auftrag_Anlegen, $GUI_DISABLE)

    If GUICtrlRead($Checkbox_Fremdauftrag) = $GUI_UNCHECKED Then
;~     Input auslesen und auf Vollständigkeit und Gültigkeit prüfen.
        For $i = 0 To 14
            $aRead_Inputbox[$i] = GUICtrlRead($aInputbox[$i])
            Select
                Case $aRead_Inputbox[$i] = ''
                    $iState = MsgBox(16, "Error", "" & $aMsgBox[$i][0])
                Case FileExists($aRead_Inputbox[$i]) = 0
                    $iState = MsgBox(16, "Error", "" & $aMsgBox[$i][1])
                Case $i > 0 And $i < 6 And $aRead_Inputbox[$i] = $aRead_Inputbox[0]
                    $iState = MsgBox(16, "Error", "" & $aMsgBox[15][0])
            EndSelect
            If $iState = -1 Then ContinueLoop
            GUICtrlSetState($Button_Auftrag_bearbeiten, $aState[$iState)
            GUICtrlSetState($Button_Auftrag_Anlegen, $aState[$iState)
            Return
        Next
    EndIf
EndFunc   ;==>Sortierauftrag_anlegen

Alles anzeigen

Mikki

Hallo Bitnugger

okay gut danke für die Antwort. Wieder was dazu gelernt

LG Mikki