GDIPlus code als Funktion - Bitte um Hilfe.

Michi91 · 29. Juli 2022

Guten Morgen allerseits.
Ich habe mir vor einiger Zeit ein Skript zusammen gebastelt, dass die aktuelle Uhrzeit und das Datum

zusammen mit einem benutzerdefinierten Bild als Wallpaper verwendet.

Zusammengebastelt deshalb, weil der GDIPlus Teil mehr hingeklotzt ist, als sonst was, da mir GDIPlus seit je her ein Rätsel ist,

dass mir einfach nicht in die Birne gehn will, egal wie lange ich mich damit auseinander setz.

Nun, das Skript funktioniert soweit super und tut genau das was es soll, sieht halt an manschen Stellen nur aus wie Hund...
Da ich das Skript im Umfang noch erweitern will und es mit einigen anderen Skripten zusammen schließen will,
würde ich den GDIPlus Teil gerne etwas verbessern.

Hier aber erstmal der Code:

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ScreenCapture.au3>
#include <GDIPlus.au3>

HotKeySet("^!o", "_openOptions")
HotKeySet("^!l", "_load")


Global $sOptionsFile = @AppDataDir & "\Clock_Wallpaper_Options.ini"
Global $sCaptureFilePath = @TempDir & "\TempClockFile.bmp"
Global $sTimeCheck

_load()

If NOT FileExists($sOptionsFile) Then
    MsgBox(16, "ERROR - Clock Wallpaper v2", "Options file not found!" & @CRLF & $sOptionsFile)
EndIf

_Update()
AdlibRegister("_Update", 1000)

While 1
    Sleep(100)
WEnd

Func _openOptions()
    Run("notepad.exe " & $sOptionsFile)
EndFunc

Func _load()
    Global $sBGFilePath =     IniRead($sOptionsFile, "options", "image", 0)
    Global $sFont =         IniRead($sOptionsFile, "options", "font", 0)
    Global $sSizeTime =     IniRead($sOptionsFile, "options", "size_time", 0)
    Global $sSizeDate =     IniRead($sOptionsFile, "options", "size_date", 0)
    Global $sPosTime =         IniRead($sOptionsFile, "options", "pos_time", 0)
    Global $sPosDate =         IniRead($sOptionsFile, "options", "pos_date", 0)

    If @HotKeyPressed = "^!l" Then
        _SetWalpaper()
    EndIf
EndFunc

Func _Update()
    Local $Checksum = @HOUR & @MIN
    If $sTimeCheck < $Checksum Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    ElseIf $sTimeCheck = 2359 And $Checksum = 0000 Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    EndIf
EndFunc   ;==>_Update

Func _SetWalpaper()
    _GDIPlus_StartUp ()

    $aHour = StringSplit(@HOUR, "")
    $aMin = StringSplit(@MIN, "")
    $aDay = StringSplit("SO.|MO.|DI.|MI.|DO.|FR.|SA.", "|")

    $sTime = $aHour[1] & " " & $aHour[2] & " : " & $aMin[1] & " " & $aMin[2]
    $sDate = $aDay[@WDAY] & " " & @MDAY & "." & @MON & "." & @YEAR

    $hImage   = _GDIPlus_ImageLoadFromFile ($sBGFilePath)
    $hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage)
    $hFamily  = _GDIPlus_FontFamilyCreate ($sFont)

    ; Set Time
    $hFont1    = _GDIPlus_FontCreate ($hFamily, $sSizeTime, 0)
    $hFormat1  = _GDIPlus_StringFormatCreate (0x4000)
                _GDIPlus_StringFormatSetAlign ($hFormat1, 1)
    $hBrush1  = _GDIPlus_BrushCreateSolid (0xff000000)
    $hPen1     = _GDIPlus_PenCreate (0xC4000000, 1)
    $tLayout1  = _GDIPlus_RectFCreate (200, $sPosTime)
    $aInfo1    = _GDIPlus_GraphicsMeasureString ($hGraphic, $sTime, $hFont1, $tLayout1, $hFormat1)
                _GDIPlus_GraphicsDrawStringEx ($hGraphic, $sTime, $hFont1, $aInfo1[0], $hFormat1, $hBrush1)

    ; Set Date
    $hFont2    = _GDIPlus_FontCreate ($hFamily, $sSizeDate, 0)
    $hFormat2  = _GDIPlus_StringFormatCreate (0x4000)
                _GDIPlus_StringFormatSetAlign ($hFormat2, 1)
    $hBrush2  = _GDIPlus_BrushCreateSolid (0xff000000)
    $hPen2     = _GDIPlus_PenCreate (0xC4000000, 1)
    $tLayout2  = _GDIPlus_RectFCreate (200, $sPosDate)
    $aInfo2    = _GDIPlus_GraphicsMeasureString ($hGraphic, $sDate, $hFont2, $tLayout2, $hFormat2)
                _GDIPlus_GraphicsDrawStringEx ($hGraphic, $sDate, $hFont2, $aInfo2[0], $hFormat2, $hBrush2)

    _GDIPlus_ImageSaveToFile ($hImage, $sCaptureFilePath)

    _GDIPlus_PenDispose ($hPen1)
    _GDIPlus_PenDispose ($hPen2)
    _GDIPlus_BrushDispose ($hBrush1)
    _GDIPlus_BrushDispose ($hBrush2)
    _GDIPlus_StringFormatDispose ($hFormat1)
    _GDIPlus_StringFormatDispose ($hFormat2)
    _GDIPlus_FontDispose ($hFont1)
    _GDIPlus_FontDispose ($hFont2)
    _GDIPlus_FontFamilyDispose ($hFamily)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ImageDispose ($hImage)
    _GDIPlus_ShutDown ()

    _ChangeDesktopWallpaper($sCaptureFilePath, 0)
    FileDelete($sCaptureFilePath)
