#include <GDIP.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

HotKeySet("{ESC}", "_Exit")

Opt("GUIOnEventMode", 1)

_GDIPlus_Startup()

Global $aChar = _CreateCharArray("GDI+ TEXT MOUSETRAIL...", 30)

Global $iWidth = @DesktopWidth
Global $iHeight = @DesktopHeight

Global $hGui = GUICreate("Test", $iWidth, $iHeight, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT, $WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
GUISetBkColor(0xABCDEF)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState()
_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF, 255, 0x1)

Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmpBuffer = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphics)
Global $hGfxBuffer = _GDIPlus_ImageGetGraphicsContext($hBmpBuffer)
_GDIPlus_GraphicsSetSmoothingMode($hGfxBuffer, 2)
_GDIPlus_GraphicsClear($hGfxBuffer, 0xFFABCDEF)

Global $hPen = _GDIPlus_PenCreate(0xFF45FF45, 1)
Global $hBrush = _GDIPlus_BrushCreateSolid(0xFF258825)

GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUIRegisterMsg($WM_ERASEBKGND, "WM_ERASEBKGND")

While 1
	_Draw()
	Sleep(10)
WEnd



Func _Draw()
	Local $aPos = MouseGetPos()
	_GDIPlus_GraphicsClear($hGfxBuffer, 0xFFABCDEF)

	Local $hPath = _GDIPlus_PathCreate(1)

	$aChar[1][0] -= ($aChar[1][0] - ($aPos[0] + $aChar[0][1])) / 4
	$aChar[1][1] -= ($aChar[1][1] - $aPos[1]) / 4
	$aChar[1][2] -= ($aChar[1][0] - ($aPos[0] + $aChar[0][1])) / 50
	$aChar[1][3] -= ($aChar[1][1] - $aPos[1]) / 50
	$aChar[1][0] += $aChar[1][2]
	$aChar[1][1] += $aChar[1][3]
	For $i = 2 To $aChar[0][0]
		$aChar[$i][0] -= ($aChar[$i][0] - ($aChar[$i - 1][0] + $aChar[0][1])) / 4
		$aChar[$i][1] -= ($aChar[$i][1] - $aChar[$i - 1][1]) / 4
		$aChar[$i][2] -= ($aChar[$i][0] - ($aChar[$i - 1][0] + $aChar[0][1])) / (50 + ($i - 1) * 5)
		$aChar[$i][3] -= ($aChar[$i][1] - $aChar[$i - 1][1]) / (50 + ($i - 1) * 5)
		$aChar[$i][0] += $aChar[$i][2]
		$aChar[$i][1] += $aChar[$i][3]
	Next

	Local $hPathClone
	Local $hMatrix = _GDIPlus_MatrixCreate()

	For $i = 1 To $aChar[0][0]
		$hPathClone = _GDIPlus_PathClone($aChar[$i][4])
		_GDIPlus_MatrixSetElements($hMatrix, 1, 0, 0, 1, 0, 0)
		_GDIPlus_MatrixTranslate($hMatrix, $aChar[$i][0], $aChar[$i][1])
		_GDIPlus_PathTransform($hPathClone, $hMatrix)

		_GDIPlus_PathAddPath($hPath, $hPathClone, False)
		_GDIPlus_PathDispose($hPathClone)
	Next

	_GDIPlus_GraphicsFillPath($hGfxBuffer, $hPath, $hBrush)
	_GDIPlus_GraphicsDrawPath($hGfxBuffer, $hPath, $hPen)
	_GDIPlus_MatrixDispose($hMatrix)
	_GDIPlus_PathDispose($hPath)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)
EndFunc   ;==>_Draw




Func WM_PAINT($hWnd, $uMsgm, $wParam, $lParam)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT

Func WM_ERASEBKGND($hWnd, $uMsgm, $wParam, $lParam)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmpBuffer, 0, 0)
	Return True
EndFunc   ;==>WM_ERASEBKGND

Func _CreateCharArray($sText, $fSize = 10)
	Local $aSplit = StringSplit($sText, "")
	Local $aChar[$aSplit[0] + 1][5]
	$aChar[0][0] = $aSplit[0]
	$aChar[0][1] = $fSize

	Local $hFormat = _GDIPlus_StringFormatCreate()
	Local $hFamily = _GDIPlus_FontFamilyCreate("Courier New")
	Local $tLayout = _GDIPlus_RectFCreate(0, 0, 0, 0)

	Local $aPos = MouseGetPos()
	Local $aBounds
	Local $hMatrix = _GDIPlus_MatrixCreate()

	For $i = 1 To $aChar[0][0]
		$aChar[$i][0] = $aPos[0] + $i * $fSize
		$aChar[$i][1] = $aPos[1]
		$aChar[$i][2] = 0
		$aChar[$i][3] = 0
		$aChar[$i][4] = _GDIPlus_PathCreate(0)
		_GDIPlus_PathAddString($aChar[$i][4], $aSplit[$i], $tLayout, $hFamily, 1, $fSize * 1.4, $hFormat)

		$aBounds = _GDIPlus_PathGetWorldBounds($aChar[$i][4])
		_GDIPlus_MatrixTranslate($hMatrix, -($aBounds[0] + ($aBounds[2] - $aBounds[1]) / 2), 0)
		_GDIPlus_PathTransform($aChar[$i][4], $hMatrix)
		_GDIPlus_MatrixTranslate($hMatrix, ($aBounds[0] + ($aBounds[2] - $aBounds[1]) / 2), 0)

	Next

	_GDIPlus_FontFamilyDispose($hFamily)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_MatrixDispose($hMatrix)

	Return $aChar
EndFunc   ;==>_CreateCharArray


Func _Exit()
	For $i = 1 To $aChar[0][0]
		_GDIPlus_PathDispose($aChar[$i][4])
	Next
	_GDIPlus_PenDispose($hPen)
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGfxBuffer)
	_GDIPlus_BitmapDispose($hBmpBuffer)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_Shutdown()
	Exit
EndFunc   ;==>_Exit