#include <array.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
Global $_Sharing2D_Array[1][5]
Global $_Radius = 50
Global $pi = 3.14159265358979
Global $_Last_Grad = 0


$hArea = _sharing2D_SetArea(0,0,800,800)

$_hDebugGui = GUICreate("DEBUGMODE", $_Sharing2D_Array[0][2],$_Sharing2D_Array[0][3] ,0,0)
GUISetState(@SW_SHOW,$_hDebugGui)

$_hGraphic = _GDIPlus_GraphicsCreateFromHWND($_hDebugGui)
$_hBMP = _GDIPlus_BitmapCreateFromGraphics ($_Sharing2D_Array[0][2],$_Sharing2D_Array[0][3], $_hGraphic )
$_hBuffer = _GDIPlus_ImageGetGraphicsContext($_hBMP)
_GDIPlus_GraphicsSetSmoothingMode($_hGraphic,2 )
_GDIPlus_GraphicsClear($_hBuffer,0xFFFFFFFF)

;Rahmen
$_hPen_Border = _GDIPlus_PenCreate ( 0xFF00FF00,4 )
_GDIPlus_GraphicsDrawRect($_hBuffer, $_Sharing2D_Array[0][0],$_Sharing2D_Array[0][1],$_Sharing2D_Array[0][2],$_Sharing2D_Array[0][3],$_hPen_Border )

; Mittelpunkt
$_hPen_Middle = _GDIPlus_PenCreate ( 0xFFFF0000,1 )
_GDIPlus_GraphicsDrawLine($_hBuffer, ($_Sharing2D_Array[0][2]/2)-5,$_Sharing2D_Array[0][3]/2,($_Sharing2D_Array[0][2]/2)+5,$_Sharing2D_Array[0][3]/2,$_hPen_Middle )
_GDIPlus_GraphicsDrawLine($_hBuffer, ($_Sharing2D_Array[0][2]/2),($_Sharing2D_Array[0][3]/2)-5,($_Sharing2D_Array[0][2]/2),($_Sharing2D_Array[0][3]/2)+5,$_hPen_Middle )

; Rechtecke
$_hPen_Rect = _GDIPlus_PenCreate ( 0xFF0000FF,1 )
$_hBrush_Rect = _GDIPlus_BrushCreateSolid('0x'&Hex(40, 2)&'0000FF' )
$_hPen_SaftyZone = _GDIPlus_PenCreate ( 0xFFFF8C00,1 )

;Kreis
$_hPen_Arc = _GDIPlus_PenCreate ( 0xFF8B0000,1 )

; zeichnen
_GDIPlus_GraphicsDrawImageRect($_hGraphic, $_hBMP, 0, 0,$_Sharing2D_Array[0][2], $_Sharing2D_Array[0][3])


For $i = 1 To 20
	_sharing2D_AddItem($hArea,Random(40,60,1),Random(80,100,1),20 )
Next



While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd
;-----------------------------------------------------------------------------------------------