EndFunc   ;==>_SetWalpaper

Func _ChangeDesktopWallpaper($bmp, $style = 0)
    If Not FileExists($bmp) Then Return -1
    ;The $SPI*  values could be defined elsewhere via #include - if you conflict,
    ; remove these, or add if Not IsDeclared "SPI_SETDESKWALLPAPER" Logic
    Local $SPI_SETDESKWALLPAPER = 20
    Local $SPIF_UPDATEINIFILE = 1
    Local $SPIF_SENDCHANGE = 2
    Local $REG_DESKTOP = "HKEY_CURRENT_USER\Control Panel\Desktop"
    If $style = 1 Then
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 1)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", 0)
    Else
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 0)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", $style)
    EndIf


    DllCall("user32.dll", "int", "SystemParametersInfo", _
            "int", $SPI_SETDESKWALLPAPER, _
            "int", 0, _
            "str", $bmp, _
            "int", BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))
    Return 0
EndFunc   ;==>_ChangeDestopWallpaper

Alles anzeigen

Es geht mir hier um die Funktion _SetWallpaper.
Aktuell wird ja erst die Zeit, dann das Datum auf das Bild gesetzt.
Und genau das hätte ich gerne in einer gesonderten Funktion.
Der Code für Zeit und Datum sind ja sehr gleich und wenn jetzt noch ein dritter oder vierter
Text dazu kommen soll, müsste ich, so wie es aktuell ist diesen Code noch weitere male verwenden.
Genau dafür ist ja ne Funktion da, um eben unnötige Wiederholungen im Code zu vermeiden.

Leider schaffe ich es aber nicht, das ganze in eine Funktion zu pressen.
Deshalb wäre ich Euch sehr dankbar, wenn Ihr mir da etwas bei helfen könntet.

Anstatt den Code für jeden Text zu wiederholen, möchte ich einfach eine Funktion aufrufen in dem ich alle Parameter wie Text, Font, Größe, Position u.s.w. übergebe.

Hoffe Ihr könnt mir da etwas helfen.

Liebe Grüße
Micha

Moombas · 29. Juli 2022

ungetestet:

AutoIt

;~ Global $sSizeTime =     IniRead($sOptionsFile, "options", "size_time", 0)        ;Idealerweise berechnen, sonst brauchst du für jeden Text einen Ini-Eintrag!
;~ Global $sSizeDate =     IniRead($sOptionsFile, "options", "size_date", 0)        ;Idealerweise berechnen, sonst brauchst du für jeden Text einen Ini-Eintrag!
;~ Global $sPosTime =         IniRead($sOptionsFile, "options", "pos_time", 0)        ;Idealerweise berechnen oder fest übergeben, sonst brauchst du für jeden Text einen Ini-Eintrag!
;~ Global $sPosDate =         IniRead($sOptionsFile, "options", "pos_date", 0)        ;Idealerweise berechnen oder fest übergeben, sonst brauchst du für jeden Text einen Ini-Eintrag!

Func GDIPlus_Add_TextToImage(Const $sText, $sPos, $sSize) ;$sSize kann weg, wenn es "berechnet" wird
Local Const $hFamily  = _GDIPlus_FontFamilyCreate($sFont)

;~ Local Const    $sSize      =  ;Du musst Size errechnen oder sie der Funktion übergeben, Siehe dazu: https://www.autoitscript.com/forum/topic/182271-solved_gdiplus-how-calculate-font-size-to-fill-a-_gdiplus_rectfcreate/
Local Const    $hFont    = _GDIPlus_FontCreate($hFamily, $sSize, 0)
Local Const    $hFormat  = _GDIPlus_StringFormatCreate(0x4000)
                           _GDIPlus_StringFormatSetAlign($hFormat, 1)
