InetGet lädt keine große Dateien

**Tweaky**

Hi,

ich will mit InetGet Fotos vom iPad herunterladen.

Über eine App auf dem iPad werden die Fotos auf dem PC als Zip zur Verfügung gestellt. (http://192.168.xx.xxx:8080...)

Dies funktioniert auch.

Allerdings werden große Dateien (ca. > 80MB) nicht heruntergeladen.

InetGetInfo zeigt als Größe 0 an.

Wenn ich die Datei mit dem Firefox oder Internet Explorer downloade funktioniert es.

Gibt es noch eine andere Downloadfunktion von AutoIt?

**autoiter**

Hallo Tweaky

hmm, das kann ich nicht nachvollziehen. Eben habe ich mit dem InetGet-Beispiel Raspbian heruntergeladen. Das hat einwandfrei funktioniert. Vielleicht ist die Verbindung über die App nicht so stabil und die Browser sind da toleranter? Keine Ahnung. Vielleicht hast du einfach einen Fehler gemacht?

Ich kenne nur noch InetRead

Alternativ würde ich vorschlagen, du probierst es noch mal mit _DownloadWithProgress von Oscar. Das ist zwar auch InetGet, aber sicherlich eine einwandfreie Umsetzung mit einer sicher gerne gesehenen Statusanzeige während des Downloads größerer Dateien.

**Bitnugger**

Evtl. hilft es, die Timeouts (CONNECT TIMEOUT und/oder RECEIVE TIMEOUT) zu ändern...

Kannst ja mal dieses Script testen, ob es damit geht.

AutoIt

;-- TIME_STAMP   2018-11-11 19:00:00   v 0.1

Global Const $INTERNET_OPTION_CONNECT_TIMEOUT = 2, $INTERNET_OPTION_RECEIVE_TIMEOUT = 6
Global $CONNECT_TIMEOUT = 0xFFFFFF, $RECEIVE_TIMEOUT = 0xFFFFFF

_InternetSetOptionsW()

; ...hier dein Script
;~ InetGet(...)

Func _InternetSetOptionsW()
    Local $hWININET = DllOpen("wininet.dll"), $hInternet = 0, $aRes, $tTime = DllStructCreate("long")
    DllStructSetData($tTime, 1, $CONNECT_TIMEOUT)
    $aRes = DllCall($hWININET, 'dword', 'InternetSetOptionW', 'int', $hInternet, 'dword', $INTERNET_OPTION_CONNECT_TIMEOUT, "ptr", DllStructGetPtr($tTime), "dword", DllStructGetSize($tTime))
    If @error Or $aRes[0] = 0 Then
        DllCall($hWININET, 'int', 'InternetCloseHandle', 'int', $hInternet)
        DllClose($hWININET)
        ConsoleWrite('! CONNECT_TIMEOUT konnte nicht geändert werden!' & @CRLF)
        Return SetError(1, 0, "")
    EndIf
    ConsoleWrite('+ CONNECT_TIMEOUT wurde geändert!' & @CRLF)

    DllStructSetData($tTime, 1, $RECEIVE_TIMEOUT)
    $aRes = DllCall($hWININET, 'int', 'InternetSetOptionW', 'int', $hInternet, 'dword', $INTERNET_OPTION_RECEIVE_TIMEOUT, "ptr", DllStructGetPtr($tTime), "dword", DllStructGetSize($tTime))
    If @error Or $aRes[0] = 0 Then
        DllCall($hWININET, 'int', 'InternetCloseHandle', 'int', $hInternet)
        DllClose($hWININET)
        ConsoleWrite('! RECEIVE_TIMEOUT konnte nicht geändert werden!' & @CRLF)
        Return SetError(1, 0, "")
    EndIf
    ConsoleWrite('+ RECEIVE_TIMEOUT wurde geändert!' & @CRLF)

    Return True
EndFunc  ;==>__InternetSetOptionsW

Alles anzeigen

**Tweaky**

Bitnugger Danke, damit funktioniert es.

Aber was genau bewirkt dies?

Wird länger gewartet, wenn keine Rückmeldung kommt?

Hat diese Funktion Nachteile?

**Bitnugger**

Zitat von Tweaky

Aber was genau bewirkt dies?

Wird länger gewartet, wenn keine Rückmeldung kommt?

Ja, es wird länger gewartet, wenn keine Rückmeldung kommt.

Global $CONNECT_TIMEOUT = 0xFFFFFF, $RECEIVE_TIMEOUT = 0xFFFFFF

Hier habe ich für CONNECT TIMEOUT und RECEIVE TIMEOUT die größtmöglichen Werte gesetzt. Für dich ist sicher $RECEIVE_TIMEOUT der wichtigere Wert.

Du kannst die Werte ja mal schrittweise verringern - z.B.: 0x0FFFFF, 0x00FFFF, 0x000FFF.

Zitat von Tweaky

Hat diese Funktion Nachteile?

In deinem Fall nein, aber ansonsten wäre es wohl extrem nervig, wenn man bei allen Verbindungen ewig lange auf eine Rückmeldung warten müsste und es am Ende dann doch nicht funktioniert.

Die Änderungen gelten nur für das ausgeführte Script (oder das angegebene Internet-Handle) und auch nur solange dieses läuft.