Anwendung bleibt stehen, was tun?

Code4Fun

Hallo zusammen,

ich habe vor ein paar Wochen ein Autoit Script gebaut, welches "eigentlich" zuverlässig läuft. Ca. alle 10 Sekunden kommt dabei ein Logfile Eintrag zustanden. Somit kann ich remote - via Logfile - sehen, ob die Anwendung noch läuft. Jeden Tag wird ein neues Logfile generiert. Es kam dann man der Zustand, dass nach 4 oder 5 Tagen kein Logfile mehr vom aktuellen Tag vorhanden war. Ich habe dann festgestellt, dass das Logfile vom Vortag mittendrin aufgehört hat zu protokollieren.

Daraufhin lassen ich jetzt um kurz vor Mitternacht den PC automatisch neu durchstarten (die paar Minuten tun mir nicht weh). Danach fängt die Anwendung wieder an zu protokollieren. Leider kommt es jetzt ab und zu vor, dass binnen 24 Stunden die Anwendung auch nicht mehr protokolliert, obwohl Sie "optisch" noch läuft. Wie kann man denn sowas abfangen, also einen Prozess, der zwar noch laut Taskmanager aktiv ist, aber "innerlich" wohl schon tod?

**alpines**

Zitat von Code4Fun

Wie kann man denn sowas abfangen, also einen Prozess, der zwar noch laut Taskmanager aktiv ist, aber "innerlich" wohl schon tod?

Uns vielleicht den Code posten, weil wir grad knapp mit Glaskugeln sind.

Code4Fun

Sorry. Persönliche Daten wurden anonymisiert.

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_Icon=pushme.ico
    #AutoIt3Wrapper_Outfile_x64=MyServerMonitoringPushService.exe
    #AutoIt3Wrapper_Compression=4
    #AutoIt3Wrapper_Res_Comment=My Servermonitoring Push Service
    #AutoIt3Wrapper_Res_Description=My Servermonitoring Push Service
    #AutoIt3Wrapper_Res_Fileversion=0.1.0.52
    #AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
    #AutoIt3Wrapper_Res_LegalCopyright=Code4Fun
    #AutoIt3Wrapper_Res_Language=1031
    #AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
    #AutoIt3Wrapper_Run_Stop_OnError=y
    #AutoIt3Wrapper_Run_Tidy=y
    #Tidy_Parameters=/gd /reel /ri /sci 9  /kv 0
    #AutoIt3Wrapper_Run_Au3Stripper=y
    #Au3Stripper_Parameters=/so /mo
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <String.au3>
#include <WinHttp.au3>
#include <TrayConstants.au3>
#include <Array.au3>
#include <Date.au3>
#include <FileConstants.au3>

;HotKeySet("{ESC}", "_Exit")

#Region ; Script Kopf
    #cs ----------------------------------------------------------------------------
        AutoIt Version:     3.3.14.5
        Author:             Code4Fun

        Script Function:

        Diese Script soll sich automatisch auf der Monitoring Website einloggen und im Quelltext nach einem bestimmten Wort suchen.
        Wenn dieses Wort vorhanden ist, löse eine Push Me Aktion aus.
        Es soll so konfigurierbar sein, das über eine ini Datei BenutzerA, BenutzerB oder BenutzerC angetriggert werden.

        Erstellungendatum: vom 10.05.2019

        Änderungsdatum:

        Version: 0.0.1.0

        History:

        0.0.1.0 Initialerstellung
    #ce ----------------------------------------------------------------------------
#EndRegion ; Script Kopf

#Region ; Globale Variablen Deklaration
    Global $iMsg, $exititem, $sInputFreitext, $idMyedit, $sLesePushMeURL, $sLeseIdentifier, $sLeseTitle, $sLeseImageURL, $hGUI, $sLeseBody, $sLeseURL, $aAlarmString, $aAlarmServer, $aAlarmKlasse
    Global $aCSRF, $sPOST, $sServerName, $sPaket, $hConnect, $hSession, $aIEproxy, $sProxy, $sPaket2, $hConnect2, $sServerName2, $hSession2, $sBenutzerName, $sPasswort, $sLocation, $sLeseTitle4Log
    Global $iCount = 1, $iOrangeCounter = 0, $iRedCounter = 0
    Global $iAlarmCount = 0
    Global $iDurchlaufCounter = 1
    Global $sFileVersion = FileGetVersion(@AutoItExe)
    Global $sStartDatum = @WDAY & "." & @MON & "." & @YEAR
    Global $sStartZeit = @HOUR & ":" & @MIN & ":" & @SEC
