#cs ----------------------------------------------------------------------------

  AutoIt Version: 3.3.14.5

  HighlightAllOccurrencesOfSelection 0.0.7

  Professor Bernd, 2019-11
#ce ----------------------------------------------------------------------------

;~ #NoTrayIcon
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <GuiListBox.au3>
#include <String.au3>
#include <Misc.au3>
#include <Array.au3>
#include <GuiListBox.au3>
#include <GuiRichEdit.au3>
#include <GuiEdit.au3>

AutoItSetOption("MustDeclareVars", 1)


; Programm nur 1x starten. Gegen "Dauerfeuer", wenn User Shortcut gedrückt hält.
_Singleton("PSPad->HighlightAllOccurrencesOfSelection")


Main_Func()


; =========================================================================
; Main_Func
;
; Main-Funktion.
; -------------------------------------------------------------------------
Func Main_Func()

  Local $hPSPad = Null

  ; PSPad-Handle ermitteln.
  WinWaitActive("[CLASS:TfPSPad]")        ; <== Nur für Tests das hier benutzen.
  $hPSPad = _WinAPI_GetForegroundWindow()

  If $hPSPad = Null Then
    MsgBox(0, 'Error', 'PSPad-Handle wurde nicht gefunden!')
    Exit(2) ; 2 = PSPad-hwnd nicht gefunden.
  EndIf

  ; Code nur ausführen, wenn das Fenster ein PSPad-Fenster ist.
  If _WinAPI_IsClassName($hPSPad, "TfPSPad") Then

    Local $sTxt
    Local $sSelTxt
    Local $range
    Local $sClassNameChildEd
    Local $sClassNameSynEd
    Local $aCtrlRecvMsg
    Local $tActiveEdit

    $tActiveEdit = PSPad_GetActiveEditor($hPSPad)

    Local $hwnd_ActvEd = $tActiveEdit.hWnd_ActvEdt
    Local $hwnd_SynEdt = $tActiveEdit.hWnd_SynEdt
    Local $iID_ActvEd = $tActiveEdit.ID_ActvEdt
    Local $iID_SynEdt = $tActiveEdit.ID_SynEdt


    $sSelTxt = ""

    $sSelTxt = ControlGetText($hwnd_SynEdt, '', '')
;~     $sSelTxt = ControlGetText($hPSPad, '', $iID_SynEdt)
;~     $sSelTxt = ControlGetText($hPSPad, '', 'TPSSynEdit1')
    ConsoleWrite('---------------------------------------------------' & @CRLF)
    ConsoleWrite($sSelTxt & @CRLF)
    ConsoleWrite('---------------------------------------------------' & @CRLF)

  Else
    ; Falls das Fenster KEIN PSPad-Fenster ist.
  EndIf
EndFunc ; ==> Main_Func


; =========================================================================
; PSPad_GetActiveEditor
;
; Funktion zum Ermitteln des aktiven Editor-Fensters.
; -------------------------------------------------------------------------
Func PSPad_GetActiveEditor($_hPSPad, $_sFilePath = "")

  Local $sStruct_Edit = _
    'hwnd hWnd_ActvEdt;' & _
    'int ID_ActvEdt;' & _
    'hwnd hWnd_SynEdt;' & _
    'int ID_SynEdt;'

  Local $tResult = DllStructCreate($sStruct_Edit)
  Local $aEnum
  Local $sPSPadTitle, $sEditPath
  Local $i, $x

  ; Alle ChildWindows in ein Array speichern.
  $aEnum = _WinAPI_EnumChildWindows($_hPSPad, False)

  If IsArray($aEnum) Then

    ; Pfad aus dem PSPad Fenster-Titel auslesen.
    If $_sFilePath = "" Then
      $sPSPadTitle = WinGetTitle($_hPSPad)
      $_sFilePath = _StringBetween($sPSPadTitle, '[', ']')[0]
    EndIf

    For $i = 1 To $aEnum[0][0]

      ; Nach Klasse "TfChildEdit" suchen.
      If $aEnum[$i][1] = "TfChildEdit" Then
        ; Pfad aus TfChildEdit auslesen.
        $sEditPath = ControlGetText($_hPSPad, '', _WinAPI_GetDlgCtrlID($aEnum[$i][0]))
        If $sEditPath = $_sFilePath Then ; ActiveEditor gefunden.
          $tResult.hWnd_ActvEdt = $aEnum[$i][0]
          $tResult.ID_ActvEdt =  _WinAPI_GetDlgCtrlID($tResult.hWnd_ActvEdt)

          ; Verbleibende Childs durchsuchen, denn nächst folgendes
          ; Handle der Klasse "TPSSynEdit" gehört zum aktiven Editor.
          For $x = $i + 1 To $aEnum[0][0]

            ; Nach Klasse "TPSSynEdit" suchen.
            If $aEnum[$x][1] = "TPSSynEdit" Then
              $tResult.hWnd_SynEdt = $aEnum[$x][0]
              $tResult.ID_SynEdt = _WinAPI_GetDlgCtrlID($tResult.hWnd_SynEdt)
              Return $tResult ; Wenn gefunden, dann raus aus der Funktion.
            EndIf
          Next
        EndIf
      EndIf
    Next
  EndIf

  ; Falls nicht gefunden, leeres Result zurückgeben, um Laufzeitfehler zu vermeiden.
  Return $tResult
EndFunc ; ==> PSPad_GetActiveEditor