Local Const    $hBrush   = _GDIPlus_BrushCreateSolid(0xff000000)
Local Const    $hPen     = _GDIPlus_PenCreate(0xC4000000, 1)
Local Const    $tLayout  = _GDIPlus_RectFCreate(200, $sPos)
Local Const    $aInfo    = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
                           _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText, $hFont, $aInfo[0], $hFormat, $hBrush)

    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_GraphicsDispose($hGraphic)
EndFunc

Alles anzeigen

Tipp:

AutoIt

Func _openOptions()
;    Run("notepad.exe " & $sOptionsFile);notepad.exe ist unnötig, wenn es das Standardprogramm zum öffnen für ini Dateien ist, dann reicht auch:
    Shellexecute($sOptionsFile)
EndFunc

**BugFix** · 29. Juli 2022

Zitat von Moombas

AutoIt

Local Const    $hFont    = _GDIPlus_FontCreate ($hFamily, $sSize, 0) 
Local Const    $hFormat  = _GDIPlus_StringFormatCreate (0x4000)
Local Const    $hBrush   = _GDIPlus_BrushCreateSolid (0xff000000) 
Local Const    $hPen     = _GDIPlus_PenCreate (0xC4000000, 1)

Das würde ich so nicht empfehlen.

Wenn die Handle im lokalen Kontext der Funktion geführt werden sollten diese nach dem Zeichnen in der Funktion zwingend mit den entsprechenden ..Dispose-Befehlen gelöscht werden.

Um so die Variablen nicht ständig zu deklarieren und zu löschen würde ich diese Global definieren und und in der Funktion nur jeweils neu setzen. In einer Exit-Routine beim Skript Beenden können dann die ..Dispose-Befehle eingefügt werden.

Moombas · 29. Juli 2022

BugFix Habe nur aufzeigen wollen, was er dafür "separieren" muss und wie. Da sind so einige Sachen, sie ich in seinem Skript etwas anders machen würde bzgl. Lokal und Global bzw. Const. Aber da ich mir da bei einigen Post die Finger diesbezüglich wundschreiben würde wollte ich hier den Fokus auf das wesentliche legen. aber genrell gebe ich dir recht und habe es mal eingefügt.

Edit: Und ich selber versuche so wenig wie möglich Global zu setzen, alles was man nur Lokal braucht, gehört für mich nur in einen Lokalen Kontext. Was es zudem zumindest für $hFont schwierig macht, da der Inhalt dynamisch ist. Die anderen drei könnte man jedoch durchaus als globale Konstanten setzen, da immer gleich. Jedoch müsste GDIPlus dann direkt bei Programmstart mitgestartet und erst beim beenden geschlossen werden, was für mich auch ein Grund wäre bei der lokalen Variante zu bleiben.

Kanashius · 29. Juli 2022

Zitat von Moombas

Und ich selber versuche so wenig wie möglich Global zu setzen, alles was man nur Lokal braucht, gehört für mich nur in einen Lokalen Kontext.

Da würde ich definitiv wiedersprechen. Konstanten gehören niemals lokal. Außerdem sollte GDIPlus beim Programmstart gestartet und beim beenden geschlossen werden, wenn die Funktionen öfter benutzt werden. Es erzeugt performance mäßig einfach viel zu viel overhead, ständig zu laden und wieder freizugeben.

Ich würde immer die Performance als erstes sehen, weil das vom Nutzer am ehesten bemerkt wird. Dann den Speicherverbrauch. Ist heutzutage nicht mehr ein ganz so großes Problem, deshalb wirds nicht allzu schnell auffallen. Und später kommt irgendwann Stil, also wenn möglich lokal,... (Natürlich alles im Rahmen, wenn es nicht anders geht muss man kompromisse eingehen.) Wenn es zu viele Globale Variablen werden, sodass es unübersichtlich wird, muss man halt auf mehrere Scripte aufteilen.

Lokal gehören nur alle temporären Variablen, die nur während eines Funktionsdurchlaufes verwendet werden. Bei denen macht es keinen Sinn, sie Global anzulegen.

Hier wüde ich sagen hängt es davon ab, wie oft das Wallpaper geändert werden soll. Wenn es manuell hin und wieder gewechselt wird würde für mich der Speicher evtl. wichtiger sein, weils eh nur alle paar Tage aufgerufen wird => Performance ist weniger wichtig (sollte aber auch nicht wenige Sekunden überschreiten). => Lokal anlegen und wieder freigeben.

Wenn es automatisch alle X Sekunden/Minuten wechselt sollte für Performance optimiert werden. => Global anlegen

Wobei ich vmtl. hier einfach nur auf Performance gehen würde und eher Global allokieren würde, weil der Speicherverbrauch so gering ist, dass er nicht ins gewicht fällt. Bei GBs an RAM sind nen paar KB egal.

Michi91 · 30. Juli 2022

