FaceDetection UDF

**eukalyptus**

Hallo Allerseits!

Auf der Suche nach einer Möglichkeit, Gesichter zu erkennen, bin ich über das hier gestolpert: https://github.com/ShiqiYu/libfacedetection

Und daraus ist vorerst mal eine kleine UDF entstanden.

Funktioniert mit 32 und 64Bit.

Ich hab selber noch nicht viel ausprobiert und kann daher auch nicht viel über die Parameter sagen - am besten mit großen und kleinen, vielen und wenigen usw... Gesichtern ausprobieren.

Trotzdem viel Spaß!

LandMarks:

EDIT: Bugs behoben!

**UEZ**

Hallo eukalyptus,

schöne dich wieder hier zu sehen!

Das Ergebnis ist durchaus brauchbar. Ich habe leider nicht so viele Bilder mit Gesichtern, werde aber mal danach googeln.

Werty

Awesome, worked 9 out of ten times i tried, on a highres image of Sinead O'Conner it found a face inside her left eye.

It worked on UEZ avatar also, 45 confidence.

Thanks.

**alpines**

Zitat von Werty

It worked on UEZ avatar also, 45 confidence.

You are mistaken because the confidence value is printed behind "confidence" itself.

Since your inserted image is too small, it was printed out of bounds and is therefore not visible.

The value "45" is corresponding to the angle the face has.

Try with a bigger image and see four yourself

Werty

Ahh, i see, thanks, very interesting it finds the angle of the face, gonna play around with it some more.

Werty

Here's an example of Live WebCam Tracking using EscApi.dll (attached), place in same folder as Eukalyptos script.

Webcam obviously required :p

Could be used for controlling stuff with your head, I'm gonna play around with Irrlicht and control a 3D model of a head, with my head

C

#include "FaceDetection.au3"
#include <Array.au3>

HotKeySet("{ESC}", "_Exit")

Global $Width = 640, $Height = 480, $hGraphics
;--------------------------------------------------------------------------
; variables required for dshow escapi
Local $tagSimpleCapParams = "ptr mTargetBuf;" & "int mWidth;" & "int mHeight;"
Local $tSimpleCapParams = DllStructCreate($tagSimpleCapParams)
Local $tTargetBuf = DllStructCreate("BYTE[" & $Width*$Height*4 & "]")
Global $pTargetBuf = DllStructGetPtr($tTargetBuf)
DllStructSetData($tSimpleCapParams, 1, $pTargetBuf)
DllStructSetData($tSimpleCapParams, 2, $Width)
DllStructSetData($tSimpleCapParams, 3, $Height)
Local $pSimpleCapParams = DllStructGetPtr($tSimpleCapParams)
Local $device = 0 ;change this number to select dshow device

;---------------------------------------------------------------------------
;Escapi init
Global $hGui = GUICreate("WebCam FaceDetection", $Width, $Height)
GUISetState(@SW_SHOW,$hGui)

local $_escapi_Dll = DllOpen("escapi.dll")
$return = DllCall($_escapi_Dll,"int","initCOM")
$return = DllCall($_escapi_Dll,"int","countCaptureDevices")
;Consolewrite("Number of devices = " & $return[0] & @CRLF)
$return = DllCall($_escapi_Dll,"int:cdecl","initCapture", "int", $device, "ptr", $pSimpleCapParams)
;---------------------------------------------------------------------------
_GDIPlus_Startup()

While 1
$hGfx = _GDIPlus_GraphicsCreateFromHWND($hGui)
;Get frame
DllCall($_escapi_Dll,"none:cdecl","doCapture", "int", $device)
Do
$return = DllCall($_escapi_Dll,"int:cdecl","isCaptureDone", "int", $device)
Until $return[0] = 1

$hBitmap = _WinAPI_CreateBitmap($Width, $Height , 1 , 32 , $pTargetBuf)
Local $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
$hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)

Global $aFaces = _FD_Detect($hImage, 4)
Global $hPen = _GDIPlus_PenCreate(0xAAFF0000, 2)
For $i = 1 To $aFaces[0][0]
    _GDIPlus_GraphicsDrawRect($hGraphics, $aFaces[$i][0], $aFaces[$i][1], $aFaces[$i][2], $aFaces[$i][3], $hPen)
Next

_GDIPlus_GraphicsDrawImageRect($hGfx, $hImage, 0, 0, $Width, $Height)

Sleep(10) ; <---- needed or your webcam will run glowing hot.

_GDIPlus_BitmapDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_PenDispose($hPen)

WEnd

