;Idea taken from http://js1k.com/demo/213
;Ported to AutoIt by UEZ 2010
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/sf /sv /om /cs=0 /cn=0
#AutoIt3Wrapper_Run_After=del /f /q "Twister_Obfuscated.au3"
#AutoIt3Wrapper_Run_After=upx.exe --ultra-brute "%out%"
;~ #AutoIt3Wrapper_Run_After=upx.exe --best "%out%"

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include "QuickDraw.au3"
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Local $hWnd, $hGraphic, $hBitmap, $hBackbuffer, $hBrush
Local $hFormat, $hFamily, $hFont, $tLayout, $aInfo, $hBrush_Font
Local $fps = 0, $fps_maintimer, $fps_timer, $fps_diff

Local $width = 80, $height = 250
Local $gui_text = "Twister"
Local $pi = ACos(-1)

$hWnd = _QuickDraw_Enable($gui_text, $width, $height, 0, 0, 0)
Local $ptrFont = _QuickDraw_CreateFont("Arial")
GUISetState()


Local $pi2 = 2 * $pi
Local $STEPS = 15
Local $iteration = 0
Local $yMin[$height +  1], $yMax[$height + 1]
Local $i, $min, $max, $previousX, $twist, $step, $angle, $radius, $x, $r

For $i = 0 To $height - 1
	$yMin[$i] = $width
	$yMax[$i] = 0
Next

Local $aSTEPS[$STEPS + 1]
For $i = 0 To $STEPS
	$aSTEPS[$i] = $pi * $i / $STEPS
Next
Local $aRadius[$STEPS + 1]
For $i = 0 To $STEPS
	$aRadius[$i] = Cos($aSTEPS[$i])
	$aRadius[$i] = (0x000001 - 0.4 * $aRadius[$i] * $aRadius[$i])
Next
Local $aTwist[$height]
For $i = 0 To $height - 1
	$aTwist[$i] = $i / $height
Next


GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

$fps_maintimer = TimerInit()
Do
	$fps_timer = TimerInit()

	_QuickDraw_ClearBuffer(0xFF000000)
	_QuickDraw_Text($width - 35, 8, "FPS: " & StringFormat("%.2f", $fps), 10, $ptrFont, 2048, 0xFF7080F0)
	$iteration += 0.05
	For $y = 0 To $height - 1 Step 4
;~ 		$min = $width
;~ 		$max = 0
;~ 		$previousX = $width
		$twist = $iteration + 0x00000A * Cos($iteration) * $aTwist[$y]
		For $step = 0x000000 To $STEPS
			$angle = $aSTEPS[$step]
			$radius = $aRadius[$step]
			$x = ($width + $width * Cos($angle + $twist) * $radius) * 0.5
			If $previousX < $x Then
				$r = 0x000000FF * $radius
				If Mod($step, 3) Then
					Line($previousX, $x, $y, $r, $r)
				Else
					Line($previousX, $x, $y, $r)
				EndIf
			EndIf
			$previousX = $x
			If $x < $min Then $min = $x
			If $x > $max Then $max = $x
		Next
	Next
	_QuickDraw_SwapBuffers()

	$fps_diff = TimerDiff($fps_timer)
	If TimerDiff($fps_maintimer) > 999 Then ;calculate FPS
		$fps = Round(1000 / $fps_diff, 2)
		$fps_maintimer = TimerInit()
	EndIf
;~ 	WinSetTitle($hWnd, "", $gui_text & "   /   FPS: " & StringFormat("%.2f", $fps))
Until Not _QuickDraw_Running()

Func Line($x1, $x2, $y, $r = 0, $gb = 0)
	Local $z = 0, $color
	While $x1 < $x2
		If $z < 3 Then
			$color = 0xFF000000
		Else
			$color = "0xFF" & Hex($r, 2) & Hex($gb, 2) & Hex($gb, 2)
		EndIf
		_QuickDraw_Point($x1, $y, $color)
		$z += 1
		$x1 += 1
	WEnd
EndFunc

Func _Exit()
	_QuickDraw_FreeFont($ptrFont)
	_QuickDraw_Disable()
	GUIDelete($hWnd)
    Exit
EndFunc   ;==>_Exit