Puhh, ok, ich muss zugeben dass ich weniger als die Hälfte von dem verstehe über das Ihr da diskutiert.
Aber sei es drum, ich werde jetzt erstmal versuchen den Code von Moombas zu implementieren und gebe Euch dann nochmal Rückmeldung.

Vielen Dank auf jeden Fall schonmal für die Hilfe

Michi91 · 30. Juli 2022

So.
Hab versucht den Code zu implementieren und kleinere Fehler zu beheben.
Das Problem ist aber, jetzt wird nur der Text im fertigen Wallpaper angezeigt, der als letztes über die Funktion eingefügt wurde.

Hier der Code:

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ScreenCapture.au3>
#include <GDIPlus.au3>

HotKeySet("^!o", "_openOptions")
HotKeySet("^!l", "_load")


Global $sOptionsFile = @AppDataDir & "\Clock_Wallpaper_Options.ini"
Global $sCaptureFilePath = @TempDir & "\TempClockFile.bmp"
Global $sTimeCheck

_load()

If NOT FileExists($sOptionsFile) Then
    MsgBox(16, "ERROR - Clock Wallpaper v2", "Options file not found!" & @CRLF & $sOptionsFile)
EndIf

_Update()
AdlibRegister("_Update", 1000)

While 1
    Sleep(100)
WEnd

Func _openOptions()
    Run("notepad.exe " & $sOptionsFile)
EndFunc

Func _load()
    Global $sBGFilePath =     IniRead($sOptionsFile, "options", "image", 0)
    Global $sFont =         IniRead($sOptionsFile, "options", "font", 0)
    Global $sSizeTime =     IniRead($sOptionsFile, "options", "size_time", 0)
    Global $sSizeDate =     IniRead($sOptionsFile, "options", "size_date", 0)
    Global $sPosTime =         IniRead($sOptionsFile, "options", "pos_time", 0)
    Global $sPosDate =         IniRead($sOptionsFile, "options", "pos_date", 0)

    If @HotKeyPressed = "^!l" Then
        _SetWalpaper()
    EndIf
EndFunc

Func _Update()
    Local $Checksum = @HOUR & @MIN
    If $sTimeCheck < $Checksum Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    ElseIf $sTimeCheck = 2359 And $Checksum = 0000 Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    EndIf
EndFunc   ;==>_Update

Func _SetWalpaper()
    _GDIPlus_StartUp ()

    $aHour = StringSplit(@HOUR, "")
    $aMin = StringSplit(@MIN, "")
    $aDay = StringSplit("SO.|MO.|DI.|MI.|DO.|FR.|SA.", "|")

    $sTime = $aHour[1] & " " & $aHour[2] & " : " & $aMin[1] & " " & $aMin[2]
    $sDate = $aDay[@WDAY] & " " & @MDAY & "." & @MON & "." & @YEAR

    GDIPlus_Add_TextToImage($sTime, $sPosTime, $sSizeTime)
    GDIPlus_Add_TextToImage($sDate, $sPosDate, $sSizeDate)

    _ChangeDesktopWallpaper($sCaptureFilePath, 0)
    FileDelete($sCaptureFilePath)
EndFunc   ;==>_SetWalpaper




Func GDIPlus_Add_TextToImage(Const $sText, $sPos, $sSize) ;$sSize kann weg, wenn es "berechnet" wird
Local $hImage   = _GDIPlus_ImageLoadFromFile ($sBGFilePath)
Local $hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage)
Local Const $hFamily  = _GDIPlus_FontFamilyCreate($sFont)

;~ Local Const    $sSize      =  ;Du musst Size errechnen oder sie der Funktion übergeben, Siehe dazu: https://www.autoitscript.com/forum/topic/182271-solved_gdiplus-how-calculate-font-size-to-fill-a-_gdiplus_rectfcreate/
Local Const    $hFont    = _GDIPlus_FontCreate($hFamily, $sSize, 0)
Local Const    $hFormat  = _GDIPlus_StringFormatCreate(0x4000)
                           _GDIPlus_StringFormatSetAlign($hFormat, 1)
Local Const    $hBrush   = _GDIPlus_BrushCreateSolid(0xff000000)
Local Const    $hPen     = _GDIPlus_PenCreate(0xC4000000, 1)
Local Const    $tLayout  = _GDIPlus_RectFCreate(200, $sPos)
Local Const    $aInfo    = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
                           _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText, $hFont, $aInfo[0], $hFormat, $hBrush)

_GDIPlus_ImageSaveToFile ($hImage, $sCaptureFilePath)

    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_GraphicsDispose($hGraphic)
EndFunc




