WM_SETTINGCHANGE

**Moombas**

Moin zusammen,

ich habe mal wieder ein kleines Problem.

Es werden Registryänderungen gemacht, die normalerweise erst nach einem Neustart/Ab&Anmelden greifen.

WM_SETTINGCHANGE soll dies aber sofort wirksam machen. Ich habe damit jedoch noch nie gearbeitet.

Könnt ihr mir sagen, wie ich WM_SETTINGCHANGE per autoit sende?

Ich habe nach vielen Suchen aktuell zwei Varianten gefunden:

AutoIt

$hWnd = WinGetHandle("[ACTIVE]")
_SendMessage ($hWnd, $WM_SETTINGCHANGE)

AutoIt

dllCall("user32.dll", "int", "SendMessage", "long", $WM_SETTINGCHANGE)

Kann mir jemand sagen, ob eine davon tut was sie soll?

**Bitnugger**

Zitat von Moombas

Könnt ihr mir sagen, wie ich WM_SETTINGCHANGE per autoit sende?

Guckst du hier: https://docs.microsoft.com/en-us/windows/…m-settingchange

und hier: https://docs.microsoft.com/en-us/windows/…messagetimeouta

und hier: https://www.autoitscript.com/autoit3/docs/l…sageTimeout.htm

**Moombas**

Wenn ich es also richtig sehe, was deine Links besagen (die ich nicht alle wirklich weiß, wie ich sie umsetzen soll) wäre ich bei folgender Lösung:

Code

$hWnd = WinGetHandle("[ACTIVE]")
_WinAPI_SendMessageTimeout($hWnd, $WM_SETTINGCHANGE)

Correct?

**Bitnugger**

Zitat von Moombas

Correct?

Kann ich dir nicht sagen, denn ich habe die Funktion auch noch nie benutzt. Anstelle von $hWnd würde ich jedoch $HWND_BROADCAST (0xFFFF) verwenden, damit alle Top-Level-Windows diese Nachricht erhalten.

**Bitnugger**

Welche Registryänderungen wurden denn gemacht? Evtl. kann ich dann ja mal testen...

**Moombas**

Einträge, damit ein jpg bzw. jpeg File mit einem anderen Programm geöffnet wird (als Middleware), um ein Problem in Windows 7 zu umgehen.

Code

    $Wert = '"C:\Fotoviewer.exe" "%1"'
    $REGKEY = "HKEY_CLASSES_ROOT\Applications\Fotoviewer.exe\shell\open\command"
    Regwrite($REGKEY, ""  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "") = $Wert Then
        $cache += 1
    EndIf

    $Wert = 'Fotoviewer.exe'
    $REGKEY = "HKEY_CLASSES_ROOT\Local Settings\Software\Microsoft\Windows\Shell\MuiCache"
    Regwrite($REGKEY, "C:\Fotoviewer.exe"  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "C:\Fotoviewer.exe") = $Wert Then
        $cache += 2
    EndIf

    $Wert = '"C:\Fotoviewer.exe" "%1"'
    $REGKEY = "HKEY_USERS\" & $SID & "\Software\Classes\Applications\Fotoviewer.exe\shell\open\command"
    Regwrite($REGKEY, ""  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "") = $Wert Then
        $cache += 4
    EndIf

    $Wert = 'Fotoviewer.exe'
    $REGKEY = "HKEY_USERS\" & $SID & "\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\MuiCache";
    Regwrite($REGKEY, "C:\Fotoviewer.exe"  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "C:\Fotoviewer.exe") = $Wert Then
        $cache += 8
    EndIf

    $Wert = 'Fotoviewer.exe'
    $REGKEY = "HKEY_USERS\" & $SID & "\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.jpg\OpenWithList";
    Regwrite($REGKEY, "b"  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "b") = $Wert Then
        $cache += 16
    EndIf

    $Wert = 'Applications\Fotoviewer.exe'
    $REGKEY = "HKEY_USERS\" & $SID & "\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.jpg\UserChoice"
    Regwrite($REGKEY, "Progid"  , "REG_SZ", $Wert)
    if RegRead($REGKEY, "Progid") = $Wert Then
        $cache += 32
    EndIf

Alles anzeigen

