Drag & Drop aus 7z heraus

Gofel

Hallo,

ich möchte ein txt Datei die sich in einer zip Datei befindet auf meine GUI droppen. Ich packe die Textdatei also mit links im 7z Dateimanager an und lasse sie auf meine GUI fallen. Wärend ich die Datei über den Bildschirm bewege wird diese auch ordnungsgemäß in z.B. %temp%\7zECE395076\test.txt entpackt. Sobald ich sie auf die GUI droppe wird die Datei sofort wieder von 7z gelöscht, offensichtlich noch bevor in Autoit der Event ausgelöst wird. Es ist mir also nicht möglich mit dieser Datei zu interagieren.

Kann mir jemand einen Tipp geben wie das gehen soll?

Kleines Beispielscript:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)

GUICreate("Test GUI", 300, 100, -1, -1, -1, $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_DROPPED, "On_Drop")
GUISetOnEvent($GUI_EVENT_CLOSE, '_exit')

GUICtrlCreateInput('', 28, 20, 240, 20)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

GUISetState(@SW_SHOW)

Do
    Sleep(10)
Until 0



Func On_Drop()

    $ret = FileCopy(@GUI_DragFile, @DesktopDir & "\test.txt")
    MsgBox(0,"",$ret)

EndFunc   ;==>On_Drop

Func _exit()
    Exit 1
EndFunc   ;==>_exit

Alles anzeigen

Danke!

**Bitnugger**

Schau dir mal in der AutoIt-Hilfe das Beispiel zu der Function _WinAPI_DragFinish an - damit funktioniert es!

Gofel

Danke für deine Hilfe, aber es verhält sich genau gleich. Die Datei ist weg bevor ich sie einlesen kann. Oder mach ich was falsch?

Hier ist der Code aus der Hilfe. Zeile 49 ist von mir, ich erhalte eine leere MsgBox.

Zumindest meistens! Von 10 Versuchen ist auch mal einer dabei wo es klappt und Autoit schneller ist als 7z die Datei löschen konnte.

C

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

OnAutoItExitRegister('OnAutoItExit')

; Create GUI
Local $hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'), 400, 400)
Local $idCheck = GUICtrlCreateCheckbox('Enable Drag && Drop', 10, 370, 120, 19)
Local $idLabel = GUICtrlCreateLabel('', 100, 100, 200, 200)
Global $g_hLabel = GUICtrlGetHandle($idLabel)
GUICtrlSetBkColor(-1, 0xD3D8EF)
GUICtrlCreateLabel('Drop here', 175, 193, 50, 14)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

; Allow WM_DROPFILES to be received from lower privileged processes (Windows Vista or later)
#cs
If IsAdmin() Then
    _WinAPI_ChangeWindowMessageFilterEx($g_hLabel, $WM_COPYGLOBALDATA, $MSGFLT_ALLOW)
    _WinAPI_ChangeWindowMessageFilterEx($g_hLabel, $WM_DROPFILES, $MSGFLT_ALLOW)
EndIf
#ce

; Register label window proc
Global $g_hDll = DllCallbackRegister('_WinProc', 'ptr', 'hwnd;uint;wparam;lparam')
Global $g_pDll = DllCallbackGetPtr($g_hDll)
Global $g_hProc = _WinAPI_SetWindowLong($g_hLabel, $GWL_WNDPROC, $g_pDll)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idCheck
            _WinAPI_DragAcceptFiles($g_hLabel, GUICtrlRead($idCheck) = $GUI_CHECKED)
    EndSwitch
WEnd

