Barcode Scanner mit Etiketten Drucker

Haldi

Hallo zusammen,

Einsatzziel wäre es beim Scannen des Auftrages direkt die passenden Etiketten drucken zu können.

Auftragsblätter besitzen einen Barcode:

Dieser wird per Scanner gesannt. Wie jeder dieser einfachen billigen Scanner haben die einen USB Anschluss und werden als HID Keyboard erkannt und tippen das gescannte einfach in das offene Fenster.

Die Etikette wird über einen Brother Drucker gedruckt mit der Software P-Touch Editor.

Die ist so fortgeschritten das sie Datenbanken und Excel dokumente unterstützt.

Mein eigentlicher plan ist:

Ich schreibe einen überwacher der im Hintergrund immer auf Spezialtasten kombination CTRL+ALT+1 (oder so ähnlich) achtet, dann bei eingabe die P-Touch Software öffnet und ein eingabefeld für den Barcode öffnet.

Alles kein Problem. Ausser das man nun entweder vorher eine Tastenkombination eintippen muss oder einen zweiten Barcode abscanen der die Tastenkombi auslöst.

Nun kommt meine geniale Idee.

Da der Barcode IMMER mit TZProduktion- anfängt müsste es doch eigentlich möglich sein sobald der Scanner die Tasteneingabe "TZproduktion-" erkennt den resten zu speichern, P-Touch Editor zu öffnen, Suche nach Barcode in der Datenbank, Etikette drucken. Fertig.

Und nun erkennt ihr sicher auch mein Problem.

Es findet sich beinahe nichts dazu wie ich auf eingabe von String XYZ warte und dann den zweiten Teil davon zwischenspeichere.

Hat vielleicht jemand Tipps dazu was das einfachste vorgehen wäre? oder vorlagen wo sowas ähnliches schon läuft?

mfg

**Alina**

Moin.

Bitte einmal das Skript posten, so weit Du es fertig hast.
Dann geht es evtl. besser mit dem helfen !!!

**Moombas**

Warum so kompliziert?

Also am einfachsten wäre, du hast eine GUI mit nur einem Input, wo du "reinscannst", davon abhängig läuft dann der Rest.

Würde da etwas dagegen sprechen?

Haldi

Zitat von Moombas

Also am einfachsten wäre, du hast eine GUI mit nur einem Input, wo du "reinscannst", davon abhängig läuft dann der Rest.

Das ich somit auf dem PC an dem der Drucker hänget IMMER das Inputfenster offen und fokusiert haben muss damit es funktioniert.

Da der Scanner eine USB Basisstation hat aber selber Wireless ist und somit NICHT immer direkt neben dem PC steht, könnte das evtl probleme geben.

Aber ja... eigentlich ein gutes Argument.

Wenn ich das andere nicht hinbekomme wirds wohl auf das heraus laufen.

**Moombas**

Alternativ wäre eine art keylogger (alle Zeichen der Tastatur mitloggen (TAB/Leertaste macht ein Reset der Daten) und immer prüfen ob der eingegebene String deiner Erwartung entspricht) aber ob das Sinnvoll und im Unternehmen erlaubt ist, sei mal dahin gestellt.

**Moombas**

Aber blöde Frage: Wie arbeitet der Scanner?

Wir haben das beim Zebra (gleiches Setup), das der Scanner erst die gescannten Datenüberträgt, wenn er in die Station gesteckt wird.

Oder überträgt der DeLock diese kontinuierlich?

Haldi

Natürlich Kontinuierlich.

Ist ja schliesslich ein WIRELESS Scanner. Wenn du abdrückst kommt der Input so gut wie ohne verzögerung.

Für das wenig geld echt ein cooles ding. Nur wie gut der Akku hält müssen wir noch testen.

**Kanashius**

Hi,

vor nicht allzu langer Zeit hatte jemand eine ähnliche Anfrage. Das wurde dort von Oscar mit einem Keyboardhook gelöst. Der Code kann relativ einfach auf dein Problem umgebaut werden. Einfach das Fenster weglassen und in der _KeyProc die Tasten erfassen. Dabei immer weiter in eine Variable schreiben, bis der Inhalt von dem gewollten Pattern abweicht. Bei einer Abweichung den Anfang wegnehmen, bis zum nächsten möglichen Anfang des Patterns.

