﻿;-- TIME_STAMP   2020-01-30 21:19:33

#include 'Dt.au3'
#include <Date.au3>


; für formatierte Ausgaben mit Date.au3
Global $aDayNameLong[] = ['', 'Montag', 'Dienstag', 'Mittwoch', 'Donnerstag', 'Freitag', 'Sonnabend', 'Sonntag']
Global $aDayNameShort[] = ['', 'Mo', 'Di', 'Mi', 'Do', 'Fr', 'Sa', 'So']
Global $aMonLong[] = ['', 'Januar', 'Februar', 'März', 'April', 'Mai', 'Juni', 'Juli', 'August', 'September', 'Oktober', 'November', 'Dezember']
Global $aMonShort[] = ['', 'Jan', 'Feb', 'März', 'Apr', 'Mai', 'Jun', 'Jul', 'Aug', 'Sept', 'Okt', 'Nov', 'Dez']

ConsoleWrite(StringFormat('%110s%30s\n\n', 'Date.au3', 'Dt.au3'))
ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', "Datum für Heute als Calc-Datum 'YYYY/MM/DD'", _
	_NowCalcDate(), _
	_Dt_Today()))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Heute formatiert als "KW nn Tagesname(lang), dd.MM.yy"', _
	StringFormat('KW %02d %s, %02d.%02d.%s', _WeekNumberISO(), _DateToDayNameLocale(), @MDAY, @MON, StringRight(@YEAR, 2)), _
	_Dt_Today("'KW 'ww dddd, dd.MM.yy")))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Heute formatiert als "KW nn Tagesname(kurz), dd. Monat(lang) yyyy"', _
	StringFormat('KW %d %s, %02d. %s %d', _WeekNumberISO(), _DateToDayNameLocale(-1, 0), @MDAY, $aMonLong[@MON], @YEAR), _
	_Dt_Today("'KW 'w ddd, d. MMMM yyyy")))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Heute formatiert als "LOCALE SHORT"', _
	_DateTimeFormat(_NowCalcDate(), 2), _
	_Dt_Today(0)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Heute formatiert als "LOCALE LONG"', _
	_DateTimeFormat(_NowCalcDate(), 1), _
	_Dt_Today(1)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Anzahl Kalenderwochen (52 od. 53) im aktuellen Jahr: ' & @YEAR, _
	'-- none function --', _
	_Dt_CountWeeks(@YEAR)))

Local $iYDay = _Dt_DateToDayNumYear(@YEAR & '/10/10')
ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Nummer des Tages im Jahr für Datum: ' & @YEAR & '/10/10', _
	'-- none function --', _
	_Dt_DateToDayNumYear(@YEAR & '/10/10')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum für Tag ' & $iYDay & ' im Jahr ' & @YEAR, _
	'-- none function --', _
	_Dt_DayNumYearToDate(@YEAR, $iYDay)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateAdd (Heute +35 Tage) mit Ausgabe Calc-Datum', _
	_DateAdd('D', 35, _NowCalcDate()), _
	_Dt_Add('D', 35, _Dt_Today())))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateAdd (Heute -7 Wochen) mit Ausgabe formatiert als "LOCALE SHORT"', _
	_DateTimeFormat(_DateAdd('w', -7, _NowCalcDate()), 2), _
	_Dt_Add('w', -7, _Dt_Today(), 0)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateAdd (Heute +9 Monate) mit Ausgabe formatiert als "LOCALE LONG"', _
	_DateTimeFormat(_DateAdd('M', 9, _NowCalcDate()), 1), _
	_Dt_Add('M', 9, _Dt_Today(), 1)))