Habe alle 3 Varianten nun getestet, ohne Erfolg.

Brauche weiterhin einen Neustart/Neuanmeldung.

Edit: Evtl. liegt hier noch ein anderes Problem vor. Ich muss noch mal schauen. Jetzt will er das trotz Registryänderungen nicht mehr nehmen -.-

**Bitnugger**

Welche Problem in Windows 7?

Als temporäre Notlösung könntest du die explorer.exe neu starten... ich schau morgen mal, ob ich dafür eine Lösung finde... wenn ja, melde ich mich wieder.

ProcessClose('explorer.exe')

Run('explorer.exe')

**Moombas**

Da dies Systeme betrifft, die im laufenden Betrieb umgestellt werden, werde ich da eher den Neustart als "Lösung" wählen, als den Explorer neu zu starten, da dies sichtbar für den Anwender wäre.

Jedoch aktuell macht mir die Registry noch ein wenig Sorgen/Probleme. Ich muss mal weiter testen.

**Moombas**

So, vorerst das Registry Problem wieder gelöst.

Bitnugger : Habe die Registryeinträge, die ich brauche oben nochmal angepasst. Sind ein paar weniger geworden

**Bitnugger**

Zitat von Moombas

Habe die Registryeinträge, die ich brauche oben nochmal angepasst. Sind ein paar weniger geworden

Ja, weniger, aber für Helfende nicht mehr nutzbar... du solltest die Variablen vorab deklarieren bzw. kommentieren - wichtig, damit es funktioniert, wäre hier vor allem $cache und $SID.

Zu dem Thema habe ich nicht wirklich brauchbare Ergebnisse finden können und somit schwindet auch mein Interesse, mich weiter damit auseinanderzusetzen.

Hier ein Link, der zumindest in den ersten Sekunden vielversprechend aussah: https://www.angryadmin.co.uk/?tag=wm_settingchange

Wie kommt der auf den Wert 5000?

Meinem jetzigen Verständnis nach, sollte der Funktionsaufruf etwa so aussehen:

AutoIt

#include <APISysConstants.au3>  ; $HWND_BROADCAST, $SMTO_ABORTIFHUNG
#include <WindowsConstants.au3> ; $WM_SETTINGCHANGE
#include <WinAPISysWin.au3>     ; _WinAPI_SendMessageTimeout

;~ Syntax: _WinAPI_SendMessageTimeout ( $hWnd, $iMsg [, $wParam = 0 [, $lParam = 0 [, $iTimeout = 1000 [, $iFlags = 0]]]] )

Local $hWnd = $HWND_BROADCAST, $iMsg = $WM_SETTINGCHANGE, $wParam = 0, $lParam = 'Environment', $iTimeout = 1000, $iFlags = $SMTO_ABORTIFHUNG
_WinAPI_SendMessageTimeout($hWnd, $iMsg, $wParam, $lParam, $iTimeout, $iFlags)

**Moombas**

Danke schon mal für die Hilfe Bitnugger.

Das funktioniert und ich wäre da selber nicht drauf gekommen.

$cache ist nur eine interne Prüfung ob alles einwandfrei durchgelaufen ist. (Ich erwarte am Ende einen bestimmten Wert der passen muss)

Sorry mir ging es hierbei nur darum dir die Registryeinträge zu zeigen.

Ich hätte natürlich überall das komplette Konstrukt weg kürzen können.

**Bitnugger**

Zitat von Moombas

Das funktioniert und ich wäre da selber nicht drauf gekommen.

Dann habe ich ja mal sehr gut geraten... wenn es funktioniert, wieso setzt du den Thread dann nicht auf gelöst?

Hier noch ein Schnipsel für dich:

AutoIt: _WinAPI_SendMessageTimeout_Example.au3

;-- TIME_STAMP   2020-12-15 18:04:16   v 0.1

#include <APISysConstants.au3>  ; $HWND_BROADCAST, $SMTO_ABORTIFHUNG
#include <WindowsConstants.au3> ; $WM_SETTINGCHANGE
#include <WinAPISysWin.au3>     ; _WinAPI_SendMessageTimeout

_SETTINGCHANGE()

