Drag and Drop auf Toolbar

**Oscar**

Ich habe ein kleines Problem.

Und zwar möchte ich eine Datei vom Explorer auf die Toolbar in meinem Script ziehen. Im Prinzip klappt das auch.

Ich habe als Extended-Style bei der GUI "$WS_EX_ACCEPTFILES" angegeben und bei der Toolbar "$TBSTYLE_REGISTERDROP".

Somit erhalte ich bei $WM_NOTIFY einen Notification-Code "$TBN_GETOBJECT", wenn ich die Datei über der Toolbar bewege.

Das Problem ist jetzt, wie bekomme ich den Dateinamen von der Datei heraus?

Ich kriege eine piid, also wohl einen Pointer auf ein Objekt, aber was fange ich damit an? Wie kriege ich den Dateinamen raus?

Hier mal ein Minimalbeispiel:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <RebarConstants.au3>
#include <StructureConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>


Opt('GUIOnEventMode', 1)

Global $hMainGui = GUICreate('Test', 1020, 480, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPCHILDREN), $WS_EX_WINDOWEDGE + $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseMainGui')
Global $hDrivesRebar = _GUICtrlRebar_Create($hMainGui, BitOR($CCS_TOP, $CCS_NODIVIDER, $RBS_VARHEIGHT, $RBS_BANDBORDERS))
Global $hUserToolbar = _GUICtrlToolbar_Create($hMainGui, BitOR($TBSTYLE_FLAT, $CCS_NOPARENTALIGN, $WS_CHILD, $WS_CLIPSIBLINGS, $WS_VISIBLE, $TBSTYLE_REGISTERDROP))
_GUICtrlRebar_AddToolBarBand($hDrivesRebar, $hUserToolbar, '', 0, $RBBS_NOGRIPPER)
GUISetState()
GUIRegisterMsg($WM_NOTIFY, '_WM_NOTIFY')
WinWaitClose($hMainGui)
Exit

Func _CloseMainGui()
    GUIDelete($hMainGui)
EndFunc   ;==>_CloseMainGui

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, 'hWndFrom'))
    $iCode = DllStructGetData($tNMHDR, 'Code')
    Switch $hWndFrom
        Case $hUserToolbar
            Switch $iCode
                Case $TBN_GETOBJECT
                    Local $tOBJECTNOTIFY = DllStructCreate($tagNMOBJECTNOTIFY, $lParam)
                    _DebugPrint("$RBN_GETOBJECT" & @CRLF & "--> hWndFrom:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "hWndFrom") & @CRLF & _
                                "-->IDFrom:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "IDFrom") & @CRLF & _
                                "-->Code:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "Code") & @CRLF & _
                                "-->Item:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "Item") & @CRLF & _
                                "-->piid:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "piid") & @CRLF & _
                                "-->pObject:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "pObject") & @CRLF & _
                                "-->Result:" & @TAB & DllStructGetData($tOBJECTNOTIFY, "Result"))
            EndSwitch
    EndSwitch
EndFunc

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

Alles anzeigen

**autoBert**

Funktioniert hier nicht das gleiche Schema, das du in deinem FileCommander angewendet hast?

**Oscar**

Zitat von autoBert

Funktioniert hier nicht das gleiche Schema, das du in deinem FileCommander angewendet hast?

Im "alten" FileCommander habe ich keine echte Toolbar verwendet. Das sind "nur" normale Buttons und das Drag and Drop funktioniert über ein unsichtbares Label.

Ich bin aber gerade dabei, den FileCommander von Grund auf neu zu schreiben und ich habe bereits die obere Toolbar und auch die Laufwerkbuttons als echte Toolbar.

**autoiter**

Hallo Oscar ,

eigentlich habe ich keine Antwort auf deine Frage. Falls aber auch $WM_DROPFILES in Ordnung wäre, habe ich hier etwas gefunden.

C

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <RebarConstants.au3>
#include <StructureConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3> ; _ArrayToString