#EndRegion ; Globale Variablen Deklaration
_WriteLog("### START ###")
AdlibRegister("_Monitoring_Login", 10000)

;Tray-Menü anpassen
Opt("TrayAutoPause", 0) ; Script will not be paused when clicking the tray icon.
Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1 + 2)
;Opt("TrayIconDebug", 1) ; Zeigt die aktuelle Skriptzeile im Trayicon Tipp um das Debugging zu unterstützen

$exititem = TrayCreateItem("Beenden")
TrayItemSetState(-1, $TRAY_UNCHECKED)
TrayItemSetOnEvent(-1, "_Exit")
TraySetState()

#Region ; Hauptschleife
    While 1
        ;Monitoring_Login()
        Sleep(1000)
    WEnd
#EndRegion ; Hauptschleife

#Region ; Funktionen

    Func _Monitoring_Login()
        _reboot()
        _IPChecker()
        If $sLocation = "GP" Then ; Login für Privat verwendet
            $sBenutzerName = "Benutzer"
            $sPasswort = "Passwort"
        Else ; Login für My verwenden
            $sBenutzerName = "Anderer Benutzer"
            $sPasswort = "anderes Passwort"
        EndIf
        _WriteLog($iDurchlaufCounter)
        TraySetToolTip("Version: " & $sFileVersion & @CRLF & "Start am: " & $sStartDatum & @CRLF & "um: " & $sStartZeit & " Uhr" & @CRLF & "Round: " & $iDurchlaufCounter & @CRLF & "O-Alarme: " & $iOrangeCounter & @CRLF & "R-Alarme: " & $iRedCounter)
        $hSession = _WinHttpOpen('Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:66.0) Gecko/20100101 Firefox/66.0')
        $sServerName = 'monitor.fqdn.tld'
        $hConnect = _WinHttpConnect($hSession, $sServerName)
        $sPaket = _WinHttpSimpleSSLRequest($hConnect, 'GET', '/')
        $aCSRF = _StringBetween($sPaket, 'name="csrf" value="', '" />')
        $iCount = 1
        _FileWrite($sPaket) ; schreibe eine Kontroll HTML Datei
        $sPOST = "csrf=" & $aCSRF[0] & "&user_name=" & $sBenutzerName & "&user_password=" & $sPasswort & "&action=login"
        $sPaket = ""
        While $sPaket = "" ;Entweder auf "0" = Zeichen oder 0 = Zahl prüfen
            $sPaket = _WinHttpSimpleSSLRequest($hConnect, 'POST', '/', 'https://monitor.fqdn.tld/', $sPOST)
        WEnd
        _FileWrite($sPaket) ; schreibe eine Kontroll HTML Datei
        Local $aAlarmString = _StringBetween($sPaket, '<div class="offline">', '<p>')
        Local $iError = @error
        If $iError = 1 Then
            $iAlarmCount = 0 ; 0 = alles im grünen Bereich
            TraySetIcon(@ScriptDir & "\green.ico")
        Else
            Local $sAlarmString = $aAlarmString[0]
            Local $aAlarmKlasse = _StringBetween($sAlarmString, '<div class="', '"') ; hier wird bestimmt, ob es ein orangener oder roter Alarm im Quelltext ist
            Local $aAlarmServer = _StringBetween($sAlarmString, '<h2>', '</h2>') ; hier wird das Serversystem ausgelesen.

            If $iAlarmCount = 0 Then
                If $aAlarmKlasse[0] = "entity warning" Then ; Orangener Alarm festgestellt
                    $iOrangeCounter += 1
                    $iAlarmCount = 1 ; 1 = orangener Alarm
                    TraySetIcon(@ScriptDir & "\orange.ico")
                    _WriteLog("System " & $aAlarmServer[0] & ": INSTABIL")
                    $sLeseTitle = $aAlarmServer[0] & @CRLF & " INSTABIL" & @CRLF
                    $sLeseTitle4Log = $aAlarmServer[0] & ": INSTABIL"
                    $sLeseBody = "Details via Login " & @CRLF & "Benutzer 'Anderer Benutzer'" & @CRLF & "Kennwort 'anderes Passwort'" & @CRLF & "hier ==>"
                    $sLeseImageURL = "https://monitor.fqdn.tld/pushme/OrangenerAlarm.jpg"
                    $sLeseURL = "https://monitor.fqdn.tld"
                    MsgBox(65584, "Info vom Servermonitoring", $sLeseTitle & @CRLF & "am: " & @MDAY & "." & @MON & "." & @YEAR & @CRLF & "um: " & @HOUR & ":" & @MIN & ":" & @SEC, 3)
                    _PushMeTo("BenutzerA", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                    _PushMeTo("BenutzerB", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
;~                     _PushMeTo("BenutzerC", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                EndIf
            EndIf

            If $iAlarmCount = 0 Or $iAlarmCount = 1 Then
                If $aAlarmKlasse[0] = "entity " Then ; Roter Alarm festgestellt
                    $iRedCounter += 1
                    $iAlarmCount = 2 ; 2 = roter Alarm
                    TraySetIcon(@ScriptDir & "\red.ico")
                    _WriteLog("System " & $aAlarmServer[0] & ": OFFLINE")
                    $sLeseTitle = $aAlarmServer[0] & @CRLF & " OFFLINE" & @CRLF
                    $sLeseTitle4Log = $aAlarmServer[0] & ": OFFLINE"
                    $sLeseBody = "Details via Login " & @CRLF & "Benutzer 'Anderer Benutzer'" & @CRLF & "Kennwort 'anderes Passwort'" & @CRLF & "hier ==>"
                    $sLeseImageURL = "https://monitor.fqdn.tld/pushme/RoterAlarm.jpg"
                    $sLeseURL = "https://monitor.fqdn.tld"
                    If $iAlarmCount = 2 Then
                        MsgBox(65552, "Info vom Servermonitoring", $sLeseTitle & @CRLF & "am: " & @MDAY & "." & @MON & "." & @YEAR & @CRLF & "um: " & @HOUR & ":" & @MIN & ":" & @SEC, 3)
                    EndIf
                    _PushMeTo("BenutzerA", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                    _PushMeTo("BenutzerB", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
;~                     _PushMeTo("BenutzerC", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                EndIf
            EndIf
        EndIf

        _WinHttpCloseHandle($hSession)
        $iDurchlaufCounter += 1
    EndFunc   ;==>_Monitoring_Login

    Func _PushMeTo($sVorname, $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL) ; Diese Funktion wird aufgerufen, wenn die Nachricht an BenutzerA gehen soll
        _LeseINI($sVorname) ; lese die INI Datei aus
        Local $bData = InetRead($sLesePushMeURL & "identifier=" & $sLeseIdentifier & "&title=" & _EncodeURL($sLeseTitle) & "&body=" & _EncodeURL($sLeseBody) & "&imageURL=" & _EncodeURL($sLeseImageURL) & '&url=' & _EncodeURL($sLeseURL), 1) ; Lese die URL. Durch den Aufruf der URL wird via GET die Nachricht an das iPhone gesendet.
        _WriteLog("Info an " & $sVorname & " : " & $sLeseTitle4Log)
        _WriteAlertLog($sLeseTitle4Log)
        Local $sData = BinaryToString($bData)
        If Not $sData = "OK" Then ; Wenn die Website KEIN OK zurück gibt, dann erzeuge Fehlermeldung
            _WriteLog("PushMe an " & $sVorname & ": fehlgeschlagen")
        Else
            _WriteLog("PushMe an " & $sVorname & ": erfolgreich")
        EndIf
    EndFunc   ;==>_PushMeTo

    Func _FileWrite($sHTML, $Zusatz = "") ; erstellt zu Kontrollzwecken lokale HTML Dateien,
        Local Const $sFilePath = @ScriptDir
        If FileExists($sFilePath) Then ; wenn das Verzeichnis existiert, dann.
            ;ConsoleWrite("Das Verzeichnis " & $sFilePath & " existiert bereits" & @CRLF)
        Else
            ShellExecute(@ScriptDir)
            DirCreate($sFilePath)
            ConsoleWrite("Das Verzeichnis " & $sFilePath & " wurde erstellt" & @CRLF)
        EndIf
        FileDelete($sFilePath & "\" & $iCount & "-MonitoringLogin" & $Zusatz & ".html")
        FileWrite($sFilePath & "\" & $iCount & "-MonitoringLogin" & $Zusatz & ".html", $sHTML)
        $iCount += 1
    EndFunc   ;==>_FileWrite

    Func _LeseINI($sSection) ; lese die PushMe.ini aus
        $sLeseIdentifier = IniRead(@ScriptDir & "\pushme.ini", $sSection, "identifier", "")
        $sLesePushMeURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "PushMeURL", "")
        ;$sLeseTitle = IniRead(@ScriptDir & "\pushme.ini", $sSection, "title", "")
        ;$sLeseBody = IniRead(@ScriptDir & "\pushme.ini", $sSection, "body", "")
        ;$sLeseURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "url", "")
        ;$sLeseImageURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "imageURL", "")
    EndFunc   ;==>_LeseINI

    Func _DecodeURL($sData) ; Diese Funktion stammt von Prog@ndy und decodiert meinen URL codierten Text wieder in Klartext
        Local $aData = StringSplit(StringReplace($sData, "+", " ", 0, 1), "%")
        $sData = ""
        For $i = 2 To $aData[0]
            $aData[1] &= Chr(Dec(StringLeft($aData[$i], 2))) & StringTrimLeft($aData[$i], 2)
        Next
        Return BinaryToString(StringToBinary($aData[1], 1), 4)
    EndFunc   ;==>_DecodeURL

    Func _EncodeURL($sData) ; Diese Funktion stammt von Prog@ndy und codiert meinen Klartext in einen URL codierten Text
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_EncodeURL

    Func _IPChecker() ; hier wird geprüft, ob die IP den String 192.168.192 enthält. Wenn ja, dann bin ich im Homeoffice, ansonsten im Geschäft
        If StringInStr(@IPAddress1 & " " & @IPAddress2 & " " & @IPAddress3 & " " & @IPAddress4, "192.168.192") Then ; hier bin ich im Homeoffice
            $sLocation = "GP" ; setze die Variable $sLocation auf GP
        Else ; und hier in Geschäft
            $sLocation = "UL" ; setze die Variable $sLocation auf UL
        EndIf
    EndFunc   ;==>_IPChecker

    Func _WriteLog($sLogFileText)
        Local Const $sFilePath = @ScriptDir & "\Log"
        If FileExists($sFilePath) Then
            ;mache nichts
        Else
            DirCreate($sFilePath)
        EndIf
        ; erstelle Logdatei
        Local $hFileopen = FileOpen($sFilePath & "\" & @YEAR & "-" & @MON & "-" & @MDAY & ".log", BitOR($FO_APPEND, $FO_UTF8))
        FileWrite($hFileopen, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "#: " & $sLogFileText & @CRLF)
        FileClose($hFileopen)
    EndFunc   ;==>_WriteLog

    Func _WriteAlertLog($sLogFileText)
        Local Const $sFilePath = @ScriptDir & "\Log"
        If FileExists($sFilePath) Then
            ;mache nichts
        Else
            DirCreate($sFilePath)
        EndIf
        ; erstelle Logdatei
        Local $hFileopen = FileOpen($sFilePath & "\" & @YEAR & "-" & @MON & "-" & @MDAY & "-Alert.log", BitOR($FO_APPEND, $FO_UTF8))
        FileWrite($hFileopen, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "#: " & $sLogFileText & @CRLF)
        FileClose($hFileopen)
    EndFunc   ;==>_WriteAlertLog

    Func _reboot()
        If @HOUR = 23 And @MIN = 59 Then
            _WriteLog("### Es ist 23:59 Uhr - System S0012214 wird automatisch neu gestartet ###")
            _WriteLog("### ENDE ###")
            Shutdown(22)
        EndIf
    EndFunc   ;==>_reboot

    Func _Exit()
        _WriteLog("### ENDE ###")
        Exit
    EndFunc   ;==>_Exit
#EndRegion ; Funktionen

Alles anzeigen

**alpines**

Zitat von Code4Fun

_WinHttpSimpleSSLRequest($hConnect, 'POST', '/', 'https://monitor.fqdn.tld/', $sPOST)

So auf Anhieb konnte ich nichts erkennen aber diese Zeile (Z. 105) wundert mich ein wenig. Denn du versuchst solange zu posten bis etwas gepostet wurde.

Es kann sein, dass die Verbindung unterwegs stirbt, weil dein Router neustartet oder unterwegs etwas verloren gegangen ist oder sonst was.

Bastel dort mal ein Timeout rein oder füg in regelmäßigen Abständen eine Debugzeile ein damit du siehst ab welcher Zeile dein Skript hängt.

Außerdem solltest du auch das Handle $hConnect schließen, das lässt du bei jeder Schleifeniteration offen.

Die Session _WinHttpOpen kann gerne offen bleiben, aber das Verbindungshandle zum Server musst du schließen bevor du dich erneut verbindest.

Code4Fun

Danke alpins, toller Tip. Habe es jetzt mal umgebaut. Mal schauen, ob ich das Problem damit einkreisen kann. Schönes Wochende. Bin jetzt erst mal mit Kind und Kegel 2 Wochen im WoMo unterwegs.

Anwendung bleibt stehen, was tun?

Ähnliche Themen

Frage zu CUI EXE Fenster

Matrix Multiplikation Rückwärts