;--------------------------------------------------------------------------
Func _Exit()
   _GDIPlus_PenDispose($hPen)
   _GDIPlus_GraphicsDispose($hGfx)
   _GDIPlus_ImageDispose($hImage)
   _GDIPlus_Shutdown()
   DllCall($_escapi_Dll,"none:cdecl","deinitCapture", "int", 0)
   GUIDelete($hGui)
   Exit
EndFunc

;-----------------------------------------------------------------

Alles anzeigen

**eukalyptus**

That´s cool!

I quick added a control window, to test the parameters

C

#include "FaceDetection.au3"
#include <GUIConstantsEx.au3>
;#include <Array.au3>

;HotKeySet("{ESC}", "_Exit")
Opt("GUIOnEventMode", 1)


Global $Width = 640, $Height = 480, $hGraphics
;--------------------------------------------------------------------------
; variables required for dshow escapi
Local $tagSimpleCapParams = "ptr mTargetBuf;" & "int mWidth;" & "int mHeight;"
Local $tSimpleCapParams = DllStructCreate($tagSimpleCapParams)
Local $tTargetBuf = DllStructCreate("BYTE[" & $Width*$Height*4 & "]")
Global $pTargetBuf = DllStructGetPtr($tTargetBuf)
DllStructSetData($tSimpleCapParams, 1, $pTargetBuf)
DllStructSetData($tSimpleCapParams, 2, $Width)
DllStructSetData($tSimpleCapParams, 3, $Height)
Local $pSimpleCapParams = DllStructGetPtr($tSimpleCapParams)
Local $device = 0 ;change this number to select dshow device

;---------------------------------------------------------------------------
;Escapi init
Global $hGui = GUICreate("WebCam FaceDetection", $Width, $Height)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW,$hGui)

Global $hGui_Ctrl = GUICreate("Ctrl", 320, 240, 10, 10, -1, -1, $hGui)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

Global $iMode = 1, $fScale = 1.2, $iNeighbor = 1, $iMinObjW = 20, $iMaxObjW = 0, $bDoLM = True

Global $cRB_Mode = GUICtrlCreateRadio("Mode 1", 10, 10, 60, 20)
GUICtrlSetOnEvent(-1, "_SetMode")
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateRadio("Mode 2", 80, 10, 60, 20)
GUICtrlSetOnEvent(-1, "_SetMode")
GUICtrlCreateRadio("Mode 3", 150, 10, 60, 20)
GUICtrlSetOnEvent(-1, "_SetMode")
GUICtrlCreateRadio("Mode 4", 230, 10, 60, 20)
GUICtrlSetOnEvent(-1, "_SetMode")

GUICtrlCreateLabel("Scale", 5, 40, 60, 20)
GUICtrlCreateSlider(70, 40, 180, 20)
GUICtrlSetLimit(-1, 50, 11)
GUICtrlSetData(-1, 12)
GUICtrlSetOnEvent(-1, "_SetScale")
Global $cIP_Scale = GUICtrlCreateInput("1.2", 260, 40, 50, 20, 0x0800)

GUICtrlCreateLabel("Min Neighb", 5, 70, 60, 20)
GUICtrlCreateSlider(70, 70, 180, 20)
GUICtrlSetOnEvent(-1, "_SetNeighbor")
GUICtrlSetLimit(-1, 20)
GUICtrlSetData(-1, 1)
Global $cIP_MinN = GUICtrlCreateInput("1", 260, 70, 50, 20, 0x0800)

GUICtrlCreateLabel("Min ObjW", 5, 100, 60, 20)
GUICtrlCreateSlider(70, 100, 180, 20)
GUICtrlSetOnEvent(-1, "_SetMinObjW")
GUICtrlSetLimit(-1, 400)
GUICtrlSetData(-1, 20)
Global $cIP_MinW = GUICtrlCreateInput("20", 260, 100, 50, 20, 0x0800)

GUICtrlCreateLabel("Max ObjW", 5, 130, 60, 20)
GUICtrlCreateSlider(70, 130, 180, 20)
GUICtrlSetOnEvent(-1, "_SetMaxObjW")
GUICtrlSetLimit(-1, 400)
Global $cIP_MaxW = GUICtrlCreateInput("0", 260, 130, 50, 20, 0x0800)

GUICtrlCreateCheckbox("Do LandMarks", 10, 160, 100, 20)
GUICtrlSetOnEvent(-1, "_SetLandMark")
GUICtrlSetState(-1, $GUI_CHECKED)
GUISetState()