Opt('GUIOnEventMode', 1)
Global $gaDropFiles[1] ; Das globale Array


Global $hMainGui = GUICreate('Test', 1020, 480, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPCHILDREN), $WS_EX_WINDOWEDGE + $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseMainGui')
Global $hDrivesRebar = _GUICtrlRebar_Create($hMainGui, BitOR($CCS_TOP, $CCS_NODIVIDER, $RBS_VARHEIGHT, $RBS_BANDBORDERS))
Global $hUserToolbar = _GUICtrlToolbar_Create($hMainGui, BitOR($TBSTYLE_FLAT, $CCS_NOPARENTALIGN, $WS_CHILD, $WS_CLIPSIBLINGS, $WS_VISIBLE, $TBSTYLE_REGISTERDROP))
_GUICtrlRebar_AddToolBarBand($hDrivesRebar, $hUserToolbar, '', 0, $RBBS_NOGRIPPER)
GUISetState()
;~ GUIRegisterMsg($WM_NOTIFY, '_WM_NOTIFY')
GUIRegisterMsg ($WM_DROPFILES, "WM_DROPFILES_UNICODE_FUNC") ; Die alternative Funktion
WinWaitClose($hMainGui)
Exit


Func _CloseMainGui()
    GUIDelete($hMainGui)
EndFunc   ;==>_CloseMainGui


Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint


Func WM_DROPFILES_UNICODE_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 255)
    For $i = 0 To $nAmt[0] - 1
        $nSize = DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
        $nSize = $nSize[0] + 1
        $pFileName = DllStructCreate("wchar[" & $nSize & "]")
        DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", $i, "int", DllStructGetPtr($pFileName), "int", $nSize)
        ReDim $gaDropFiles[$i + 1]
        $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
    _DebugPrint(_ArrayToString($gaDropFiles))
EndFunc   ;==>WM_DROPFILES_UNICODE_FUNC

Alles anzeigen

**Oscar**

Zitat von autoiter

Falls aber auch $WM_DROPFILES in Ordnung wäre,

Ja, die Funktion kenne ich bereits und das wäre evtl. eine Alternative, aber dabei wird die gesamte Gui als Ziel akzeptiert.

Ich hätte aber gern nur die Toolbar. Eine Kombination aus beiden ist auch nicht so einfach, weil WM_NOTIFY vor WM_DROPFILES aufgerufen wird.

Dann müsste ich das über globale Variablen anpassen.

Da kann ich dann auch wieder ein transparentes Label benutzen. Damit klappt auch das interne @GUI_DragFile.

Ich hatte halt die Hoffnung, dass man anhand der PIID irgendwie den Dateinamen herausbekommen könnte...

**autoiter**

Statt einer Kombination von WM_NOTIFY vor WM_DROPFILES würde ich versuchen, in der WM_DROPFILES einen Check einzubauen, über welchem Control der Cursor ist, um das Drop-Event einem Control zuzuordnen.

Zitat von Oscar

Ich hatte halt die Hoffnung, dass man anhand der PIID irgendwie den Dateinamen herausbekommen könnte...

Naja warte mal ab. Hier gibt es ja deutlich hellere Geister als mich

**BugFix**

Ich würde etwa so vorgehen:

- Permanent bei Öffnen eines Fensters prüfen, ob es der Explorer ist.

--> Wenn ja: Verliert das Fenster den Fokus --> Auslesen welche Datei markiert ist. --> Folgt jetzt ein Datei-Drop-Event, kann es nur die gerade ausgelesene Datei sein.

EDIT:

Hier mal ein Bsp. wie du aus dem Explorer auslesen kannst.

ACHTUNG: Mit Bibliotheken kann die Funktion nur bedingt umgehen. Dateinamen können gelesen werden, aber der Pfad zur Bibliothek nicht.

AutoIt