Func _ChangeDesktopWallpaper($bmp, $style = 0)
    If Not FileExists($bmp) Then Return -1
    ;The $SPI*  values could be defined elsewhere via #include - if you conflict,
    ; remove these, or add if Not IsDeclared "SPI_SETDESKWALLPAPER" Logic
    Local $SPI_SETDESKWALLPAPER = 20
    Local $SPIF_UPDATEINIFILE = 1
    Local $SPIF_SENDCHANGE = 2
    Local $REG_DESKTOP = "HKEY_CURRENT_USER\Control Panel\Desktop"
    If $style = 1 Then
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 1)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", 0)
    Else
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 0)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", $style)
    EndIf


    DllCall("user32.dll", "int", "SystemParametersInfo", _
            "int", $SPI_SETDESKWALLPAPER, _
            "int", 0, _
            "str", $bmp, _
            "int", BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))
    Return 0
EndFunc   ;==>_ChangeDestopWallpaper

Alles anzeigen

Weiß leider nich genau was da schief läuft.

EDIT:
Hab nochmal etwas dran gebastelt, jetzt funktioniert es wie gewünscht

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ScreenCapture.au3>
#include <GDIPlus.au3>

HotKeySet("^!o", "_openOptions")
HotKeySet("^!l", "_load")


Global $sOptionsFile = @AppDataDir & "\Clock_Wallpaper_Options.ini"
Global $sCaptureFilePath = @TempDir & "\TempClockFile.bmp"
Global $sTimeCheck

_load()

If NOT FileExists($sOptionsFile) Then
    MsgBox(16, "ERROR - Clock Wallpaper v2", "Options file not found!" & @CRLF & $sOptionsFile)
EndIf

_Update()
AdlibRegister("_Update", 1000)

While 1
    Sleep(100)
WEnd

Func _openOptions()
    Run("notepad.exe " & $sOptionsFile)
EndFunc

Func _load()
    Global $sBGFilePath =     IniRead($sOptionsFile, "options", "image", 0)
    Global $sFont =         IniRead($sOptionsFile, "options", "font", 0)
    Global $sSizeTime =     IniRead($sOptionsFile, "options", "size_time", 0)
    Global $sSizeDate =     IniRead($sOptionsFile, "options", "size_date", 0)
    Global $sPosTime =         IniRead($sOptionsFile, "options", "pos_time", 0)
    Global $sPosDate =         IniRead($sOptionsFile, "options", "pos_date", 0)

    If @HotKeyPressed = "^!l" Then
        _SetWalpaper()
    EndIf
EndFunc

Func _Update()
    Local $Checksum = @HOUR & @MIN
    If $sTimeCheck < $Checksum Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    ElseIf $sTimeCheck = 2359 And $Checksum = 0000 Then
        $sTimeCheck = $Checksum
        _SetWalpaper()
    EndIf
EndFunc   ;==>_Update

Func _SetWalpaper()
    _GDIPlus_StartUp ()
    $hImage   = _GDIPlus_ImageLoadFromFile ($sBGFilePath)

    $aHour = StringSplit(@HOUR, "")
    $aMin = StringSplit(@MIN, "")
    $aDay = StringSplit("SO.|MO.|DI.|MI.|DO.|FR.|SA.", "|")

    $sTime = $aHour[1] & " " & $aHour[2] & " : " & $aMin[1] & " " & $aMin[2]
    $sDate = $aDay[@WDAY] & " " & @MDAY & "." & @MON & "." & @YEAR

    GDIPlus_Add_TextToImage($hImage, $sTime, $sPosTime, $sSizeTime)
    GDIPlus_Add_TextToImage($hImage, $sDate, $sPosDate, $sSizeDate)

    _GDIPlus_ImageSaveToFile ($hImage, $sCaptureFilePath)

    _ChangeDesktopWallpaper($sCaptureFilePath, 0)
    FileDelete($sCaptureFilePath)
EndFunc   ;==>_SetWalpaper




Func GDIPlus_Add_TextToImage($hImage, $sText, $sPos, $sSize) ;$sSize kann weg, wenn es "berechnet" wird
Local $hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage)
Local $hFamily  = _GDIPlus_FontFamilyCreate($sFont)

;~ Local Const    $sSize      =  ;Du musst Size errechnen oder sie der Funktion übergeben, Siehe dazu: https://www.autoitscript.com/forum/topic/182271-solved_gdiplus-how-calculate-font-size-to-fill-a-_gdiplus_rectfcreate/
Local Const    $hFont    = _GDIPlus_FontCreate($hFamily, $sSize, 0)
Local Const    $hFormat  = _GDIPlus_StringFormatCreate(0x4000)
                           _GDIPlus_StringFormatSetAlign($hFormat, 1)
Local Const    $hBrush   = _GDIPlus_BrushCreateSolid(0xff000000)
Local Const    $hPen     = _GDIPlus_PenCreate(0xC4000000, 1)
Local Const    $tLayout  = _GDIPlus_RectFCreate(200, $sPos)
Local Const    $aInfo    = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
                           _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText, $hFont, $aInfo[0], $hFormat, $hBrush)