local $_escapi_Dll = DllOpen("escapi.dll")
$return = DllCall($_escapi_Dll,"int","initCOM")
$return = DllCall($_escapi_Dll,"int","countCaptureDevices")
;Consolewrite("Number of devices = " & $return[0] & @CRLF)
$return = DllCall($_escapi_Dll,"int:cdecl","initCapture", "int", $device, "ptr", $pSimpleCapParams)
;---------------------------------------------------------------------------
_GDIPlus_Startup()





While 1
$hGfx = _GDIPlus_GraphicsCreateFromHWND($hGui)
;Get frame
DllCall($_escapi_Dll,"none:cdecl","doCapture", "int", $device)
Do
$return = DllCall($_escapi_Dll,"int:cdecl","isCaptureDone", "int", $device)
Until $return[0] = 1

$hBitmap = _WinAPI_CreateBitmap($Width, $Height , 1 , 32 , $pTargetBuf)
Local $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
$hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)

Global $hPen = _GDIPlus_PenCreate(0xAAFF0000, 2)
Global $hPen2 = _GDIPlus_PenCreate(0xAA00FF00, 1)

Global $aFaces = _FD_Detect($hImage, $iMode, $fScale, $iNeighbor, $iMinObjW, $iMaxObjW, $bDoLM)
For $i = 1 To $aFaces[0][0]
    _GDIPlus_GraphicsDrawRect($hGraphics, $aFaces[$i][0], $aFaces[$i][1], $aFaces[$i][2], $aFaces[$i][3], $hPen)
    If $bDoLM And UBound($aFaces, 2) > 6 Then
        For $j = 0 To 67
            _GDIPlus_GraphicsDrawEllipse($hGraphics, $aFaces[$i][6 + $j * 2], $aFaces[$i][7 + $j * 2], 4, 4, $hPen2)
        Next
    EndIf
Next

_GDIPlus_GraphicsDrawImageRect($hGfx, $hImage, 0, 0, $Width, $Height)

Sleep(10) ; <---- needed or your webcam will run glowing hot.

_GDIPlus_BitmapDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_PenDispose($hPen)
_GDIPlus_PenDispose($hPen2)
WEnd




Func _SetMode()
    $iMode = @GUI_CtrlId - $cRB_Mode + 1
EndFunc

Func _SetScale()
    $fScale = GUICtrlRead(@GUI_CtrlId) / 10
    GUICtrlSetData($cIP_Scale, $fScale)
EndFunc

Func _SetNeighbor()
    $iNeighbor = GUICtrlRead(@GUI_CtrlId)
    GUICtrlSetData($cIP_MinN, $iNeighbor)
EndFunc

Func _SetMinObjW()
    $iMinObjW = GUICtrlRead(@GUI_CtrlId)
    GUICtrlSetData($cIP_MinW, $iMinObjW)
EndFunc

Func _SetMaxObjW()
    $iMaxObjW = GUICtrlRead(@GUI_CtrlId)
    GUICtrlSetData($cIP_MaxW, $iMaxObjW)
EndFunc

Func _SetLandMark()
    $bDoLM = (GUICtrlRead(@GUI_CtrlId) = 1)
EndFunc



;--------------------------------------------------------------------------
Func _Exit()
   _GDIPlus_PenDispose($hPen)
   _GDIPlus_GraphicsDispose($hGfx)
   _GDIPlus_ImageDispose($hImage)
   _GDIPlus_Shutdown()
   DllCall($_escapi_Dll,"none:cdecl","deinitCapture", "int", 0)
   GUIDelete($hGui)
   Exit
EndFunc

;-----------------------------------------------------------------

Alles anzeigen

Werty

Very nice.

I have a wierd behaviour here, if i try and add the confidence/angle stuff, only the confidence seem to work, angle is stuck at zero.

Do you know what's going on ?

It's this part of the code, where i added the drawstring line.

Code

For $i = 1 To $aFaces[0][0]
    _GDIPlus_GraphicsDrawRect($hGraphics, $aFaces[$i][0], $aFaces[$i][1], $aFaces[$i][2], $aFaces[$i][3], $hPen)
    _GDIPlus_GraphicsDrawString($hGraphics, "confidence: " & $aFaces[$i][4] & @CRLF & "angle: " & $aFaces[$i][5], $aFaces[$i][0] + 4, $aFaces[$i][1] + 4, "Arial", 16)
    If $bDoLM And UBound($aFaces, 2) > 6 Then
        For $j = 0 To 67
            _GDIPlus_GraphicsDrawEllipse($hGraphics, $aFaces[$i][6 + $j * 2], $aFaces[$i][7 + $j * 2], 4, 4, $hPen2)

        Next
    EndIf