Local $TmpDate = _DateAdd('D', -288, _NowCalcDate())
Local $aTmpDate = StringSplit($TmpDate, '/', 2)
ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateAdd (Heute -288 Tage) mit Ausgabe formatiert benutzerdefiniert', _
	StringFormat('KW %02d %d %s, %02d.', _WeekNumberISO($aTmpDate[0],$aTmpDate[1],$aTmpDate[2]), $aTmpDate[0], $aMonShort[$aTmpDate[1]], $aTmpDate[2]), _
	_Dt_Add('D', -288, _Dt_Today(), '"KW "ww yyyy MMM, d.')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateDiff (Tage): Heute - 2018/02/01', _
	_DateDiff('D', _NowCalcDate(), '2018/02/01'), _
	_Dt_Diff('D', _Dt_Today(), '2018/02/01')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'DateDiff (Monate): Heute - 2019/02/01', _
	_DateDiff('M', _NowCalcDate(), '2019/02/01'), _
	_Dt_Diff('M', _Dt_Today(), '2019/02/01')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum (Heute) als Wochentagsname (kurz)', _
	$aDayNameShort[_DateToDayOfWeekISO(@YEAR, @MON, @MDAY)], _
	_Dt_DayName(_Dt_Today(), 0)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum (Heute) als Wochentagsname (lang)', _
	$aDayNameLong[_DateToDayOfWeekISO(@YEAR, @MON, @MDAY)], _
	_Dt_DayName(_Dt_Today(), 1)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum (Heute) als Wochentagsnummer (1..7)', _
	_DateToDayOfWeekISO(@YEAR, @MON, @MDAY), _
	_Dt_DayNumWeek(_Dt_Today())))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Wochentagsnummer [' & _Dt_DayNumWeek(_Dt_Today()) & '] als Tagesname (kurz)', _
	$aDayNameShort[_DateToDayOfWeekISO(@YEAR, @MON, @MDAY)], _
	_Dt_DayNumOfWeekToName(_Dt_DayNumWeek(_Dt_Today()), 0)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Wochentagsnummer [' & _Dt_DayNumWeek(_Dt_Today()) & '] als Tagesname (lang)', _
	$aDayNameLong[_DateToDayOfWeekISO(@YEAR, @MON, @MDAY)], _
	_Dt_DayNumOfWeekToName(_Dt_DayNumWeek(_Dt_Today()), 1)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Jahr od. Datum auf Schaltjahr prüfen (2019)', _
	_DateIsLeapYear(2019), _
	_Dt_IsLeapYear(2019)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Jahr od. Datum auf Schaltjahr prüfen (' & @YEAR & ')', _
	_DateIsLeapYear(@YEAR), _
	_Dt_IsLeapYear(@YEAR)))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum auf Gültigkeit prüfen (falsch -> 0; gültig -> YYYY/MM/DD) für: "2018/02/29"', _
	_DateIsValid('2018/02/29'), _
	_Dt_IsValid('2018/02/29')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum auf Gültigkeit prüfen (falsch -> 0; gültig -> YYYY/MM/DD) für: "18/12/12"', _
	_DateIsValid('2018/12/12'), _
	_Dt_IsValid('18/12/12')))

ConsoleWrite(StringFormat('%-90s%-40s%-40s\n', 'Datum in lokalem Kurzformat als Calc-Datum wiedergeben (YYYY/MM/DD) für: "12.05.2019"', _
	'-- none function --', _
	_Dt_ShortLocaleToCalcDate('12.05.2019')))

ConsoleWrite(@CRLF &'Wochennummer und zugehöriges Kalenderjahr (kann abweichen vom Jahr des Datums!) -- nur Dt.au3 --' & @CRLF)
Local $aD[6][2] = [ _
['2016/01/01','2016/12/31'], _
['2017/01/01','2017/12/31'], _
['2018/01/01','2018/12/31'], _
['2019/01/01','2019/12/31'], _
['2020/01/01','2020/12/31']]
ConsoleWrite(StringFormat('%-13s%-9s%-13s%-3s', 'Datum', 'KW-Jahr', 'Datum', 'KW-Jahr') & @CRLF)
For $i = 0 To 4
	ConsoleWrite(StringFormat('%10s   %02d-%02d    %10s   %02d-%02d\n', $aD[$i][0], _Dt_WeekNum($aD[$i][0],True)[0], _Dt_WeekNum($aD[$i][0],True)[1], _
	                                                          $aD[$i][1], _Dt_WeekNum($aD[$i][1],True)[0], _Dt_WeekNum($aD[$i][1],True)[1]))