Func _SETTINGCHANGE()
    Local $vCheck = '', $sSID = _GetSID(@UserName)
    If $sSID = '' Then Exit ConsoleWrite('! Fehler bei _GetSID, $sSID = ' & $sSID & @CRLF)

    __SetvCheck($vCheck, __RegWrite("HKEY_CLASSES_ROOT\Applications\Fotoviewer.exe\shell\open\command", "", "REG_SZ", '"C:\Fotoviewer.exe" "%1"'))
    __SetvCheck($vCheck, __RegWrite("HKEY_CLASSES_ROOT\Local Settings\Software\Microsoft\Windows\Shell\MuiCache", "C:\Fotoviewer.exe", "REG_SZ", 'Fotoviewer.exe'))
    __SetvCheck($vCheck, __RegWrite("HKEY_USERS\" & $sSID & "\Software\Classes\Applications\Fotoviewer.exe\shell\open\command", "", "REG_SZ", '"C:\Fotoviewer.exe" "%1"'))
    __SetvCheck($vCheck, __RegWrite("HKEY_USERS\" & $sSID & "\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\MuiCache", "C:\Fotoviewer.exe", "REG_SZ", 'Fotoviewer.exe'))
    __SetvCheck($vCheck, __RegWrite("HKEY_USERS\" & $sSID & "\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.jpg\OpenWithList", "b", "REG_SZ", 'Fotoviewer.exe'))
    __SetvCheck($vCheck, __RegWrite("HKEY_USERS\" & $sSID & "\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.jpg\UserChoice", "Progid", "REG_SZ", 'Applications\Fotoviewer.exe'))

    If $vCheck = '111111' Then
        ; Syntax: _WinAPI_SendMessageTimeout ( $hWnd, $iMsg [, $wParam = 0 [, $lParam = 0 [, $iTimeout = 1000 [, $iFlags = 0]]]] )

        ; Hier ein Link, der zumindest in den ersten Sekunden vielversprechend aussah: https://www.angryadmin.co.uk/?tag=wm_settingchange
        ; Wie kommt der auf den Wert 5000?

        ; Ausgehend von dem, was er da schreibt, bin ich zu folgender Lösung gekommen:
        ; [win32.nativemethods]::SendMessageTimeout($HWND_BROADCAST, $WM_SETTINGCHANGE,[uintptr]::Zero, "Environment", 2                , 5000             , [ref]$result);
        ; _WinAPI_SendMessageTimeout (              $hWnd          , $iMsg            , $wParam = 0   , $lParam = 0  , $iTimeout = 1000 , $iFlags = 0]]]] )

        Local $hWnd = $HWND_BROADCAST, $iMsg = $WM_SETTINGCHANGE, $wParam = 0, $lParam = 'Environment', $iTimeout = 1000, $iFlags = $SMTO_ABORTIFHUNG
        _WinAPI_SendMessageTimeout($hWnd, $iMsg, $wParam, $lParam, $iTimeout, $iFlags)
    Else
        ConsoleWrite('! Fehler bei __RegWrite, $vCheck = ' & $vCheck & @CRLF)
    EndIf
EndFunc

Func _GetSID($sUser)
    Local $iPID = Run('wmic useraccount where name="'&$sUser&'" get sid', '', @SW_HIDE, $STDOUT_CHILD)
    ProcessWaitClose($iPID)
    Local $aOutput = StringSplit(StringStripWS(StdoutRead($iPID), 2), @CRLF, 3)
    Return UBound($aOutput) > 1 ? $aOutput[1] : ''
EndFunc

Func __SetvCheck(ByRef $vCheck, $sRegWrite)
    $vCheck = ($sRegWrite ? '1' : '0') & $vCheck
EndFunc

Func __RegWrite($sKeyName, $sValueName, $sType, $vValue)
    RegWrite($sKeyName, $sValueName, $sType, $vValue)
    Return RegRead($sKeyName, $sValueName) = $vValue
EndFunc

Alles anzeigen

**Moombas**

Danke dafür, jedoch wird im Script mehr als nur Registry geschrieben Und die Lösung mit dem $cache kann ich flexibel anwenden.

Und das mit dem "Erledigt" ist unter gegangen, hole ich jetzt nach^^