Den Code findest du hier: RE: Barcode in Variable scannen ohne den Inhalt irgendwo anzuzeigen

Falls du das selbst nicht anpassen kannst, meld dich gerne wieder.

MfG, Kanashius

Haldi

Ohhh danke für den Hinweis!

Ich sehe schon das Oscar hier eine wundervolle Vorlage erstellt hat.

AutoIt

#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
#include <WinAPIConstants.au3>
#include <WinAPIInternals.au3>
#include <WinAPISys.au3>
#include <WinAPISysInternals.au3>
#include <WindowsConstants.au3>
#include <FileConstants.au3>
#include <File.au3>
#include <WinAPI.au3>

Global $Gewerk = "Polsterei"
Global $Titel = "Polsterei.htm"
Global $Titelmin = "Polsterei_min.htm"

Global $Freigabe = "\\ste01\planung\"
Global $hmod, $hHook, $hStub_KeyProc, $buffer = '', $scannerbufferflag = 0
Global $LogText =""
Global $Eingabe
Global $File[5]

; Hier den Postfix-Code von eurem Scanner eintragen.
Global $g_iPostfix = 0x0D ;Enter
; Hier den Prefix-Code von eurem Scanner eintragen.
Global $g_iPrefix = 0x71 ;F2

HotKeySet('{ESC}', '_Exit')
OnAutoItExitRegister('OnAutoItExit')
Global $hKeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
Global $hmod = _WinAPI_GetModuleHandle(0)
Global $hKeyHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hKeyProc), $hmod)

Global $hGui = GUICreate('Barcodescanner', 300, 140)
Global $idBarcode = GUICtrlCreateLabel('', 10, 10, 280, 30)
GUICtrlSetFont(-1, 16, 400, 0, 'Courier New')
Global $idInput = GUICtrlCreateInput('', 10, 50, 280, 30)
GUICtrlSetFont(-1, 16, 400, 0, 'Courier New')
GUISetState(@SW_HIDE)
Global $g_bBufferOk = False, $g_sBuffer = ''
Do
    If $g_bBufferOk Then
        _StatusSave($g_sBuffer)
        $g_sBuffer = ''
        $g_bBufferOk = False
    EndIf
Until GUIGetMsg() = $GUI_EVENT_CLOSE
consolewrite("ende")
Exit

Func _Exit()
    Exit
EndFunc