;~ _GDIPlus_ImageSaveToFile ($hImage, $sCaptureFilePath)

    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_GraphicsDispose($hGraphic)
EndFunc




Func _ChangeDesktopWallpaper($bmp, $style = 0)
    If Not FileExists($bmp) Then Return -1
    ;The $SPI*  values could be defined elsewhere via #include - if you conflict,
    ; remove these, or add if Not IsDeclared "SPI_SETDESKWALLPAPER" Logic
    Local $SPI_SETDESKWALLPAPER = 20
    Local $SPIF_UPDATEINIFILE = 1
    Local $SPIF_SENDCHANGE = 2
    Local $REG_DESKTOP = "HKEY_CURRENT_USER\Control Panel\Desktop"
    If $style = 1 Then
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 1)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", 0)
    Else
        RegWrite($REG_DESKTOP, "TileWallPaper", "REG_SZ", 0)
        RegWrite($REG_DESKTOP, "WallpaperStyle", "REG_SZ", $style)
    EndIf


    DllCall("user32.dll", "int", "SystemParametersInfo", _
            "int", $SPI_SETDESKWALLPAPER, _
            "int", 0, _
            "str", $bmp, _
            "int", BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))
    Return 0
EndFunc   ;==>_ChangeDestopWallpaper

Alles anzeigen

Kanashius · 1. August 2022

Hi, ich hatte mir deinen Code gestern angesehen und fand es unglücklich, dass du jede Minute ein neues Bild erstellst, es als Datei speicherst und dann als Hintergrund setzt.

Das ist eine echt gute Methode, wie du sehr schnell deine Festplatte kaputt schreibst. Bei mir ist das Hintergrundbild (2x4K und 2xFHD Bildschirm) ca. 11MB groß...

Das wären ~15.840MB => ~16GB in 24 Stunden, die dort geschrieben werden...

Deshalb hab ich mir gestern ein paar Stunden angeschaut, wie genau die Fenster vom Desktop funktionieren und hab eine UDF geschrieben, mit der man auf den Desktop zeichnen kann.

Ich hab dein Script mal mit der UDF umgesetzt. Das würde dann so ausschauen:

AutoIt

;Author: Kanashius@autoitscript.com, Kanashius@autoit.de, https://www.kanashius.com
#include "WallpaperUDF.au3"
#include <StaticConstants.au3>

HotKeySet("^!o", "_openOptions")
HotKeySet("^!l", "_load")

Global $hFamily, $hFontTime, $hFontDate, $hFormat, $hBrush, $hPen, $iPosDate = 25, $iPosTime = 60, $arDays = StringSplit("SO.|MO.|DI.|MI.|DO.|FR.|SA.", "|")

Global $sOptionsFile = @AppDataDir & "\Clock_Wallpaper_Options.ini"

; initialize own tray
__Wallpaper_InitDefaultTray()

; start the wallpaper drawing loop
__Wallpaper_Start(_draw, _init, _shutdown)
If @error Then MsgBox(16, "Error", "Something went wrong starting initializing the wallpaper: "&@error)

Func _draw(ByRef $hGraphics, $iWidth, $iHeight, ByRef $arScreenInfo) ; will be called for each drawing cicle.
    ; Draw Date
    Local $sDate = StringFormat("%s %02i.%02i.%04i", $arDays[@WDAY], @MDAY, @MON, @YEAR)
    Local $tLayoutDate = _GDIPlus_RectFCreate($arScreenInfo[0][0] + 200, $arScreenInfo[0][1] + $iPosDate) ; Draw at the primary screen
    Local $aInfoDate = _GDIPlus_GraphicsMeasureString($hGraphics, $sDate, $hFontDate, $tLayoutDate, $hFormat)
   _GDIPlus_GraphicsDrawStringEx($hGraphics, $sDate, $hFontDate, $aInfoDate[0], $hFormat, $hBrush)

    ; Draw Time
    Local $sTime = StringFormat("%02i:%02i:%02i", @HOUR, @MIN, @SEC)
    $tLayoutTime = _GDIPlus_RectFCreate($arScreenInfo[0][0] + 200, $arScreenInfo[0][1] + $iPosTime) ; Draw at the primary screen
    $aInfoTime = _GDIPlus_GraphicsMeasureString($hGraphics, $sTime, $hFontTime, $tLayoutTime, $hFormat)
   _GDIPlus_GraphicsDrawStringEx($hGraphics, $sTime, $hFontTime, $aInfoTime[0], $hFormat, $hBrush)

    ; Return redraw areas
    Local $arAreas[0][4]
    _addRect($arAreas, $aInfoDate)
    _addRect($arAreas, $aInfoTime)
    return SetExtended(100, $arAreas) ; Change extended to the (min) time in ms to wait between each redraw. (This does not influence _process)
EndFunc