Func _sharing2D_AddItem( ByRef $_Sharing2D_Array,$_ItemWidth,$_ItemHeight,$_Safety_Zone )
	Local $_Step_Grad = 10
	Local $_Step_Radius = 10
	If UBound ( $_Sharing2D_Array ) < 2 Then
		_Array2DAdd($_Sharing2D_Array,Round(($_Sharing2D_Array[0][2]/2)-($_ItemWidth/2),0)&'|'& _
									  Round(($_Sharing2D_Array[0][3]/2)-($_ItemHeight/2),0)&'|'& _
									  Round($_ItemWidth,0)&'|'& _
									  Round($_ItemHeight,0)&'|'& _
									  Round($_Safety_Zone,0) )
	Else
		While 1

			For $_Grad = 0 To 360 Step $_Step_Grad
				$_KreisX = Round(($_Sharing2D_Array[0][2]/2)+Sin($_Grad*($pi/180))*$_Radius,0)
				$_KreisY = Round(($_Sharing2D_Array[0][3]/2)+Cos($_Grad*($pi/180))*$_Radius,0)
				_sharing2D_DEBUG($_Sharing2D_Array)
				_GDIPlus_GraphicsDrawArc( $_hBuffer,$_Sharing2D_Array[0][2]/2-$_Radius,$_Sharing2D_Array[0][3]/2-$_Radius,$_Radius*2,$_Radius*2,0,360,$_hPen_Arc )
				_GDIPlus_GraphicsDrawLine($_hBuffer,$_Sharing2D_Array[0][2]/2,$_Sharing2D_Array[0][3]/2,$_KreisX,$_KreisY )
				_sharing2D_Draw_Item($_KreisX-($_ItemWidth/2), _
									 $_KreisY-($_ItemHeight/2), _
									 $_ItemWidth, _
									 $_ItemHeight, _
									 $_Safety_Zone )
				_GDIPlus_GraphicsDrawImageRect($_hGraphic, $_hBMP, 0, 0,$_Sharing2D_Array[0][2], $_Sharing2D_Array[0][3])
				;======================================================
				; RecCollisions Punkte...
				;======================================================
				; Gibt FALSE zurück wenn die Rechtecke sich berühren
				;
				;   1X1/1Y1 -------
				;	  |            |
				;	  |            |
				;	  |            |
				;	  |   2X1/2Y1--|------
				;	  |      |     |	  |
				;	  |      |     |	  |
				;	   --------1X2/1Y2	  |
				;			 |			  |
				;			 |			  |
				;			 |			  |
				;			  ---------2X1/2Y2
				;
				Local $_Collison = False
				For $i = 1 To UBound ( $_Sharing2D_Array ) -1
					If _RectCollision(	$_Sharing2D_Array[$i][0],$_Sharing2D_Array[$i][1], _ ;1X1/1Y1
										$_Sharing2D_Array[$i][0]+$_Sharing2D_Array[$i][2]+$_Sharing2D_Array[$i][4],$_Sharing2D_Array[$i][1]+$_Sharing2D_Array[$i][3]+$_Sharing2D_Array[$i][4], _ ;1X2/1Y2
										$_KreisX-($_ItemWidth/2)-$_Safety_Zone,$_KreisY-($_ItemHeight/2)-$_Safety_Zone, _ ;2X1/2Y1
										$_KreisX-($_ItemWidth/2)+$_ItemWidth+($_Safety_Zone*2), $_KreisY-($_ItemHeight/2)+$_ItemHeight+$_Safety_Zone*2 ) Then
						$_Collison = True
					EndIf
				Next
				If Not $_Collison Then
					_Array2DAdd($_Sharing2D_Array,	$_KreisX-($_ItemWidth/2)&'|'& _
													$_KreisY-($_ItemHeight/2)&'|'& _
													Round($_ItemWidth,0)&'|'& _
													Round($_ItemHeight,0)&'|'& _
													Round($_Safety_Zone,0) )
;~ 					_ArrayDisplay ($_Sharing2D_Array )
					Return
				EndIf
			Next
			$_Radius += $_Step_Radius
		WEnd
	EndIf
EndFunc


Func _sharing2D_SetArea($Xin,$Yin,$Width,$Height)
	$_Sharing2D_Array[0][0] = $Xin
	$_Sharing2D_Array[0][1] = $Yin
	$_Sharing2D_Array[0][2] = $Width
	$_Sharing2D_Array[0][3] = $Height
	$_Sharing2D_Array[0][4] = 0
	Return $_Sharing2D_Array
EndFunc

