#include <File.au3>
#include <Array.au3>
#include <StringConstants.au3>
#include <Date.au3>

Global $sReplaceFile, $sFileRead, $sReplaceFileName, $sReplaceFileExt, $sReplaceFileNew
Global $aReplaceArr, $sFilePathReplaceArr
Global $iError, $iReplacements, $iFileEncoding, $bValueChanged = False

; [optional] : diese Globals dienen nur zur Zeitmessung :
Global $hTimer, $fTimerDiff, $iTimerHours = 0, $iTimerMins = 0, $iTimerSecs = 0, $iTimerMilliSecs = 0

$sReplaceFileName = "Testtext01"
$sReplaceFileExt  = ".txt"
$sReplaceFile     = @ScriptDir & "\" & $sReplaceFileName & $sReplaceFileExt
$sReplaceFileNew  = @ScriptDir & "\" & $sReplaceFileName & "_New" & $sReplaceFileExt

If Not FileExists($sReplaceFile) Then
	ConsoleWrite('! ---> Datei : ' & $sReplaceFile & ' nicht gefunden -> EXIT' & @CRLF)
	Exit
EndIf

; Array mit den 'Suchen & Ersetzen'-Werten :
;    Spalte 0 = gesuchte Textkette
;    Spalte 1 = neue Textkette
;    Spalte 2 = falls Semikolon (;) -> Element nicht ersetzen (quasi auskommentiert)

$sFilePathReplaceArr = @ScriptDir & "\ReplaceArr01.txt"
_FileReadToArray($sFilePathReplaceArr, $aReplaceArr, BitOR($FRTA_COUNT, $FRTA_ENTIRESPLIT) , "#|#")
_ArrayDisplay($aReplaceArr, "Replace Array") ; *** nur zur Anzeige

; [optional] : Zeitmessung starten :
$hTimer = TimerInit()


$sFileRead = FileRead($sReplaceFile)
If @error Then
	ConsoleWrite('! ---> Datei : ' & $sReplaceFile & ' kann nicht gelesen werden -> EXIT' & @CRLF)
	Exit
EndIf

For $i = 1 To $aReplaceArr[0][0]
	; Falls in Spalte 2 ein Semikolon vorkommt ==> nicht bearbeiten
	If Not StringInStr($aReplaceArr[$i][2], ';') Then
		ConsoleWrite('+ ===> Arrayzeile <' & $i & '> : Ersetze <' & $aReplaceArr[$i][0] & '> mit <' & $aReplaceArr[$i][1] & '>' & @CRLF)

		$sFileRead     = StringRegExpReplace($sFileRead, '(?i)' & $aReplaceArr[$i][0], $aReplaceArr[$i][1])
		$iError        = @error
		$iReplacements = @extended
		If Not $iError Then
			$bValueChanged = True
			ConsoleWrite('< -----> <' & $aReplaceArr[$i][0] & '>  wurde ' & $iReplacements & ' mal mit <' & $aReplaceArr[$i][1] & '> ersetzt' & @CRLF)
		EndIf
	Else
		ConsoleWrite('> ===> Arrayzeile <' & $i & '> auskommentiert !' & @CRLF)
	EndIf
Next

If $bValueChanged Then
    Local $iFileEncoding = FileGetEncoding($sReplaceFile)
    Local $hFileOpen = FileOpen($sReplaceFileNew, BitOR($iFileEncoding, $FO_OVERWRITE))
    FileWrite($hFileOpen, $sFileRead)
    FileClose($hFileOpen)
EndIf

; [optional] : Zeitdauer des Prozesses anzeigen :
$fTimerDiff = TimerDiff($hTimer)
$iTimerMilliSecs = Int(Mod($fTimerDiff, 1000))
_TicksToTime(Int($fTimerDiff), $iTimerHours, $iTimerMins, $iTimerSecs)
$sString = StringFormat("%02d:%02d:%02d.%03d (Std:Min:Sek.Millisek)", $iTimerHours, $iTimerMins, $iTimerSecs, $iTimerMilliSecs)
ConsoleWrite("Generierungszeit = " & $sString & @CRLF)