Next

/edit, just just tried adding it to my script above, without all the green circles, and there it works, but it doesnt work in your script, confusing.

/Edit2, Disregard, i found the reason, it only shows angle in mode 3 and 4, not 1 and 2. sorry for the inconvenience.

**eukalyptus**

Ich hab ein BUG gefunden: siehe 1 Post!

**UEZ**

Bitnugger Wunderschönes Gesicht

**Bitnugger**

Ich habe das Example auf die Schnelle mal ein wenig umgebaut, dass es nach dem Anzeigen des Bildes nicht sofort beendet wird, sondern fragt, ob noch ein weiteres detektiert werden soll. Komischerweise schmiert Autoit (3.3.15.1) dann aber bei fast jedem zweiten Durchlauf ab... bei manchen Bilder sogar beim ersten!

!>18:58:42 AutoIt3.exe ended.rc:-1073741819

Hat jemand eine Idee, woran das liegen könnte?

C

;-- TIME_STAMP   2019-06-25 18:58:17   v 0.1

#AutoIt3Wrapper_UseX64=n

#include "FaceDetection.au3"
#include <Array.au3>

Global $g_iMsgBoxAnswer

_GDIPlus_Startup()

While 1
    _FD_Demo()
    Select
        Case $g_iMsgBoxAnswer = 1 ;OK
            ContinueLoop
        Case $g_iMsgBoxAnswer = 2 ;Cancel
            _GDIPlus_Shutdown()
            Exit
    EndSelect
WEnd

Func _FD_Demo()
    Local $sFile = FileOpenDialog("open image", "", "(*.jpg;*.bmp;*.png;*.tif;*.gif)")
    ;$sFile = "Test.png"
    If @error Or Not FileExists($sFile) Then Return 2

    Local $hImg = _GDIPlus_ImageLoadFromFile($sFile)
    Local $iImg_W = _GDIPlus_ImageGetWidth($hImg)
    Local $iImg_H = _GDIPlus_ImageGetHeight($hImg)

    Local $hGui = GUICreate("FaceDetection", $iImg_W, $iImg_H)
    GUISetState()

    Local $hGfx = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsDrawImageRect($hGfx, $hImg, 0, 0, $iImg_W, $iImg_H)


    Local $aFaces = _FD_Detect($hImg, 4)
    ConsoleWrite("> " & $aFaces[0][0] & " Faces found!" & @CRLF)
    ;_ArrayDisplay($aFaces)

    ;Local $hBmpGray = _GDIPlus_BitmapCreateFromScan0($iImg_W, $iImg_H, $GDIP_PXF08INDEXED, $iImg_W, $_tFD_BmpG)
    ;_GDIPlus_GraphicsDrawImageRect($hGfx, $hBmpGray, 0, 0, $iImg_W, $iImg_H)

    Local $hPen = _GDIPlus_PenCreate(0xAAFF0000, 2)
    For $i = 1 To $aFaces[0][0]
        _GDIPlus_GraphicsDrawRect($hGfx, $aFaces[$i][0], $aFaces[$i][1], $aFaces[$i][2], $aFaces[$i][3], $hPen)
        _GDIPlus_GraphicsDrawString($hGfx, "confidence: " & $aFaces[$i][4] & @CRLF & "angle: " & $aFaces[$i][5], $aFaces[$i][0] + 4, $aFaces[$i][1] + 4, "Arial", 16)
    Next

    _GDIPlus_PenSetColor($hPen, 0xAA00FF00)
    For $i = 1 To $aFaces[0][0]
        For $j = 0 To 67
            _GDIPlus_GraphicsDrawEllipse($hGfx, $aFaces[$i][6 + $j * 2], $aFaces[$i][7 + $j * 2], 4, 4, $hPen)
        Next
    Next

    $g_iMsgBoxAnswer = MsgBox(262209,"example", $aFaces[0][0] & " Faces found!" & @CRLF & @CRLF & "Nächstes Bild?")
    _GDIPlus_ImageDispose($hImg)
    _GDIPlus_GraphicsDispose($hGfx)
    _GDIPlus_PenDispose($hPen)
    GUIDelete()
EndFunc

Alles anzeigen

**Andy**

Hi,

das hängt an der Abfrage der Struct in der Funktion _FD_Detect()

Füge

$_tFD_Bmp=0

$_tFD_BmpG=0

vor dem Return $aFaces ein.

**Bitnugger**

Zitat von Andy

das hängt an der Abfrage der Struct in der Funktion _FD_Detect()

Sehr schön - so funktioniert es!