Func _WinProc($hWnd, $iMsg, $wParam, $lParam)
    Switch $iMsg
        Case $WM_DROPFILES
            Local $aFileList = _WinAPI_DragQueryFileEx($wParam)
            If Not @error Then
                ConsoleWrite('--------------------------------------------------' & @CRLF)
                For $i = 1 To $aFileList[0]
                    ConsoleWrite($aFileList[$i] & @CRLF)
                    MsgBox(0, "", FileRead($aFileList[$i]))
                Next
            EndIf

            _WinAPI_DragFinish($wParam)
            Return 0
    EndSwitch
    Return _WinAPI_CallWindowProc($g_hProc, $hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_WinProc

Func OnAutoItExit()
    _WinAPI_SetWindowLong($g_hLabel, $GWL_WNDPROC, $g_hProc)
    DllCallbackFree($g_hDll)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

**Bitnugger**

Zitat von Gofel

Danke für deine Hilfe, aber es verhält sich genau gleich. Die Datei ist weg bevor ich sie einlesen kann. Oder mach ich was falsch?

Nein, du machst nichts falsch... ich habe es gerade noch mal ausführlich bei mir getestet und bei mir funktioniert es auch nur ab und zu.

Der 7z Dateimanager löscht die Files also tatsächlich sofort, nachdem die Drag-Message versendet wurde, und somit sind die Files teilweise schon gelöscht, bevor die Drag-Message in deinem Script ankommt... tzzz... das ist aber echt ka***!

Mit WinRAR funktioniert es aber immer... mit deinem Beispiel-Script geht es nur mit 7zFM.exe und WinRAR.exe... mit dem Beispiel zu der Function _WinAPI_DragFinish geht es aber z.B. auch mit Total-Commander!

Hier nochmal dein Beispiel-Script... etwas geändert... funktioniert aber auch nicht mit Total-Commander.

C

;-- TIME_STAMP   2018-12-14 18:03:19   v 0.1

#Region    ;************ Includes ************
#include-once
#include <WinAPI.au3>       ; <= AutoIt-Version 3.3.14.2
#include <WinAPISysWin.au3> ; >= AutoIt-Version 3.3.14.3
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#EndRegion ;************ Includes ************

Opt("GUIOnEventMode", 1)

Global $idInput, $idEdit

GUICreate("Test GUI", 800, 240, -1, -1, -1, $WS_EX_ACCEPTFILES)
;~ GUISetOnEvent($GUI_EVENT_DROPPED, "_On_Drop")
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')

$idInput = GUICtrlCreateInput('', 10, 20, 780, 20)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

$idEdit = GUICtrlCreateEdit('', 10, 50, 780, 180)
GUICtrlSetFont(-1, 10, 400, 0, 'Courier New')

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_DROPFILES, '_WM_DROPFILES')

Do
    Sleep(10)
Until 0

Func _WM_DROPFILES($hWnd, $iMsg, $wParam, $lParam)
    Switch $iMsg
        Case $WM_DROPFILES
            Local $aFileList = _WinAPI_DragQueryFileEx($wParam)
            If Not @error Then
                GUICtrlSetData($idEdit, '--------------------------------------------------' & @CRLF, 1)
                For $i = 1 To $aFileList[0]
                    GUICtrlSetData($idEdit, StringFormat('FileExists = %i  DragFile_%03i = %s\r\n', FileExists($aFileList[$i]), $i, $aFileList[$i]), 1)
                Next
            EndIf
            _WinAPI_DragFinish($wParam)
            Return 0
    EndSwitch
    Return $GUI_RUNDEFMSG ; Anweisung an Windows, dass es mit der normalen Abarbeitung fortfahren kann
EndFunc

;~ Func _On_Drop()
;~     $ret = FileCopy(@GUI_DragFile, @DesktopDir & "\test.txt")
;~     MsgBox(0,"",$ret)
;~     Local $aFiles = StringSplit(GUICtrlRead($idInput) & '|', '|', 2)
;~     _ArrayDelete($aFiles, UBound($aFiles) -1)
;~     If UBound($aFiles) Then
;~         GUICtrlSetData($idEdit, '@GUI_DragFile = ' & @GUI_DragFile & @CRLF, 1)
;~         For $i = 0 To UBound($aFiles) -1 Step 1
;~             GUICtrlSetData($idEdit, StringFormat('DragFile_%03i     = %s\r\n', $i, $aFiles[$i]), 1)
;~         Next
;~     EndIf
;~ EndFunc   ;==>_On_Drop

Func _Exit()
    Exit 1
EndFunc   ;==>_Exit

Alles anzeigen

Gofel

Nett das du dich reinhängst, danke.

Es muss da doch einen Trick geben, andere Programme kommen mit dem Drop klar. Notepad++ zeigt das Textdokument anstandslos an wenn ich es darauf droppe.

Bin also für weitere Hinweise dankbar!

Drag & Drop aus 7z heraus

Ähnliche Themen

Drag and Drop auf Toolbar