Local $a = _GetSelectionFromTopMostExplorer(False)
ConsoleWrite($a[1] & @CRLF)


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetSelectionFromTopMostExplorer
; Description ...: Gets an array with selected files from the top most explorer window
; Syntax ........: _GetSelectionFromTopMostExplorer([$_bDir = True])
; Parameters ....: $_bDir       - [optional] Returns the full path (Default 'True'). With 'False' will only the filename returned.
; Return values .: Array with selected files. Counter at $ar[0]
; Requires.......: _GetTopmostHwndFromProcess()
; Author ........: BugFix
; ===============================================================================================================================
Func _GetSelectionFromTopMostExplorer($_bDir=True)
    Local $oShell = ObjCreate("Shell.Application")
    Local $oIE, $sPath, $oShellWindows = $oShell.Windows
    Local $oDoc, $bIE = False, $oFV
    For $i = 0 To $oShellWindows.Count -1  ; all opened explorer and internet explorer windows
        $oIE = $oShellWindows($i)
        $oDoc = $oIE.Document
        If _GetTopmostHwndFromProcess('explorer.exe', 'CabinetWClass') = $oIE.Hwnd Then
            If StringRegExp(ObjName($oDoc), "IShellFolderViewDual.") Then       ; be sure it's the explorer object
                $sPath =StringReplace(StringReplace(StringTrimLeft($oIE.LocationURL, 8), '%20', ' '), '/', '\') ; extract windows path from file-url
                $bIE = True   ; flag: found explorer
            EndIf
        EndIf
    Next
    Local $aSelection[500] = [0]
    If $bIE Then
        $oFV = $oIE.Document             ; Datei-Browser (ShellFolderView)
        For $oFI In $oFV.SelectedItems   ; Markierte Elemente darin
            $aSelection[0] += 1
            If $aSelection[0] > UBound($aSelection) Then ReDim $aSelection[UBound($aSelection) +500]
            If Not $_bDir Then $sPath = ''
            $aSelection[$aSelection[0]] = StringFormat('%s%s',  $sPath, $oFI.Name)
        Next
    EndIf
    If $aSelection[0] = 0 Then
        ReDim $aSelection[1]
    Else
        ReDim $aSelection[$aSelection[0]+1]
    EndIf
    Return $aSelection
EndFunc ;==>_GetSelectionFromTopMostExplorer



; #FUNCTION# ====================================================================================================================
; Name ..........: _GetTopmostHwndFromProcess
; Description ...: Returns the handle of the top most window of a specific process
; Syntax ........: _GetTopmostHwndFromProcess($_vProcess)
; Parameters ....: $_vProcess           The Process name or PID
;                  $_sClass             The classname of windows that will created by the specific process
; Return values .: Success              The handle of the top most window
;                  Failure              0, set @error = 1 (process does not exists)
;                                              @error = 2 (there is no window for this)
; Author ........: BugFix
; ===============================================================================================================================
Func _GetTopmostHwndFromProcess($_vProcess, $_sClass)
    Local $aProc[2][2] = [[1],['',$_vProcess]]
    If IsString($_vProcess) Then
        $aProc = ProcessList($_vProcess)
        If $aProc[0][0] = 0 Then
            Return SetError(1,0,0)
        EndIf
    Else
        If Not ProcessExists($_vProcess) Then Return SetError(1,0,0)
    EndIf
    Local $hWnd = 0, $aWin =  WinList('[CLASS:' & $_sClass & ']')
    If $aWin[0][0] = 0 Then Return SetError(2,0,0)
    Local $tPID = DllStructCreate("int")
    ; check only the first window, has highest z-order
    For $i = 1 To $aProc[0][0]
        DllCall("user32.dll", "int", "GetWindowThreadProcessId", "hwnd", $aWin[1][1], "ptr", DllStructGetPtr($tPID))
        If DllStructGetData($tPID,1) = $aProc[$i][1] Then Return $aWin[1][1]
    Next
    Return 0
EndFunc ;==>_GetTopmostHwndFromProcess

Alles anzeigen

**Oscar**

Zitat von BugFix

Hier mal ein Bsp. wie du aus dem Explorer auslesen kannst.

Es ist nett von euch, mir Workaraounds vorzuschlagen, aber der einfachste Workaround ist ein transparentes Label unter der Toolbar (habe ich schon ausprobiert).

Das funktioniert und vermutlich werde ich das wohl auch so machen.

Ich hatte mich halt gefragt, warum es bei der Toolbar den Style "$TBSTYLE_REGISTERDROP" gibt und man bei WM_NOTIFY die Message "$TBN_GETOBJECT" bekommt, wenn man die "Quelle" (den Dateinamen) nicht ermitteln kann?

Ich vermute, dass das irgendwie in dieser PIID (Pointer auf ein Object) steckt, aber ich konnte nicht herausbekommen, wie man das "dekodiert".

**chesstiger**

Du kannst auch einfach WM_DROPFILES überwachen. Das Drop-Event in WParam enthält einerseits alle Dateinamen, andererseits auch die Koordinaten des "Loslassens". Über ChildWindowFromPoint kannst du dir dann das entsprechende Control-Handle holen und schauen, ob es deine Toolbar ist.

C

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <RebarConstants.au3>
#include <StructureConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <WinAPISys.au3>




Opt('GUIOnEventMode', 1)


Global $hMainGui = GUICreate('Test', 1020, 480, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPCHILDREN), $WS_EX_WINDOWEDGE + $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseMainGui')
Global $hDrivesRebar = _GUICtrlRebar_Create($hMainGui, BitOR($CCS_TOP, $CCS_NODIVIDER, $RBS_VARHEIGHT, $RBS_BANDBORDERS))
Global $hUserToolbar = _GUICtrlToolbar_Create($hMainGui, BitOR($TBSTYLE_FLAT, $CCS_NOPARENTALIGN, $WS_CHILD, $WS_CLIPSIBLINGS, $WS_VISIBLE, $TBSTYLE_REGISTERDROP))
_GUICtrlRebar_AddToolBarBand($hDrivesRebar, $hUserToolbar, '', 0, $RBBS_NOGRIPPER)
GUISetState()
GUIRegisterMsg($WM_DROPFILES, "WM_DROPFILES")
WinWaitClose($hMainGui)
Exit


Func _CloseMainGui()
GUIDelete($hMainGui)
EndFunc   ;==>_CloseMainGui


Func WM_DROPFILES($hWnd, $msgID, $wParam, $lParam)
Local $nSize, $pFileName
$tPoint = _WinAPI_DragQueryPoint($wParam)
If Not DllStructGetSize($tPoint) Then Return ;window border
$hCtrl = _WinAPI_ChildWindowFromPointEx($hWnd, $tPoint)
ConsoleWrite("File drop to coordinates (" & $tPoint.X & "|" & $tPoint.Y & "), this is child window handle " & $hCtrl & "." & @CRLF)
If $hCtrl <> $hDrivesRebar Then Return ;not the target control, abort
$aFiles = _WinAPI_DragQueryFileEx($wParam)
ConsoleWrite("Drop to our toolbar registered, containing " & $aFiles[0] & " files." & @CRLF)
For $i = 1 To $aFiles[0]
ConsoleWrite("- " & $aFiles[$i] & @CRLF)
Next
EndFunc

Alles anzeigen

**Oscar**

Zitat von chesstiger

Das Drop-Event in WParam enthält einerseits alle Dateinamen, andererseits auch die Koordinaten des "Loslassens". Über ChildWindowFromPoint kannst du dir dann das entsprechende Control-Handle holen und schauen, ob es deine Toolbar ist.

Ja, ich denke, das ist als Workaround noch besser, als das transparente Label.

Vermutlich werde ich diese Variante benutzen. Danke schön!

Die Toolbar wird unter AutoIt scheinbar nicht so oft benutzt. Man findet im Netz nur sehr wenig Scripte dazu.