Next


;===============================================================================
; Function Name....: _DateToDayNameLocale
; Description......: Gibt zu einem Datum den Wochentag (Lang-/Kurzform) gemäß den lokalen
; .................: Einstellungen (Ländereinstellung) zurück
; Parameter(s).....: $_vDateYear   Jahr oder String mit Datum der Formen:
; .................:               "(T)T.(M)M.(JJ)JJ", "YYYY/(M)M/(D)D"
; .................:               Standard= -1 aktuelles Tagesdatum
; .................: $_vLongMonth  Monat oder wenn 1.Param=Datumsstring: Lang-/Kurzform (1/0)
; .................: $_iDay        Tag (nur für Einzelwertübergabe, sonst 0)
; .................: $_iLong       Lang-/Kurzform (1/0) des Tagesnamens, Standard=1
; Return Value(s)..: Erfolg        Name Wochentag (lang od. kurz) nach lokalen Einstellungen
; .................: Fehler        Leerstring  set @error = 1 Datumsstring fehlerhaft
; .................:                                      = 2 Datum ungültig
; Author(s)........: BugFix
;===============================================================================
Func _DateToDayNameLocale($_vDateYear=-1, $_vLongMonth=1, $_iDay=0, $_iLong=1)
	Local $iDay = @MDAY, $iMon = @MON, $iYear = @YEAR, $aDate, $tmp
	If $_iDay <> 0 Then
		$iDay = $_iDay
		$iMon = $_vLongMonth
		$iYear = $_vDateYear
	Else
		$_iLong = $_vLongMonth
		If $_vDateYear <> -1 Then
			If StringInStr($_vDateYear, '.') Then
				$aDate = StringRegExp($_vDateYear, '(\d{1,2})\.(\d{1,2})\.(\d{2,4})', 3)
				If @error Then Return SetError(1,0,'')
				If StringLen($aDate[2]) = 2 And $aDate[2] > StringRight(@YEAR, 2) Then
					$aDate[2] = '19' & $aDate[2]
				Else
					$aDate[2] = '20' & $aDate[2]
				EndIf
				$iDay = $aDate[0]
				$iMon = $aDate[1]
				$iYear = $aDate[2]
			EndIf
			If StringInStr($_vDateYear, '/') Then
				$aDate = StringRegExp($_vDateYear, '(\d{4})/(\d{1,2})/(\d{1,2})', 3)
				If @error Then Return SetError(1,0,'')
				$iDay = $aDate[2]
				$iMon = $aDate[1]
				$iYear = $aDate[0]
			EndIf
		EndIf
	EndIf
	If $_iLong <> 0 Then $_iLong = 1
    Local $tSYSTEMTIME = DllStructCreate("struct; word Year;word Month;word Dow;word Day;word Hour;word Minute;word Second;word MSeconds; endstruct")
    $tSYSTEMTIME.Year = $iYear
    $tSYSTEMTIME.Month = $iMon
    $tSYSTEMTIME.Day = $iDay
	Local $tFormat = DllStructCreate('wchar[64];'), $tDateStr = DllStructCreate('wchar[64];')
	DllStructSetData($tFormat, 1, "ddd','dddd")
    Local $ret = DllCall("kernel32", "long", "GetDateFormatW", "long", 0, "long", 0, _
        "ptr", DllStructGetPtr($tSYSTEMTIME), "ptr", DllStructGetPtr($tFormat), "ptr", DllStructGetPtr($tDateStr), "long", 64)
	Local $sDayName = DllStructGetData($tDateStr, 1)
	If $sDayName = '' Then Return SetError(2,0,'')
	Local $aDayName = StringSplit($sDayName, ',', 2)
	Return $aDayName[$_iLong]
EndFunc  ;==>_DateToDayNameLocale