; ACHTUNG! Callback-Funktion!
; In dieser Funktion darf es keinen blockierenden Code (z.B. MsgBox, Sleep, etc.) geben!
; Hier werden direkt die virtuellen Keycodes der Tastatur ausgewertet:
; https://docs.microsoft.com/en-us/windows/win32/inputdev/virtual-key-codes
Func _KeyProc($nCode, $wParam, $lParam)
    Local $tKBDLLHOOK = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
    Local $iKeyCode = $tKBDLLHOOK.vkCode, $iPressTime
    Local Static $sBuffer = '', $bBarcodeActive = False
    If $nCode >= 0 Then
        If $iKeyCode = $g_iPrefix And $wParam = $WM_KEYUP Then
            $bBarcodeActive = Not $bBarcodeActive
            ConsoleWrite('$bBarcodeActive = ' & $bBarcodeActive & @CRLF)
            $sBuffer = ''
        EndIf
        If $bBarcodeActive Then
            Switch $wParam
                Case $WM_KEYDOWN
                    Return 1
                Case $WM_KEYUP
                    Switch $iKeyCode ; Keycode auswerten
                        Case $g_iPostfix
                            ConsoleWrite(StringFormat('Barcode = "%s"\r\n', $sBuffer))
                            $g_sBuffer = $sBuffer
                            $g_bBufferOk = True
                            $sBuffer = ''
                            $bBarcodeActive = False
                            ConsoleWrite('$bBarcodeActive = ' & $bBarcodeActive & @CRLF)
                            Return 1
                        Case 0x30 To 0x39, 0x41 To 0x5A ; 0 - 9, A - Z
                            $sBuffer &= Chr($iKeyCode)
                            Return 1
                    EndSwitch
            EndSwitch
        EndIf
    EndIf
    Return _WinAPI_CallNextHookEx($hKeyHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

; Wichtig! Beim Programmende den Hook wieder entfernen.
Func OnAutoItExit()
    _WinAPI_UnhookWindowsHookEx($hKeyHook)
    DllCallbackFree($hKeyProc)
EndFunc   ;==>OnAutoItExit

Func _StatusSave($sBuffer)
    Local $hFile
    If FileExists($Freigabe & "\Prod-Status\" & $Gewerk & "\" & $sBuffer & "_Start.log") Then
        $hFile = FileOpen($Freigabe & "\Prod-Status\" & $Gewerk & "\" & $sBuffer & "_Ende.log", 1)
        beep(500,200)
        beep(500,200)
    Else
        $hFile = FileOpen($Freigabe & "\Prod-Status\" & $Gewerk & "\" & $sBuffer & "_Start.log", 1)
        beep(500,200)
    EndIf
    _FileWriteLog($hFile, $sBuffer & @CRLF)
    FileClose($hFile)
EndFunc   ;==>StatusSave

Alles anzeigen

Gehe ich korrekt in der Annahme dass das alles darauf basiert das der Scanner (hier in diesem falle mit F2 und Enter) sämtliche Scans einkapselt?

Ich sehe zwar noch nicht wie das GUI aufgerufen wird, aber so wies ausschaut sollte ich mit der "Func _StatusSave($sBuffer)" eigentlich an den Barcode rankommen.

Werde das morgen in aller Frische mal versuchen! Hab iwo noch ne fette anleitung des Scanners, wenn probieren nicht hilft sollte vielleicht da noch stehen welche Pre/Postfix der verwendet.

Danke.

**Kanashius**

Hi,

Ich hatte gerade Zeit und fand das ganze interessant, also hab ich das mal mit Pattern-Matching umgesetzt.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIvkeysConstants.au3>
OnAutoItExitRegister('OnAutoItExit')

;HotKeySet('{ESC}', '_exit')

;Global $sStart = StringUpper("TZProduktion-")
Global $sStart = StringUpper("test")
Global $arBuffer[200], $iBufferEnd = 0, $bBufferMatch = False, $arStart = StringSplit($sStart, "", BitOR(1, 2))

Global $hKeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
Global $hmod = _WinAPI_GetModuleHandle(0)
Global $hKeyHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hKeyProc), $hmod)

Global $iWidth = 300, $iHeigt = 200
Global $hGui = GUICreate('Barcodescanner', $iWidth, $iHeigt)
Global $idBarcode = GUICtrlCreateLabel('', 10, 10, $iWidth-20, 30)
GUISetState(@SW_SHOW)

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _exit()
    EndSwitch
WEnd

Func _barcodeFound($sBarcode)
    ConsoleWrite("FOUND: "&$sBarcode&@crlf)
EndFunc

Func _exit() ;just to enable the ESC hotkey
    Exit
EndFunc

; ACHTUNG! Callback-Funktion!
; In dieser Funktion darf es keinen blockierenden Code (z.B. MsgBox, Sleep, etc.) geben!
; Hier werden direkt die virtuellen Keycodes der Tastatur ausgewertet:
; https://docs.microsoft.com/en-us/windows/win32/inputdev/virtual-key-codes
Func _KeyProc($nCode, $wParam, $lParam)
    Local $tKBDLLHOOK = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
    Local $iKeyCode = $tKBDLLHOOK.vkCode, $iPressTime
    $iKeyCode = _WinAPI_MapVirtualKey($iKeyCode, $MAPVK_VK_TO_CHAR) ; needed for different keyboard layouts (e.g. US-layout - is ASCII 189, not 45 otherwise)
    If $nCode >= 0 Then
        Switch $wParam
            Case $WM_KEYUP
                If $iKeyCode = 45 Or _
                    ($iKeyCode>=48 And $iKeyCode<=57) Or _
                    ($iKeyCode>=65 And $iKeyCode<=90) Then
                    $arBuffer[$iBufferEnd] = Chr($iKeyCode)
                    $iBufferEnd += 1
                    If $iBufferEnd>UBound($arBuffer)-1 Then $iBufferEnd = 0 ; Reset if longer than buffer, may lead to scan loss
                    If Not $bBufferMatch Then _checkBuffer()
                Else
                    If $bBufferMatch Then _barcodeFound(_bufferToStr())
                    $bBufferMatch = False
                    $iBufferEnd = 0
                EndIf
                GUICtrlSetData($idBarcode, _bufferToStr())
                ; Return 1
        EndSwitch
    EndIf
    Return _WinAPI_CallNextHookEx($hKeyHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

Func _checkBuffer()
    Local $iCount = 0, $iStart = 0
    While $iCount<$iBufferEnd
        $iStart = $iCount
        While $iStart < $iBufferEnd
            If $arBuffer[$iStart] <> $arStart[$iStart-$iCount] Then
                $iCount += 1
                ContinueLoop 2
            EndIf
            If $iStart-$iCount >= UBound($arStart)-1 Then
                $bBufferMatch = True
                Return True
            EndIf
            $iStart+=1
        WEnd
        ExitLoop
    WEnd
    If $iCount<>0 Then
        Local $iDiff = $iBufferEnd-$iCount
        If $iDiff<=0 Then
            $iBufferEnd=0
        Else
            For $i=0 To $iDiff Step 1
                $arBuffer[$i] = $arBuffer[$iCount+$i]
            Next
            $iBufferEnd=$iDiff
        EndIf
        Return False
    EndIf
    Return True
EndFunc

Func _bufferToStr()
    Local $sRes = ""
    For $i=0 To $iBufferEnd-1 Step 1
        $sRes &= $arBuffer[$i]
    Next
    Return $sRes
EndFunc

; Wichtig! Beim Programmende den Hook wieder entfernen.
Func OnAutoItExit()
    _WinAPI_UnhookWindowsHookEx($hKeyHook)
    DllCallbackFree($hKeyProc)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

Das Fenster ist optional, ich habs nur zum Anzeigen und Testen drin.

In der Funktion _barcodeFound kannst du dann mit dem Code machen, was du möchtest. (Also auch dein Programm öffnen,...).

Ich lese alle 0-9, A-Z und - Zeichen ein und füge sie zum Buffer hinzu. Wird eine andere Taste gedrückt, wird der Buffer zurückgesetzt, oder der Barcode als erkannt gemeldet (je nachdem, ob das Pattern passt oder nicht).

Das betrifft auch Tasten wie SHIFT. Falls dein Scanner Groß/Klein-schreibung beachtet musst du evtl. den Code für SHIFT ignorieren, um nicht zurückzusetzen (Zeile 55). Dementsprechend ignoriert der Code auch Groß/Klein-Schreibung beim Pattern.

Der Buffer hat max. 200 Zeichen, das ganze Funktioniert also nur, wenn dein Code weniger als 200 Zeichen hat. Ggf. musst du den Buffer anpassen, bis es für dich passt.

Ich hab dabei auch festgestellt, dass man nicht einfach den KeyCode zum vergleichen verwenden sollte. Ich nutze eine Tastatur mit US-Layout und das - hat dort den vkCode 189 und nicht 45. Deshalb nutze ich die _WinAPI_MapVirtualKey um den Virtuellen Keycode auf den eigentlichen KeyCode umzuwandeln. Sollte man also immer machen; man weiß ja nie, was für eine Tastatur grad angeschlossen ist.

Ich hoffe das hilft dir weiter

MfG, Kanashius

Haldi

Zitat von Kanashius

Das betrifft auch Tasten wie SHIFT. Falls dein Scanner Groß/Klein-schreibung beachtet musst du evtl. den Code für SHIFT ignorieren, um nicht zurückzusetzen (Zeile 55). Dementsprechend ignoriert der Code auch Groß/Klein-Schreibung beim Pattern.

Scheint so als würde er mit Shift machen und mit Tab beenden.

AutoIt

            Case $WM_KEYUP
                 If $iKeyCode = 45 Or _ ;key -
                     ($iKeyCode>=48 And $iKeyCode<=57) Or _ ;Numbers 0 to 9
                    ($iKeyCode>=65 And $iKeyCode<=90) Then ; Letters A to Z
                    $arBuffer[$iBufferEnd] = Chr($iKeyCode)
                    $iBufferEnd += 1
                    If $iBufferEnd>UBound($arBuffer)-1 Then $iBufferEnd = 0 ; Reset if longer than buffer, may lead to scan loss
                    If Not $bBufferMatch Then _checkBuffer()
                Else
                    If $bBufferMatch Then _barcodeFound(_bufferToStr())
                    $bBufferMatch = False
                    $iBufferEnd = 0
                EndIf
                GUICtrlSetData($idBarcode, _bufferToStr())

Alles anzeigen

Shift wird VORHER getriggert, also wenn ich nur nach "Produktion" suche findet er dies...

"FOUND: PRODUKTION-22103748-101"

Okay... ich seh ich hab wesentlich weniger Ahnung als ich gedacht habe^^

Irgendwie muss da also im Else der Ignore Shift befehlt eingebaut werden....

Grossklein schreibung ist zum glück eh irrelevant.

**Moombas**

Zitat von Haldi

Natürlich Kontinuierlich.
Ist ja schliesslich ein WIRELESS Scanner. Wenn du abdrückst kommt der Input so gut wie ohne verzögerung.
Für das wenig geld echt ein cooles ding. Nur wie gut der Akku hält müssen wir noch testen.

Naja, das kommt auf den Anwendungsfall wie man Wireless definiert an.

Beispiel 1:

Der Scanner ist per Basis, Dongle, BT mit dem PC/Kasse/Smartphone,... verbunden und überträgt die gescannten Daten direkt.

Beispiel 2:

Du gehst zum Scannen außerhalb der Reichweite (anderes Lagerhaus, Keller,...), scannst Kartons etc. (die gescannten Daten werden dann im Scanner gespeichert) und packst ihn dann zum Auslesen in die Station, wo diese dann vom PC verarbeitet werden müssen. Das wäre auch eine Form von Wireless arbeiten.

Aber an die schon existierende (Teil)-Lösung von Oscar hatte ich garnicht mehr gedacht. Gut das Kanashius das noch wusste

**Kanashius**

Zitat von Haldi

Okay... ich seh ich hab wesentlich weniger Ahnung als ich gedacht habe^^

Irgendwie muss da also im Else der Ignore Shift befehlt eingebaut werden....

In Zeile 51 findest du den Aufruf der Methode Chr(). Wenn du die Hilfe dazu öffnest (anklicken und F1), dann Findest du unter "Remarks" einen Link zur ASCII Character Code table. Da stehen die Zahlen zu allen Zeichen drin.

Ansonsten kannst du auch einfach nach Zeile 47 ein ConsoleWrite($iKeyCode&@crlf) einfügen. Dann bekommst du die Ausgabe des Zahlencodes, wenn du die Taste drückst und kannst einfach ausprobieren

In diesem Fall würde ich einfach das Else in Zeile 55 (Zeile 9 in dem Ausschnitt, den du gepostet hast) abändern zu ElseIf $iKeyCode<>0 Then. Damit sollten alle Tasten, die nichts ausgeben (wie SHIFT, ALT,...) keinen Unterschied mehr machen.

Haldi

Zitat von Kanashius

Ansonsten kannst du auch einfach nach Zeile 47 ein ConsoleWrite($iKeyCode&@crlf) einfügen.

Ohhh.... Das ist eine geniale idee.

Das mit den ASCI -> Char hab ich im internet gefunden für 0-9 und A-z aber Shift war da nicht dabei.

Macht ja auch sinn wenn das 0 ist.

Die Methode mit ElseIf hat funktioniert!

Tausend dank.

Ich kann eigentlich das ganze P-Touch mit ControlClicks steuern. Machts recht bequem.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIvkeysConstants.au3>
OnAutoItExitRegister('OnAutoItExit')

Global $fileName = "[PoC_3.lbx]", $windowName = "P-touch Editor - "&$fileName

HotKeySet('{ESC}', '_exit')

Global $sStart = StringUpper("TZProduktion-")
Global $arBuffer[200], $iBufferEnd = 0, $bBufferMatch = False, $arStart = StringSplit($sStart, "", BitOR(1, 2))

Global $hKeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
Global $hmod = _WinAPI_GetModuleHandle(0)
Global $hKeyHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hKeyProc), $hmod)

Global $iWidth = 300, $iHeigt = 200
Global $hGui = GUICreate('Barcodescanner', $iWidth, $iHeigt)
Global $idBarcode = GUICtrlCreateLabel('', 10, 10, $iWidth-20, 30)
GUISetState(@SW_SHOW) ;HIER FENSTER VERSTECKEN.

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _exit()
    EndSwitch
WEnd

Func _barcodeFound($sBarcode)
    ConsoleWrite("FOUND: "&$sBarcode&@crlf)
    If WinExists($windowName) Then
        WinActivate($windowName)
    Else
        MsgBox(0, "Error Kein Window", $windowName) ;ODER Programm Starten und Vorlage öffnen!
        Exit ;temp.....
EndIf
ControlClick($windowName, "", 11945) ;Suchfeld öffnen
WinWait("Suchen")
ControlSetText("Suchen", "", 11171, StringTrimLeft($sBarcode, 13))
ControlClick("Suchen", "Gefundene &Datensätze auswählen", 11178) ;Suchen
Sleep(200)
If WinExists("P-touch Editor", "Alle Datensätze wurden durchsucht.")  Then
;~     MsgBox(262144, "ERROR", "Existiert nicht")
    ControlClick("P-touch Editor", "OK", 2)
    ControlClick("Suchen", "Schließen", 2)
    Beep(500, 500)
    Sleep(50)
    Beep(500, 500)
    ToolTip("ERROR! Auftrag nicht gefunden")
Else
WinWaitActive($windowName)
ControlClick($windowName, "", 5350) ;Direct Print
EndIf
EndFunc

Func _exit() ;just to enable the ESC hotkey
    Exit
EndFunc

; ACHTUNG! Callback-Funktion!
; In dieser Funktion darf es keinen blockierenden Code (z.B. MsgBox, Sleep, etc.) geben!
; Hier werden direkt die virtuellen Keycodes der Tastatur ausgewertet:
; https://docs.microsoft.com/en-us/windows/win32/inputdev/virtual-key-codes
Func _KeyProc($nCode, $wParam, $lParam)
    Local $tKBDLLHOOK = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
    Local $iKeyCode = $tKBDLLHOOK.vkCode, $iPressTime
    $iKeyCode = _WinAPI_MapVirtualKey($iKeyCode, $MAPVK_VK_TO_CHAR) ; needed for different keyboard layouts (e.g. US-layout - is ASCII 189, not 45 otherwise)
    If $nCode >= 0 Then
        Switch $wParam
            Case $WM_KEYUP
                 If $iKeyCode = 45 Or _ ;key -
                     ($iKeyCode>=48 And $iKeyCode<=57) Or _ ;Numbers 0 to 9
                    ($iKeyCode>=65 And $iKeyCode<=90) Then ; Letters A to Z
                    $arBuffer[$iBufferEnd] = Chr($iKeyCode)
                    $iBufferEnd += 1
                    If $iBufferEnd>UBound($arBuffer)-1 Then $iBufferEnd = 0 ; Reset if longer than buffer, may lead to scan loss
                    If Not $bBufferMatch Then _checkBuffer()
                ElseIf $iKeyCode <> 0 Then
                    If $bBufferMatch Then _barcodeFound(_bufferToStr())
                    $bBufferMatch = False
                    $iBufferEnd = 0
                EndIf
                GUICtrlSetData($idBarcode, _bufferToStr())
                ; Return 1
        EndSwitch
    EndIf
    Return _WinAPI_CallNextHookEx($hKeyHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

Func _checkBuffer()
    Local $iCount = 0, $iStart = 0
    While $iCount<$iBufferEnd
        $iStart = $iCount
        While $iStart < $iBufferEnd
            If $arBuffer[$iStart] <> $arStart[$iStart-$iCount] Then
                $iCount += 1
                ContinueLoop 2
            EndIf
            If $iStart-$iCount >= UBound($arStart)-1 Then
                $bBufferMatch = True
                Return True
            EndIf
            $iStart+=1
        WEnd
        ExitLoop
    WEnd
    If $iCount<>0 Then
        Local $iDiff = $iBufferEnd-$iCount
        If $iDiff<=0 Then
            $iBufferEnd=0
        Else
            For $i=0 To $iDiff Step 1
                $arBuffer[$i] = $arBuffer[$iCount+$i]
            Next
            $iBufferEnd=$iDiff
        EndIf
        Return False
    EndIf
    Return True
EndFunc

Func _bufferToStr()
    Local $sRes = ""
    For $i=0 To $iBufferEnd-1 Step 1
        $sRes &= $arBuffer[$i]
    Next
    Return $sRes
EndFunc

; Wichtig! Beim Programmende den Hook wieder entfernen.
Func OnAutoItExit()
    _WinAPI_UnhookWindowsHookEx($hKeyHook)
    DllCallbackFree($hKeyProc)
EndFunc   ;==>OnAutoItExit

Alles anzeigen