#include <array.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Global $_StartRadius = 50
Global $_Pi = ACos(-1)



$timerinit = TimerInit()
$hArea = _sharing2D_CreateArea(0,0,800,800)
For $i = 1 To 25
	_sharing2D_AddItem($hArea,Random(40,60,1),Random(80,100,1),20 )
Next
_ArrayDisplay ($hArea,'fertig in: '&Round(TimerDiff($timerinit)/1000,4)&' sec.' )





; #FUNCTION# ====================================================================================================================
; Name...........:  _sharing2D_AddItem()
; Description ...: 	Verteilt in die zuvor erstellte Area ein Rechteck. Hierbei werden die Rechtecke Radial um den Mittelpunkt verteilt.
; Parameters ....: 	$_Sharing2D_Array		- Das Array, dem das neue Rechteck hinzugefügt wird
;					$_ItemWidth				- Breite des hinzuzufügenden Rechtecks
;					$_ItemHeight			- Höhe des hinzuzufügenden Rechtecks
;					$_Safety_Zone			- Sicherheitsabstand zu den anderen Rechtecken
;					[$_Grad_Step]			- alle wieviel Grad versucht werden soll ein Rechteck zu verteilen
;											  beinflusst extrem die Geschwindigkeit ( Richtwert 10 )
;					[$_Radius_Step]			- um wieviel sich der Verteilradius pro 360° vergrößert
;											  beinflusst extrem die Geschwindigkeit ( Richtwert 10 )
;
; Return values .: 	Erfolg              	- fügt der Area ein Rechteck hinzu enthalten im Array
;                  	Fehler              	- @error 1	=	kein Array zum hinzufügen angegeben
;											- @error 2	=	Werte keine Zahlen oder kleiner Null
; Author ........: 	chrisatack ( autoit.de )
; Remarks .......: 	Durchschnittliche Zeit 1,8 sec bei 25 Rechtecken Area 800 x 800
; ===============================================================================================================================
Func _sharing2D_AddItem( ByRef $_Sharing2D_Array,$_ItemWidth,$_ItemHeight,$_Safety_Zone,$_Grad_Step = 10,$_Radius_Step = 10 )
	If Not IsArray($_Sharing2D_Array)Then
		SetError (1)
		Return 0
	EndIf
	If  Not IsNumber($_ItemWidth) Or _
		$_ItemWidth < 0 Or _
		Not IsNumber($_ItemHeight) Or _
		$_ItemHeight < 0 Or _
		Not IsNumber($_Safety_Zone) Or _
		$_Safety_Zone < 0 Then
		SetError (2)
		Return 0
	EndIf
	If UBound ( $_Sharing2D_Array ) < 2 Then
		_sharing2D_Array2DAdd($_Sharing2D_Array,Round(($_Sharing2D_Array[0][2]/2)-($_ItemWidth/2),0)&'|'& _
									  Round(($_Sharing2D_Array[0][3]/2)-($_ItemHeight/2),0)&'|'& _
									  Round($_ItemWidth,0)&'|'& _
									  Round($_ItemHeight,0)&'|'& _
									  Round($_Safety_Zone,0) )
	Else
		While 1
			For $_Grad = 0 To 360 Step $_Grad_Step
				$_KreisX = Round(($_Sharing2D_Array[0][2]/2)+Sin($_Grad*($_Pi/180))*$_StartRadius,0)
				$_KreisY = Round(($_Sharing2D_Array[0][3]/2)+Cos($_Grad*($_Pi/180))*$_StartRadius,0)
				Local $_Collison = False
				For $i = 1 To UBound ( $_Sharing2D_Array ) -1
					If _sharing2D_RectCollision(	$_Sharing2D_Array[$i][0],$_Sharing2D_Array[$i][1], _
										$_Sharing2D_Array[$i][0]+$_Sharing2D_Array[$i][2]+$_Sharing2D_Array[$i][4],$_Sharing2D_Array[$i][1]+$_Sharing2D_Array[$i][3]+$_Sharing2D_Array[$i][4], _
										$_KreisX-($_ItemWidth/2)-$_Safety_Zone,$_KreisY-($_ItemHeight/2)-$_Safety_Zone, _
										$_KreisX-($_ItemWidth/2)+$_ItemWidth+($_Safety_Zone*2), $_KreisY-($_ItemHeight/2)+$_ItemHeight+$_Safety_Zone*2 ) Then
						$_Collison = True
					EndIf
				Next
				If Not $_Collison Then
					_sharing2D_Array2DAdd($_Sharing2D_Array,	Round($_KreisX-($_ItemWidth/2),0)&'|'& _
													Round($_KreisY-($_ItemHeight/2),0)&'|'& _
													Round($_ItemWidth,0)&'|'& _
													Round($_ItemHeight,0)&'|'& _
													Round($_Safety_Zone,0) )
					Return
				EndIf
			Next
			$_StartRadius += $_Radius_Step
		WEnd
	EndIf
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........:  _sharing2D_CreateArea()
; Description ...: 	Erstellt eine Area in der die Rechtecke verteilt werden können
; Parameters ....: 	$_Xin					- X
;					$_Yin					- Y
;					$_Width					- Breite
;					$_Height				- Höhe
;
; Return values .: 	Erfolg              	- Erstellt eine Area und gibt ein Array zurück
;                  	Fehler              	- @error 1	=	Werte keine Zahlen oder kleiner Null
; Author ........: 	chrisatack ( autoit.de )
; Remarks .......:
; ===============================================================================================================================
Func _sharing2D_CreateArea($_Xin,$_Yin,$_Width,$_Height)
	If  Not IsNumber($_Xin) Or _
		$_Xin < 0 Or _
		Not IsNumber($_Yin) Or _
		$_Yin < 0 Or _
		Not IsNumber($_Width) Or _
		$_Width < 0 Or _
		Not IsNumber($_Height) Or _
		$_Height < 0 Then
		SetError (1)
		Return 0
	EndIf
	Global $_Sharing2D_Array[1][5]
	$_Sharing2D_Array[0][0] = $_Xin
	$_Sharing2D_Array[0][1] = $_Yin
	$_Sharing2D_Array[0][2] = $_Width
	$_Sharing2D_Array[0][3] = $_Height
	Return $_Sharing2D_Array
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........:  _sharing2D_Array2DAdd(ByRef $avArray, $sValue='')
; Description ...: 	Redim Array Size and add an Array element at last position
;					Works with any occurences in 2nd Dimension
;					Works also with 1D-Array
; Parameters ....: 	$avArray	Given Array
;		optional	$sValue		Value of new Element, parts must be seperate with '|'
;
; Return values .: 	Succes      - 1
;					Failure		0 and set @error
;								@error = 1	given array is not array
;								@error = 2	given parts of Element too less/much
; Author ........: 	BugFix  (bugfix@autoit.de)
; Remarks .......:
; ===============================================================================================================================
Func _sharing2D_Array2DAdd(ByRef $avArray, $sValue='')
	If ( Not IsArray($avArray) ) Then
		SetError(1)
		Return 0
	EndIf
	Local $i
	Local $UBound2nd = UBound($avArray,2)
	If @error = 2 Then
		ReDim $avArray[UBound($avArray)+1]
		$avArray[UBound($avArray)-1] = $sValue
	Else
		Local $arValue
		ReDim $avArray[UBound($avArray)+1][$UBound2nd]
		If $sValue = '' Then
			For $i = 0 To $UBound2nd-2
				$sValue &= '|'
			Next
		EndIf
		$arValue = StringSplit($sValue, '|')
		If $arValue[0] <> $UBound2nd Then
			SetError(2)
			Return 0
		EndIf
		For $i = 0 To $UBound2nd-1
			$avArray[UBound($avArray)-1][$i] = $arValue[$i+1]
		Next
	EndIf
	Return -1
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........:  _sharing2D_CreateArea()
; Description ...: 	Überprüft ob sich 2 Flächen in einer Ebene überlappen
; Parameters ....: 	$Rect1X1					- X
;					$Rect1Y1					- Y
;					$Rect1X2					- Breite
;					$Rect1Y2					- Höhe
;					$Rect2X1					- X
;					$Rect2Y1					- Y
;					$Rect2X2					- Breite
;					$Rect2Y2					- Höhe
;
;   1X1/1Y1 -------
;	  |            |
;	  |            |
;	  |            |
;	  |   2X1/2Y1--|------
;	  |      |     |	  |
;	  |      |     |	  |
;	   --------1X2/1Y2	  |
;			 |			  |
;			 |			  |
;			 |			  |
;			  ---------2X1/2Y2
;
; Return values .: 	Erfolg              	- gibt False für Überlappung und True für keine Überlappung zurück
; Author ........: 	Prog@ndy ( autoit.de )
; Remarks .......:
; ===============================================================================================================================
Func _sharing2D_RectCollision($Rect1X1,$Rect1Y1,$Rect1X2,$Rect1Y2, $Rect2X1, $Rect2Y1, $Rect2X2, $Rect2Y2)
    Local $tagRECT = "long;long;long;long"
    Local $1 = DllStructCreate($tagRECT)
    Local $2 = DllStructCreate($tagRECT)
    Local $3 = DllStructCreate($tagRECT)
    DllStructSetData($1,1,$Rect1X1)
    DllStructSetData($1,2,$Rect1Y1)
    DllStructSetData($1,3,$Rect1X2)
    DllStructSetData($1,4,$Rect1Y2)
    DllStructSetData($2,1,$Rect2X1)
    DllStructSetData($2,2,$Rect2Y1)
    DllStructSetData($2,3,$Rect2X2)
    DllStructSetData($2,4,$Rect2Y2)
    Local $r = DllCall("User32.dll", "int", "IntersectRect", "ptr", DllStructGetPtr($3), "ptr", DllStructGetPtr($1), "ptr", DllStructGetPtr($2))
    If @error Then Return SetError(1,0,0)
    Return $r[0]<>0
EndFunc