Func _addRect(ByRef $arAreas, $aTag)
    ReDim $arAreas[UBound($arAreas)+1][4]
    For $i = 1 To 4 Step 1
        $arAreas[UBound($arAreas)-1][$i-1] = DllStructGetData($aTag[0], $i)
    Next
EndFunc

Func _init($iWidth, $iHeight, ByRef $arScreenInfo) ; The initialization method is called once before the draw loop starts.
    If UBound($arScreenInfo) = 0 Then
        MsgBox(16, "Error", "It is difficult to draw a wallpaper without a screen.")
        Exit
    EndIf
    _load()
    $hFormat  = _GDIPlus_StringFormatCreate(0x4000)
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    $hBrush = _GDIPlus_BrushCreateSolid(0xff000000)
    $hPen = _GDIPlus_PenCreate(0xC4000000, 1)
EndFunc

Func _shutdown() ; The shutdown method is called at the end of the draw loop, after __Wallpaper_Exit was called.
    _cleanUp()
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_PenDispose($hPen)
EndFunc

Func _load()
    Local $bIsPaused = __Wallpaper_IsPause() ; pause drawing, while changing the fonts
    if Not $bIsPaused Then __Wallpaper_PauseResume()
    ; Local $sBGFilePath = IniRead($sOptionsFile, "options", "image", 0)
    $iPosDate = Int(IniRead($sOptionsFile, "options", "pos_date", $iPosDate))
    $iPosTime = Int(IniRead($sOptionsFile, "options", "pos_time", $iPosTime))
    _cleanUp()
    $hFamily = _GDIPlus_FontFamilyCreate(IniRead($sOptionsFile, "options", "font", "Arial"))
    $hFontDate = _GDIPlus_FontCreate($hFamily, IniRead($sOptionsFile, "options", "size_date", 25), 0)
    $hFontTime = _GDIPlus_FontCreate($hFamily, IniRead($sOptionsFile, "options", "size_time", 25), 0)
    if Not $bIsPaused Then __Wallpaper_PauseResume()
EndFunc

Func _cleanUp()
    _GDIPlus_FontDispose($hFontTime)
    _GDIPlus_FontDispose($hFontDate)
    _GDIPlus_FontFamilyDispose($hFamily)
EndFunc

Func _openOptions()
    Run("notepad.exe " & $sOptionsFile)
EndFunc

Alles anzeigen

Ich hab noch die Sekunden hinzugefügt, weil warum nicht

Edit: Link zur UDF: Wallpaper UDF

Edit2: _getMaxRect() removed

**Bitnugger** · 1. August 2022

Zitat von Kanashius

#include "WallpaperUDF.au3"

~~Ja und wo finde ich die?~~

Hat sich erledigt...

Zitat von Kanashius

Func _getMaxRect()

Die kann wohl weg...

Michi91 · 2. August 2022

Zitat von Kanashius

Hi, ich hatte mir deinen Code gestern angesehen und fand es unglücklich, dass du jede Minute ein neues Bild erstellst, es als Datei speicherst und dann als Hintergrund setzt.

Das ist eine echt gute Methode, wie du sehr schnell deine Festplatte kaputt schreibst. Bei mir ist das Hintergrundbild (2x4K und 2xFHD Bildschirm) ca. 11MB groß...

Das wären ~15.840MB => ~16GB in 24 Stunden, die dort geschrieben werden...

Deshalb hab ich mir gestern ein paar Stunden angeschaut, wie genau die Fenster vom Desktop funktionieren und hab eine UDF geschrieben, mit der man auf den Desktop zeichnen kann.

Ich hab dein Script mal mit der UDF umgesetzt. Das würde dann so ausschauen:

AutoIt

;Author: Kanashius@autoitscript.com, Kanashius@autoit.de, https://www.kanashius.com
#include "WallpaperUDF.au3"
#include <StaticConstants.au3>

HotKeySet("^!o", "_openOptions")
HotKeySet("^!l", "_load")

Global $hFamily, $hFontTime, $hFontDate, $hFormat, $hBrush, $hPen, $iPosDate = 25, $iPosTime = 60, $arDays = StringSplit("SO.|MO.|DI.|MI.|DO.|FR.|SA.", "|")

Global $sOptionsFile = @AppDataDir & "\Clock_Wallpaper_Options.ini"

; initialize own tray
__Wallpaper_InitDefaultTray()

; start the wallpaper drawing loop
__Wallpaper_Start(_draw, _init, _shutdown)
If @error Then MsgBox(16, "Error", "Something went wrong starting initializing the wallpaper: "&@error)