Func _sharing2D_DEBUG($_Sharing2D_Array)
	_GDIPlus_GraphicsClear($_hBuffer,0xFFFFFFFF)
	For $i = 1 To UBound ( $_Sharing2D_Array )-1
		_sharing2D_Draw_Item($_Sharing2D_Array[$i][0], _
							 $_Sharing2D_Array[$i][1], _
							 $_Sharing2D_Array[$i][2], _
							 $_Sharing2D_Array[$i][3], _
							 $_Sharing2D_Array[$i][4])
	Next
	_GDIPlus_GraphicsDrawRect($_hBuffer, $_Sharing2D_Array[0][0],$_Sharing2D_Array[0][1],$_Sharing2D_Array[0][2],$_Sharing2D_Array[0][3],$_hPen_Border )
	_GDIPlus_GraphicsDrawLine($_hBuffer, ($_Sharing2D_Array[0][2]/2)-5,$_Sharing2D_Array[0][3]/2,($_Sharing2D_Array[0][2]/2)+5,$_Sharing2D_Array[0][3]/2,$_hPen_Middle )
	_GDIPlus_GraphicsDrawLine($_hBuffer, ($_Sharing2D_Array[0][2]/2),($_Sharing2D_Array[0][3]/2)-5,($_Sharing2D_Array[0][2]/2),($_Sharing2D_Array[0][3]/2)+5,$_hPen_Middle )
EndFunc

Func _sharing2D_Draw_Item($Draw_X,$Draw_Y,$Draw_Width,$Draw_Height,$Draw_SafeZone)
	_GDIPlus_GraphicsDrawRect($_hBuffer,$Draw_X-$Draw_SafeZone, _
										$Draw_Y-$Draw_SafeZone, _
										$Draw_Width+$Draw_SafeZone*2, _
										$Draw_Height+$Draw_SafeZone*2, _
										$_hPen_SaftyZone )
	_GDIPlus_GraphicsFillRect($_hBuffer,$Draw_X, _
										$Draw_Y, _
										$Draw_Width, _
										$Draw_Height, _
										$_hBrush_Rect )
	_GDIPlus_GraphicsDrawRect($_hBuffer,$Draw_X, _
										$Draw_Y, _
										$Draw_Width, _
										$Draw_Height, _
										$_hPen_Rect )
EndFunc

Func _Array2DAdd(ByRef $avArray, $sValue='')
	If ( Not IsArray($avArray) ) Then
		SetError(1)
		Return 0
	EndIf
	Local $i
	Local $UBound2nd = UBound($avArray,2)
	If @error = 2 Then
		ReDim $avArray[UBound($avArray)+1]
		$avArray[UBound($avArray)-1] = $sValue
	Else
		Local $arValue
		ReDim $avArray[UBound($avArray)+1][$UBound2nd]
		If $sValue = '' Then
			For $i = 0 To $UBound2nd-2
				$sValue &= '|'
			Next
		EndIf
		$arValue = StringSplit($sValue, '|')
		If $arValue[0] <> $UBound2nd Then
			SetError(2)
			Return 0
		EndIf
		For $i = 0 To $UBound2nd-1
			$avArray[UBound($avArray)-1][$i] = $arValue[$i+1]
		Next
	EndIf
	Return -1
EndFunc ;==>_Array2DAdd

Func _RectCollision($Rect1X1,$Rect1Y1,$Rect1X2,$Rect1Y2, $Rect2X1, $Rect2Y1, $Rect2X2, $Rect2Y2)
    ; Prog@ndy
    Local $tagRECT = "long;long;long;long"
    Local $1 = DllStructCreate($tagRECT)
    Local $2 = DllStructCreate($tagRECT)
    Local $3 = DllStructCreate($tagRECT)
    DllStructSetData($1,1,$Rect1X1)
    DllStructSetData($1,2,$Rect1Y1)
    DllStructSetData($1,3,$Rect1X2)
    DllStructSetData($1,4,$Rect1Y2)
    DllStructSetData($2,1,$Rect2X1)
    DllStructSetData($2,2,$Rect2Y1)
    DllStructSetData($2,3,$Rect2X2)
    DllStructSetData($2,4,$Rect2Y2)
    Local $r = DllCall("User32.dll", "int", "IntersectRect", "ptr", DllStructGetPtr($3), "ptr", DllStructGetPtr($1), "ptr", DllStructGetPtr($2))
    If @error Then Return SetError(1,0,0)
    Return $r[0]<>0
EndFunc