Func _draw(ByRef $hGraphics, $iWidth, $iHeight, ByRef $arScreenInfo) ; will be called for each drawing cicle.
    ; Draw Date
    Local $sDate = StringFormat("%s %02i.%02i.%04i", $arDays[@WDAY], @MDAY, @MON, @YEAR)
    Local $tLayoutDate = _GDIPlus_RectFCreate($arScreenInfo[0][0] + 200, $arScreenInfo[0][1] + $iPosDate) ; Draw at the primary screen
    Local $aInfoDate = _GDIPlus_GraphicsMeasureString($hGraphics, $sDate, $hFontDate, $tLayoutDate, $hFormat)
   _GDIPlus_GraphicsDrawStringEx($hGraphics, $sDate, $hFontDate, $aInfoDate[0], $hFormat, $hBrush)

    ; Draw Time
    Local $sTime = StringFormat("%02i:%02i:%02i", @HOUR, @MIN, @SEC)
    $tLayoutTime = _GDIPlus_RectFCreate($arScreenInfo[0][0] + 200, $arScreenInfo[0][1] + $iPosTime) ; Draw at the primary screen
    $aInfoTime = _GDIPlus_GraphicsMeasureString($hGraphics, $sTime, $hFontTime, $tLayoutTime, $hFormat)
   _GDIPlus_GraphicsDrawStringEx($hGraphics, $sTime, $hFontTime, $aInfoTime[0], $hFormat, $hBrush)

    ; Return redraw areas
    Local $arAreas[0][4]
    _addRect($arAreas, $aInfoDate)
    _addRect($arAreas, $aInfoTime)
    return SetExtended(100, $arAreas) ; Change extended to the (min) time in ms to wait between each redraw. (This does not influence _process)
EndFunc

Func _addRect(ByRef $arAreas, $aTag)
    ReDim $arAreas[UBound($arAreas)+1][4]
    For $i = 1 To 4 Step 1
        $arAreas[UBound($arAreas)-1][$i-1] = DllStructGetData($aTag[0], $i)
    Next
EndFunc

Func _init($iWidth, $iHeight, ByRef $arScreenInfo) ; The initialization method is called once before the draw loop starts.
    If UBound($arScreenInfo) = 0 Then
        MsgBox(16, "Error", "It is difficult to draw a wallpaper without a screen.")
        Exit
    EndIf
    _load()
    $hFormat  = _GDIPlus_StringFormatCreate(0x4000)
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    $hBrush = _GDIPlus_BrushCreateSolid(0xff000000)
    $hPen = _GDIPlus_PenCreate(0xC4000000, 1)
EndFunc

Func _shutdown() ; The shutdown method is called at the end of the draw loop, after __Wallpaper_Exit was called.
    _cleanUp()
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_PenDispose($hPen)
EndFunc

Func _load()
    Local $bIsPaused = __Wallpaper_IsPause() ; pause drawing, while changing the fonts
    if Not $bIsPaused Then __Wallpaper_PauseResume()
    ; Local $sBGFilePath = IniRead($sOptionsFile, "options", "image", 0)
    $iPosDate = Int(IniRead($sOptionsFile, "options", "pos_date", $iPosDate))
    $iPosTime = Int(IniRead($sOptionsFile, "options", "pos_time", $iPosTime))
    _cleanUp()
    $hFamily = _GDIPlus_FontFamilyCreate(IniRead($sOptionsFile, "options", "font", "Arial"))
    $hFontDate = _GDIPlus_FontCreate($hFamily, IniRead($sOptionsFile, "options", "size_date", 25), 0)
    $hFontTime = _GDIPlus_FontCreate($hFamily, IniRead($sOptionsFile, "options", "size_time", 25), 0)
    if Not $bIsPaused Then __Wallpaper_PauseResume()
EndFunc

Func _cleanUp()
    _GDIPlus_FontDispose($hFontTime)
    _GDIPlus_FontDispose($hFontDate)
    _GDIPlus_FontFamilyDispose($hFamily)
EndFunc

Func _openOptions()
    Run("notepad.exe " & $sOptionsFile)
EndFunc

Alles anzeigen

Ich hab noch die Sekunden hinzugefügt, weil warum nicht

Edit: Link zur UDF: Wallpaper UDF

Edit2: _getMaxRect() removed

Alles anzeigen

In Zeile 73 (mein letzter Post) wird doch das Bild nachdem es als Wallpaper gesetzt wurde gelöscht.
Der Speicherverbrauch sollte eigl. minimal sein und in der Zeit von TB Festplatten nicht mehr ins Gewicht fallen.

**BugFix** · 2. August 2022

Zitat von Michi91

Der Speicherverbrauch sollte eigl. minimal sein und in der Zeit von TB Festplatten nicht mehr ins Gewicht fallen.

Aber der Speichervorgang.

Unnütze Schreibvorgänge sind der SSD-Platte ihr Tod.

Moombas · 2. August 2022

Zitat von BugFix

Aber der Speichervorgang.
Unnütze Schreibvorgänge sind der SSD-Platte ihr Tod.

Richtig, weshalb man auch gerne bei allen SSD's die Auslagerungsdatei abschalten sollte, um so unnötige Schreibvorgänge zu vermeiden.

Teilen