#include <String.au3>
#include <Array.au3>
#include <GUIConstantsEx.au3>
#RequireAdmin
#AutoIt3Wrapper_usex64=N
#AutoIt3Wrapper_Run_Obfuscator=Y
#Obfuscator_Parameters=/sf=1 /sv=1 /om /cs=0 /cn=0
dim $a0="SourceCode Optimierung..."
_Optimierung()
Func _Optimierung()
	$sFile=@ScriptFullPath
	$sCompilerE=@AutoItExe

	; Kompilierung des Sources
	$sCompiler=StringReplace($sCompilerE,"AutoIt3.exe", 'SciTE\AutoIt3Wrapper\AutoIt3Wrapper.exe')
	$sCompile=$sCompiler&' /prod /in "'&$sFile&'"'
	RunWait($sCompile)
	$sFile=StringReplace($sFile, ".au3", "_Obfuscated.au3",0,1)

	; Die Optimierungs-Funktion Suchen und löschen
	$hFile0=FileOpen($sFile,0)
	$sFileTxt=FileRead($hFile0)
	FileClose($hFile0)
	$aTxt=StringSplit($sFileTxt, @CRLF, 1)
	dim $sStart, $sEnde
	for $i = 1 to $aTxt[0]
		if StringInStr($aTxt[$i],$a0,1) then $sStart=$aTxt[$i]&@CRLF
		if StringInStr($aTxt[$i],'"...Ferti'&chr(103)&'!"') then $sEnde=$aTxt[$i]&@CRLF
	Next
	$sFileTxtTmp = _StringBetween($sFileTxt, $sStart, $sEnde, 1)
	$sFileTxt = StringReplace($sFileTxt, $sStart&$sFileTxtTmp[0]&$sEnde, "",0,1)
	$sFileTxt = StringReplace($sFileTxt, '#RequireAdmin'&@CRLF, "",0,1)
	$hFile1=FileOpen($sFile,2)
	FileWrite($hFile1, $sFileTxt)
	FileClose($hFile1)

	; Funktionen Tauschen
	$hFile0=FileOpen($sFile,0)
	$sFileTxt=FileRead($hFile0)
	FileClose($hFile0)
	dim $_afterSrc="", $aArray[4][3]=[ _
		['GUICtrlSetData(', '_SD(', 'Func _SD(ByRef $a,$b)'&@CRLF&'GUICtrlSetData($a,$b)'&@CRLF&'EndFunc'&@CRLF], _
		['StringSplit(', '_SS(', 'Func _SS($a,$b,$c=1)'&@CRLF&'Return StringSplit($a,$b,$c)'&@CRLF&'EndFunc'&@CRLF], _
		['UBound(', '_UB(', 'Func _UB($a,$b=1)'&@CRLF&'Return UBound($a,$b)'&@CRLF&'EndFunc'&@CRLF], _
		['StringMid(', '_SM(', 'Func _SM(byref $a,$b,$c)'&@CRLF&'Return StringMid($a,$b,$c)'&@CRLF&'EndFunc']]
	for $i = 0 to UBound($aArray)-1
		if StringInStr($sFileTxt, $aArray[$i][0]) Then
			$sFileTxt = StringReplace($sFileTxt, $aArray[$i][0], $aArray[$i][1])
		EndIf
		$_afterSrc&=$aArray[$i][2]
	Next
	$sFileTxt=$sFileTxt&$_afterSrc

	; Überflüsse Leerzeichen entfernen
	dim $sFileSizeBefore1=FileGetSize($sFile)
	dim $aArray[30][2]=[[', ', ','], [' =', '='], ['= ', '='], [' &', '&'], ['& ', '&'], [' <', '<'], ['< ', '<'], [' >', '>'], ['> ', '>'], [' +', '+'], _
						['+ ', '+'], [' -', '-'], ['- ', '-'], ['And', 'and'], ['Or', 'or'], ['Then', 'then'], ['To', 'to'], _
						[') and', ')and'], [') or', ')or'], [') then', ')then'], [') to', ')to'], _
						['] and', ']and'], ['] or', ']or'], ['] then', ']then'], ['] to', ']to'], _
						['" and', '"and'], ['" or', '"or'], ['" then', '"then'], ['" to', '"to'], [' '&@CRLF, @CRLF]]
	for $i = 0 to UBound($aArray)-1
		if StringInStr($sFileTxt, $aArray[$i][0], 1) Then
			$sFileTxt = StringReplace($sFileTxt, $aArray[$i][0], $aArray[$i][1])
		EndIf
	Next
	$hFile1=FileOpen($sFile,2)
	FileWrite($hFile1, $sFileTxt)
	FileClose($hFile1)

;~ 	; 15Kb Info schreiben
;~ 	dim $sFileSizeAfter1=FileGetSize($sFile)
;~ 	$hFile0=FileOpen($sFile,0)
;~ 	$sFileTxt=FileRead($hFile0)
;~ 	FileClose($hFile0)
;~ 	$sFileSizeReplacer ='dim $_15Kb = "Now : '&$sFileSizeAfter1&' Bytes - Before: '&$sFileSizeBefore1&' Bytes - '&int($sFileSizeBefore1-$sFileSizeAfter1)&' Bytes Optimiert!"'
;~ 	$sFileTxt = $sFileSizeReplacer&$sFileTxt
;~ 	$hFile1=FileOpen($sFile,2)
;~ 	FileWrite($hFile1, $sFileTxt)
;~ 	FileClose($hFile1)

;~ 	; 15Kb Grösse korrigieren
;~ 	dim $sFileSizeAfter2=FileGetSize($sFile)
;~ 	$hFile0=FileOpen($sFile,0)
;~ 	$sFileTxt=FileRead($hFile0)
;~ 	FileClose($hFile0)
;~ 	$sFileTxt = StringReplace($sFileTxt, int($sFileSizeBefore1-$sFileSizeAfter1)&' Bytes', int($sFileSizeBefore1-$sFileSizeAfter2)&' Bytes',0,1)
;~ 	$hFile1=FileOpen($sFile,2)
;~ 	FileWrite($hFile1, $sFileTxt)
;~ 	FileClose($hFile1)
EndFunc
dim $b0="...Fertig!"

Opt("GUIOnEventMode", 1)
Opt("GUICloseOnESC", 1)

; Standarts
Global $_GelaendeArten[6][3] = [["Wald", "14", 0x008800], ["Wiese", "41", 0x10ff00], ["Wüste", "00", 0xffff00], ["Steppe", "10", 0x88ff00], ["Berge", "05", 0xaa8888], ["Wasser", "50", 0x6666ff]], $_Spielfeld_FelderX=20, $_Spielfeld_FelderY=20, $_Spielfeld_FelderSizeX=40, $_Spielfeld_FelderSizeY=30, $_Spielfeld_StartX=20, $_Spielfeld_StartY=20, $_Spielfeld[20][20], $_Einheiten[20][20], $_Bauwerk[20][20], $_Gelaende[20][20], $_Ressourcen[20][20], $_EnemySet[16][2], $_StueckEinheiten[1][2], $_StueckBauwerke[1][2], $_UnterhaltEinheiten[3], $_UnterhaltBauwerke[3], $__ProductionTime=20000, $__Timer, $_Aktionen=0, $_TotalAktionen=0, $_TotalEinheiten=0, $_TotalBauwerke=0

; Baumenü
Global $_Bauwerke[4][3] = [["Basis", "002020", "010101"], ["Wohnhaus", "000810", "020201"], ["Kaserne", "102010", "050505"], ["Kraftwerk", "202000", "0005-9"]], $_Baumenu_FelderX=4, $_Baumenu_FelderSizeX=80, $_Baumenu_FelderSizeY=30, $_Baumenu_StartX=20, $_Baumenu_StartY=642, $_Baumenu[4]

; Einheitmenü
Global $_Einheit[4][3] = [["Arbeiter", "01020001", "010000"], ["Kundschafter", "03050003", "020000"], ["Soldat", "05100505", "030000"], ["Ingeneur", "10105002", "030101"]], $_Einheit_FelderX=4, $_Einheit_FelderSizeX=80, $_Einheit_FelderSizeY=30, $_Einheit_StartX=20, $_Einheit_StartY=694, $_Einheitmenu[4]

; Inventar
Global $_Ressource[3][2] = [["Nahrung", 30], ["Material", 50], ["Energie", 70]], $_Ressource_FelderSizeX=150, $_Ressource_FelderSizeY=30, $_Ressource_StartX=850, $_Ressource_StartY=20, $_ResView[3]

; Ress Produktion
Global $_RessProdunktion[3] = ["Nahrung", "Material", "Energie"], $_RessProdunktion_FelderSizeX=150, $_RessProdunktion_FelderSizeY=30, $_RessProdunktion_StartX=850, $_RessProdunktion_StartY=135, $_ResProdunktionView[3]

; Auswahl
Global $_Auswahl[7] = ["Name: ", "Nahrung: ", "Material: ", "Energie: ", "Bewegung: ", "Coord X: ", "Coord Y: "], $_Auswahl_FelderSizeX=150, $_Auswahl_FelderSizeY=30, $_Auswahl_StartX=850, $_Auswahl_StartY=250, $_AuswahlView[7], $hMainGui = GUICreate('15K-Strategie', 1024, 768, -1, -1)

; Spielfeld
$SpielfeldGroup = GUICtrlCreateGroup("", $_Spielfeld_StartX-15, $_Spielfeld_StartY-15, $_Spielfeld_FelderSizeX*$_Spielfeld_FelderX+20, $_Spielfeld_FelderSizeY*$_Spielfeld_FelderY+20)
for $iY=0 To 19
	for $iX=0 To 19
		$__Gelaende=Random(0,5,1)
		$_Gelaende[$iX][$iY] = $_GelaendeArten[$__Gelaende][0]
		$_Ressourcen[$iX][$iY] = $_GelaendeArten[$__Gelaende][1]
		$_Spielfeld[$iX][$iY] = GUICtrlCreateLabel("", 15+($iX*40), 17+($iY*30), 40, 30)
		GUICtrlSetBkColor(-1, $_GelaendeArten[$__Gelaende][2])
		GUICtrlSetOnEvent(-1, "_Click_Spielfeld")
	Next
Next

; Baumenü
$BaumenuGroup = GUICtrlCreateGroup("Bauwerke", $_Baumenu_StartX-15, $_Baumenu_StartY-10, $_Baumenu_FelderSizeX*$_Baumenu_FelderX+20, $_Baumenu_FelderSizeY+22)
for $iX=0 To 3
	$_Baumenu[$iX] = GUICtrlCreateLabel($_Bauwerke[$iX][0], $_Baumenu_StartX+($iX*$_Baumenu_FelderSizeX), $_Baumenu_StartY+10, $_Baumenu_FelderSizeX, $_Baumenu_FelderSizeY)
	GUICtrlSetOnEvent(-1, "_Click_Baumenu")
Next

; Einheiten
$BaumenuGroup = GUICtrlCreateGroup("Einheiten", $_Einheit_StartX-15, $_Einheit_StartY-10, $_Einheit_FelderSizeX*$_Einheit_FelderX+20, $_Einheit_FelderSizeY+22)
for $iX=0 To 3
	$_Einheitmenu[$iX] = GUICtrlCreateLabel($_Einheit[$iX][0], $_Einheit_StartX+($iX*$_Einheit_FelderSizeX), $_Einheit_StartY+10, $_Einheit_FelderSizeX, $_Einheit_FelderSizeY)
	GUICtrlSetOnEvent(-1, "_Click_Einheitenmenu")
Next

; Ressourcen
$RessGroup = GUICtrlCreateGroup("Ressourcen", $_Ressource_StartX-15, $_Ressource_StartY-15, $_Ressource_FelderSizeX+20, $_Ressource_FelderSizeY*3+25)
for $iY=0 To 2
	$_ResView[$iY] = GUICtrlCreateLabel($_Ressource[$iY][0]&": "&$_Ressource[$iY][1], $_Ressource_StartX, $_Ressource_StartY+($_Ressource_FelderSizeY*$iY)+8, $_Ressource_FelderSizeX, $_Ressource_FelderSizeY)
Next

; Ress Produnktion
$RessGroup = GUICtrlCreateGroup("Produktion", $_RessProdunktion_StartX-15, $_RessProdunktion_StartY-15, $_RessProdunktion_FelderSizeX+20, $_RessProdunktion_FelderSizeY*3+25)
for $iY=0 To 2
	$_ResProdunktionView[$iY] = GUICtrlCreateLabel($_RessProdunktion[$iY]&": ", $_RessProdunktion_StartX, $_RessProdunktion_StartY+($_RessProdunktion_FelderSizeY*$iY)+8, $_RessProdunktion_FelderSizeX, $_RessProdunktion_FelderSizeY)
Next

; Auswahl
$AuswahlGroup = GUICtrlCreateGroup("Info", $_Auswahl_StartX-15, $_Auswahl_StartY-15, $_Auswahl_FelderSizeX+20, $_Auswahl_FelderSizeY*7+25)
for $iY=0 To 6
	$_AuswahlView[$iY] = GUICtrlCreateLabel($_Auswahl[$iY], $_Auswahl_StartX, $_Auswahl_StartY+($_Auswahl_FelderSizeY*$iY)+8, $_Auswahl_FelderSizeX, $_Auswahl_FelderSizeY)
Next

; Next-Turn
$AuswahlGroup = GUICtrlCreateGroup("Nächste Runde", $_Auswahl_StartX-15, $_Auswahl_StartY+$_Auswahl_FelderSizeY*7+20, $_Auswahl_FelderSizeX+20, 95)
dim $_Progress = GUICtrlCreateProgress($_Auswahl_StartX-5, $_Auswahl_StartY+$_Auswahl_FelderSizeY*7+40, $_Auswahl_FelderSizeX, 20), $_NextTurn = GUICtrlCreateButton("Weiter", $_Auswahl_StartX-5, $_Auswahl_StartY+$_Auswahl_FelderSizeY*7+75, $_Auswahl_FelderSizeX)
GUICtrlSetOnEvent(-1, "_Produktion")


GUISetState(@SW_SHOW, $hMainGui)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GameOver", $hMainGui)
AdlibRegister("_Produktion", $__ProductionTime)
dim $__Timer = TimerInit(), $__StartTimer = TimerInit()

While 1
	$__Diff=TimerDiff($__Timer)
	GUICtrlSetData($_Progress, 100/$__ProductionTime*$__Diff)
	if $_Aktionen > 2 then _Produktion()
	Sleep(9)
WEnd
Func _Click_Spielfeld()
	dim $aInfo = GUIGetCursorInfo($hMainGui), $iX = int(($aInfo[0]-$_Spielfeld_StartX) / $_Spielfeld_FelderSizeX), $iY = int(($aInfo[1]-$_Spielfeld_StartY) / $_Spielfeld_FelderSizeY), $tmp=GUICtrlRead($_AuswahlView[0])
	if $_Einheiten[$iX][$iY] <> "" then
		if StringInStr($tmp, "/",1) Then
			$tmp=StringSplit($tmp, "/ ", 1)
			$tmp=$tmp[2]
		EndIf
		_SetNew($iX,$iY,$tmp)
	elseif StringInStr($tmp,"Versetze:",1) then
		$tmp=StringSplit($tmp, "Versetze: ", 1)
		$tmp=$tmp[2]
		_SetNew($iX,$iY,$tmp)
	Else
		$tmp=StringReplace($tmp, "Name: ", "", 1)
		if _ArraySearch($_GelaendeArten, $tmp) = -1 then _SetNew($iX,$iY,$tmp)
	EndIf
	dim $_SetDataArray[7] = [$_Gelaende[$iX][$iY], StringMid($_Ressourcen[$iX][$iY], 1, 1), StringMid($_Ressourcen[$iX][$iY], 2, 1), "", "", $iX, $iY]
	if $_Bauwerk[$iX][$iY] <> "" then $_SetDataArray[0] &= " / "&$_Bauwerk[$iX][$iY]
	if $_Einheiten[$iX][$iY] <> "" then
		$_SetDataArray[0] &= " / "&$_Einheiten[$iX][$iY]
		$_SetDataArray[4] = StringMid($_Einheit[_ArraySearch($_Einheit, $_Einheiten[$iX][$iY])][1], 7, 2)
	EndIf
	$tmp=GUICtrlRead($_AuswahlView[0])
	$tmp=StringReplace($tmp, "Name: ", "", 1)
	if StringInStr($tmp,"Versetze:",1) then
		$tmp2=StringSplit($tmp, "Versetze: ", 1)
		$tmp2=$tmp2[2]
		dim $_SetDataArray[7] = [$tmp, "", "", "", StringMid($_Einheit[_ArraySearch($_Einheit, $tmp2)][1], 7, 2), $iX, $iY]
	EndIf
		_SetData($_SetDataArray)
EndFunc

Func _Click_Baumenu()
	dim $aInfo = GUIGetCursorInfo($hMainGui), $iX = int(($aInfo[0]-$_Einheit_StartX) / $_Baumenu_FelderSizeX), $iBaumenuNr = $iX, $_SetDataArray[7] = [$_Bauwerke[$iBaumenuNr][0], StringMid($_Bauwerke[$iBaumenuNr][1], 1, 2), StringMid($_Bauwerke[$iBaumenuNr][1], 3, 2), StringMid($_Bauwerke[$iBaumenuNr][1], 5, 2), "", "", ""]
	_SetData($_SetDataArray)
EndFunc

Func _Click_Einheitenmenu()
	dim $aInfo = GUIGetCursorInfo($hMainGui), $iX = int(($aInfo[0]-$_Baumenu_StartX) / $_Einheit_FelderSizeX), $iEinheitmenuNr = $iX
	if ($_Einheit[$iEinheitmenuNr][0] = $_Einheit[0][0] and _ArraySearch($_Bauwerk, $_Bauwerke[0][0]) <> -1) or ($_Einheit[$iEinheitmenuNr][0] = $_Einheit[1][0] and _ArraySearch($_Bauwerk, $_Bauwerke[1][0]) <> -1) or ($_Einheit[$iEinheitmenuNr][0] = $_Einheit[2][0] and _ArraySearch($_Bauwerk, $_Bauwerke[2][0]) <> -1) or ($_Einheit[$iEinheitmenuNr][0] = $_Einheit[3][0] and _ArraySearch($_Bauwerk, $_Bauwerke[1][0]) <> -1 and _ArraySearch($_Bauwerk, $_Bauwerke[2][0]) <> -1 and _ArraySearch($_Bauwerk, $_Bauwerke[3][0]) <> -1) then
		dim $_SetDataArray[7] = [$_Einheit[$iEinheitmenuNr][0], StringMid($_Einheit[$iEinheitmenuNr][1], 1, 2), StringMid($_Einheit[$iEinheitmenuNr][1], 3, 2), StringMid($_Einheit[$iEinheitmenuNr][1], 5, 2), StringMid($_Einheit[$iEinheitmenuNr][1], 7, 2), "", ""]
		_SetData($_SetDataArray)
	EndIf
EndFunc

Func _SetNew($_posX, $_posY, $_unit)
	$_Einheit_unitNr=_ArraySearch($_Einheit, $_unit)
	if $_Einheit_unitNr <> -1 then
		if $_Einheiten[$_posX][$_posY] = "" and $_Bauwerk[$_posX][$_posY] = "" then
			dim $tmp=GUICtrlRead($_AuswahlView[0])
			if StringInStr($tmp,"Versetze:",1) then
				$tmp=StringSplit($tmp, "Versetze: ",1)
				$tmp=$tmp[2]
				$tmpX=GUICtrlRead($_AuswahlView[5])
				$tmpX=StringSplit($tmpX, "Coord X: ",1)
				$tmpX=$tmpX[2]
				$tmpY=GUICtrlRead($_AuswahlView[6])
				$tmpY=StringSplit($tmpY, "Coord Y: ",1)
				$tmpY=$tmpY[2]
				_MoveEinheit($tmpX,$tmpY,$tmp)
				dim $_SetDataArray[7]
				_SetData($_SetDataArray)
				for $ii = 0 to 15
					$_EnemyPos=StringSplit($_EnemySet[$ii][0],":",1)
					if $_EnemyPos[0]= 2 and $_posX=$_EnemyPos[1] and $_posY=$_EnemyPos[2] and $_unit=$_Einheit[2][0] then
						$_EnemySet[$ii][0]=""
						$_EnemySet[$ii][1]=""
						GUICtrlSetBkColor($_Spielfeld[$_posX][$_posY], $_GelaendeArten[_ArraySearch($_GelaendeArten, $_Gelaende[$_posX][$_posY])][2])
						ExitLoop
					EndIf
				Next
			EndIf
			dim $_Ress[3]=[StringMid($_Einheit[$_Einheit_unitNr][1],1,2), StringMid($_Einheit[$_Einheit_unitNr][1],3,2), StringMid($_Einheit[$_Einheit_unitNr][1],5,2)]
			if $_Ressource[1][1] >= $_Ress[1] and $_Ressource[2][1] >= $_Ress[2] then
				$_Einheiten[$_posX][$_posY]=$_Einheit[$_Einheit_unitNr][0]
				$_StueckEinheiten[UBound($_StueckEinheiten)-1][0] = $_Einheit[$_Einheit_unitNr][0]
				$_StueckEinheiten[UBound($_StueckEinheiten)-1][1] = $_posX&":"&$_posY
				ReDim $_StueckEinheiten[UBound($_StueckEinheiten)+1][2]
				if not StringInStr($tmp,"Versetze:",1) then
					for $i=0 to 2
						$_Ressource[$i][1]-=$_Ress[$i]
					Next
					$_Aktionen+=1
					$_TotalEinheiten+=1
					for $ii = 0 to 15
						$_EnemyPos=StringSplit($_EnemySet[$ii][1],":",1)
						if $_EnemyPos[0]=2 then _Sight($_posX, $_posY, $_unit, $_EnemyPos[1],$_EnemyPos[2])
					Next
				EndIf
			EndIf
		elseif $_Einheiten[$_posX][$_posY] <> "" then
			dim $_Einheit_unitNr=_ArraySearch($_StueckEinheiten, $_posX&":"&$_posY), $_Einheit_unitNr2=_ArraySearch($_Einheit, $_StueckEinheiten[$_Einheit_unitNr][0])
			$_Einheiten[$_posX][$_posY]=""
			$_StueckEinheiten[$_Einheit_unitNr][1] = ""
			GUICtrlSetData($_Spielfeld[$iX][$iY], "")
			dim $_SetDataArray[7] = ["Versetze: "&$_StueckEinheiten[$_Einheit_unitNr][0], "", "", "", StringMid($_Einheit[$_Einheit_unitNr2][1], 7, 2), "", ""]
			_SetData($_SetDataArray)
		EndIf
	EndIf
	$_Bauwerke_unitNr=_ArraySearch($_Bauwerke, $_unit)
	if $_Bauwerke_unitNr <> -1 then
		if $_Bauwerk[$_posX][$_posY] = "" and $_Einheiten[$_posX][$_posY] = "" and $_Gelaende[$_posX][$_posY] <> "Wasser" then
			dim $_Ress[3]=[StringMid($_Bauwerke[$_Bauwerke_unitNr][1],1,2), StringMid($_Bauwerke[$_Bauwerke_unitNr][1],3,2), StringMid($_Bauwerke[$_Bauwerke_unitNr][1],5,2)], $_Einheit_unitNr2=_ArraySearch($_Einheiten, $_Einheit[3][0])
			if $_Ressource[0][1] >= $_Ress[0] and $_Ressource[1][1] >= $_Ress[1] then
				if (UBound($_StueckBauwerke)-1 > 0 and $_Bauwerke[$_Bauwerke_unitNr][0] = $_Bauwerke[0][0] and $_Einheit_unitNr2 <> -1) or (UBound($_StueckBauwerke)-1 = 0 and $_Bauwerke[$_Bauwerke_unitNr][0] = $_Bauwerke[0][0]) or ($_Bauwerke[$_Bauwerke_unitNr][0] <> $_Bauwerke[0][0]) then
					$_Bauwerk[$_posX][$_posY]=$_Bauwerke[$_Bauwerke_unitNr][0]
					for $i=0 to 2
						$_Ressource[$i][1]-=$_Ress[$i]
					Next
					$_Aktionen+=1
					$_TotalBauwerke+=1
					$_StueckBauwerke[UBound($_StueckBauwerke)-1][0] = $_Bauwerke[$_Bauwerke_unitNr][0]
					$_StueckBauwerke[UBound($_StueckBauwerke)-1][1] = $_posX&":"&$_posY
					ReDim $_StueckBauwerke[UBound($_StueckBauwerke)+1][2]
				EndIf
			EndIf
		EndIf
	EndIf
	for $iY=0 To $_Spielfeld_FelderY-1
		for $iX=0 To $_Spielfeld_FelderX-1
			if $_Bauwerk[$iX][$iY] <> "" then GUICtrlSetData($_Spielfeld[$iX][$iY], $_Bauwerk[$iX][$iY])
			if $_Einheiten[$iX][$iY] <> "" then GUICtrlSetData($_Spielfeld[$iX][$iY], $_Einheiten[$iX][$iY])
		Next
	Next
	for $iY=0 To 2
		GUICtrlSetData($_ResView[$iY], $_Ressource[$iY][0]&": "&$_Ressource[$iY][1])
	Next
EndFunc

Func _MoveEinheit($_posX, $_posY, $_unit)
	dim $aInfo = GUIGetCursorInfo($hMainGui), $iX = int(($aInfo[0]-$_Spielfeld_StartX) / $_Spielfeld_FelderSizeX), $iY = int(($aInfo[1]-$_Spielfeld_StartY) / $_Spielfeld_FelderSizeY), $_Einheit_unitNr=_ArraySearch($_Einheit, $_unit), $_Steps=0
	if $iX < $_posX then
		$_Steps+=$_posX-$iX
	Else
		$_Steps+=$iX-$_posX
	EndIf
	if $iY < $_posY then
		$_Steps+=$_posY-$iY
	Else
		$_Steps+=$iY-$_posY
	EndIf
	for $i = 0 to UBound($_StueckEinheiten)-1
		if $_StueckEinheiten[$i][0] <> "" and $_StueckEinheiten[$i][1] = "" then ExitLoop
	Next
	if $_Steps <= number(StringMid($_Einheit[$_Einheit_unitNr][1], 7, 2)) then
		$_StueckEinheiten[$i][1] = $iX&":"&$iY
		$_Einheiten[$iX][$iY] = $_Einheit[$_Einheit_unitNr][0]
		$_Aktionen+=1
	Else
		$_StueckEinheiten[$i][1] = $_posX&":"&$_posY
		$_Einheiten[$iX][$iY] = ""
		$_Einheiten[$_posX][$_posY] = $_Einheit[$_Einheit_unitNr][0]
	EndIf
	$_StueckEinheiten[$i][0] = $_Einheit[$_Einheit_unitNr][0]
EndFunc

Func _Produktion()
	dim $_Prod[3]
	for $iY=0 To $_Spielfeld_FelderY-1
		for $iX=0 To $_Spielfeld_FelderX-1
			if $_Bauwerk[$iX][$iY] <> "" or $_Einheiten[$iX][$iY] <> "" then
				dim $_Ress[2]=[StringMid($_Ressourcen[$iX][$iY],1,1), StringMid($_Ressourcen[$iX][$iY],2,1)]
				for $i=0 to 1
					$_Ressource[$i][1]+=$_Ress[$i]
					$_Prod[$i]+=$_Ress[$i]
				Next
			EndIf
		Next
	Next
	for $i = 0 to 2
		$_UnterhaltBauwerke[$i] = 0
		$_UnterhaltEinheiten[$i] = 0
	next
	for $i = 0 to UBound($_StueckBauwerke)-1
		if $_StueckBauwerke[$i][0] <> "" then
			$_Bauwerke_unitNr=_ArraySearch($_Bauwerke, $_StueckBauwerke[$i][0])
			$_UnterhaltBauwerke[0]+=StringMid($_Bauwerke[$_Bauwerke_unitNr][2],1,2)
			$_UnterhaltBauwerke[1]+=StringMid($_Bauwerke[$_Bauwerke_unitNr][2],3,2)
			$_UnterhaltBauwerke[2]+=StringMid($_Bauwerke[$_Bauwerke_unitNr][2],5,2)
		EndIf
	next
	for $i = 0 to UBound($_StueckEinheiten)-1
		if $_StueckEinheiten[$i][0] <> "" then
			$_Einheit_unitNr=_ArraySearch($_Einheit, $_StueckEinheiten[$i][0])
			$_UnterhaltEinheiten[0]+=StringMid($_Einheit[$_Einheit_unitNr][2],1,2)
			$_UnterhaltEinheiten[1]+=StringMid($_Einheit[$_Einheit_unitNr][2],3,2)
			$_UnterhaltEinheiten[2]+=StringMid($_Einheit[$_Einheit_unitNr][2],5,2)
		EndIf
	next
	for $i = 0 to 2
		$_Ressource[$i][1] -= $_UnterhaltBauwerke[$i]
		$_Ressource[$i][1] -= $_UnterhaltEinheiten[$i]
		$_Prod[$i] -=$_UnterhaltBauwerke[$i]+$_UnterhaltEinheiten[$i]
		GUICtrlSetData($_ResProdunktionView[$i], $_RessProdunktion[$i]&": "&$_Prod[$i])
		GUICtrlSetData($_ResView[$i], $_Ressource[$i][0]&": "&$_Ressource[$i][1])
	next
	if $_Ressource[0][1] < -10 Then
		if UBound($_StueckEinheiten)-1 > 0 then
			dim $_unit=Random(0,UBound($_StueckEinheiten)-2,1), $_Pos=StringSplit($_StueckEinheiten[$_unit][1],":",1)
			if $_Pos[0] = 2 then
				$_Einheiten[$_Pos[1]][$_Pos[2]]=""
				_ArrayDelete($_StueckEinheiten, $_unit)
				GUICtrlSetData($_Spielfeld[$_Pos[1]][$_Pos[2]], "")
				$_Ressource[0][1] += 10
				$_Ressource[1][1] += 5
				$_Ressource[2][1] += 10
			EndIf
		Else
			dim $_unit=Random(0,UBound($_StueckBauwerke)-2,1), $_Pos=StringSplit($_StueckBauwerke[$_unit][1],":",1)
			if $_Pos[0] = 2 then
				$_Bauwerk[$_Pos[1]][$_Pos[2]]=""
				GUICtrlSetData($_Spielfeld[$_Pos[1]][$_Pos[2]], "")
				_ArrayDelete($_StueckBauwerke, $_unit)
				$_Ressource[0][1] += 10
				$_Ressource[1][1] += 5
				$_Ressource[2][1] += 30
			EndIf
		EndIf
	EndIf
	if $_Ressource[2][1] < -25 Then
		if UBound($_StueckBauwerke)-1 > 0 then
			dim $_unit=Random(0,UBound($_StueckBauwerke)-2,1), $_Pos=StringSplit($_StueckBauwerke[$_unit][1],":",1)
			if $_Pos[0] = 2 then
				$_Bauwerk[$_Pos[1]][$_Pos[2]]=""
				GUICtrlSetData($_Spielfeld[$_Pos[1]][$_Pos[2]], "")
				_ArrayDelete($_StueckBauwerke, $_unit)
				$_Ressource[0][1] += 20
				$_Ressource[1][1] += 10
				$_Ressource[2][1] += 30
			EndIf
		EndIf
	EndIf
	if $_Ressource[0][1] < -150 or $_Ressource[1][1] < -150 or $_Ressource[2][1] < -150 then _GameOver()
	_Enemy()
	dim $__Timer = TimerInit(), $_Aktionen=0
	if $_Aktionen=0 then $_Aktionen=1
	$_TotalAktionen+=$_Aktionen
EndFunc

Func _Enemy()
	if Random(0,99,1) >= 95 Then
		; Gegner erstellen
		$_enemyNr = _ArraySearch($_EnemySet, "")
		if UBound($_StueckBauwerke)-1 >0 and $_enemyNr <> -1 and $_enemyNr <= 14 then _GebaudeSearch(Random(0,UBound($_StueckBauwerke)-2,1),$_enemyNr)
	EndIf
	for $i = 0 to 15
		if $_EnemySet[$i][0] <> "" or $_EnemySet[$i][1] <> "" Then
			; Gegner bewegen
			dim $_Pos=StringSplit($_EnemySet[$i][0],":",1), $_Ziel=StringSplit($_EnemySet[$i][1],":",1), $_NewPos[2] = [$_Pos[1], $_Pos[2]], $_GelaendeNr = _ArraySearch($_GelaendeArten, $_Gelaende[$_Pos[1]][$_Pos[2]])
			GUICtrlSetData($_Spielfeld[$_Pos[1]][$_Pos[2]], "")
			GUICtrlSetBkColor($_Spielfeld[$_Pos[1]][$_Pos[2]], $_GelaendeArten[$_GelaendeNr][2])
			if Random(0,100,1) < 60 then
				if int($_Ziel[1]) < int($_Pos[1]) then
					$_NewPos[0]-=1
				else
					$_NewPos[0]+=1
				EndIf
			EndIf
			if Random(0,100,1) < 60 then
				if int($_Ziel[2]) < int($_Pos[2]) then
					$_NewPos[1]-=1
				Else
					$_NewPos[1]+=1
				EndIf
			EndIf
			$_EnemySet[$i][0]=$_NewPos[0]&":"&$_NewPos[1]
			$_unit=_ArraySearch($_StueckEinheiten, $_NewPos[0]&":"&$_NewPos[1])
			if $_unit <> -1 then
				_ArrayDelete($_StueckEinheiten, $_unit)
				$_Einheiten[$_NewPos[0]][$_NewPos[1]] = ""
				GUICtrlSetData($_Spielfeld[$_NewPos[0]][$_NewPos[1]], "")
				for $ii = 0 to 15
					if $_EnemySet[$ii][0] = $_NewPos[0]&":"&$_NewPos[1] or $_EnemySet[$ii][1] = $_NewPos[0]&":"&$_NewPos[1] Then
						$_Pos2=StringSplit($_EnemySet[$ii][0],":",1)
						$_NewGelaendeNr = _ArraySearch($_GelaendeArten, $_Gelaende[$_Pos2[1]][$_Pos2[2]])
						$_EnemySet[$ii][0] = ""
						$_EnemySet[$ii][1] = ""
						if $_NewGelaendeNr <> -1 then GUICtrlSetBkColor($_Spielfeld[$_NewPos[0]][$_NewPos[1]], $_GelaendeArten[$_NewGelaendeNr][2])
						if UBound($_StueckBauwerke)-1 > 0 then _GebaudeSearch(Random(0,UBound($_StueckBauwerke)-2,1),$ii)
					EndIf
				Next
			EndIf
			for $ii= 0 to 99
				if $ii <= UBound($_StueckBauwerke)-1 and $_StueckBauwerke[$ii][0] <> "" and $_StueckBauwerke[$ii][1] <> "" Then
					$_Pos=StringSplit($_StueckBauwerke[$ii][1],":",1)
					_Sight($_Pos[1],$_Pos[2],$_StueckBauwerke[$ii][0], $_NewPos[0],$_NewPos[1])
				EndIf
				if $ii <= UBound($_StueckEinheiten)-1 and $_StueckEinheiten[$ii][0] <> "" and $_StueckEinheiten[$ii][1] <> "" Then
					$_Pos=StringSplit($_StueckEinheiten[$ii][1],":",1)
					_Sight($_Pos[1],$_Pos[2],$_StueckEinheiten[$ii][0], $_NewPos[0],$_NewPos[1])
				EndIf
			Next
			if $_NewPos[0] = $_Ziel[1] and $_NewPos[1] = $_Ziel[2] Then
				$_unit=_ArraySearch($_StueckBauwerke, $_Ziel[1]&":"&$_Ziel[2])
				if $_unit <> -1 then
					GUICtrlSetData($_Spielfeld[$_NewPos[0]][$_NewPos[1]], "")
					GUICtrlSetBkColor($_Spielfeld[$_NewPos[0]][$_NewPos[1]], $_GelaendeArten[$_GelaendeNr][2])
					_ArrayDelete($_StueckBauwerke, $_unit)
					$_Bauwerk[$_Ziel[1]][$_Ziel[2]] = ""
					$_EnemySet[$i][0] = ""
					$_EnemySet[$i][1] = ""
					if UBound($_StueckBauwerke)-1 > 0 then _GebaudeSearch(Random(0,UBound($_StueckBauwerke)-2,1),$i)
				EndIf
			EndIf
			if UBound($_StueckBauwerke)-1 = 0 and UBound($_StueckEinheiten)-1 = 0 then _GameOver()
		EndIf
	Next
EndFunc

Func _Sight($iX,$iY,$sUnit, $iEX,$iEY)
	dim $_Bauwerke_unitNr=_ArraySearch($_Bauwerk, $sUnit), $_Einheit_unitNr=_ArraySearch($_Einheit, $sUnit), $Step=0
	if $_Bauwerke_unitNr <> -1 or ($_Einheit_unitNr <> -1 and ($_Einheit[$_Einheit_unitNr][0] = $_Einheit[0][0] or $_Einheit[$_Einheit_unitNr][0] = $_Einheit[3][0])) Then $Step=2
	If $_Einheit_unitNr <> -1 and $_Einheit[$_Einheit_unitNr][0] = $_Einheit[1][0] Then $Step=4
	If $_Einheit_unitNr <> -1 and $_Einheit[$_Einheit_unitNr][0] = $_Einheit[2][0] Then $Step=3

	if abs(int($iX)-int($iEX)) <= $Step and abs(int($iY)-int($iEY)) <= $Step then
		GUICtrlSetBkColor($_Spielfeld[$iEX][$iEY], 0xff0000)
		GUICtrlSetData($_Spielfeld[$iEX][$iEY], "Gegner")
		$_Einheiten_unitNr=_ArraySearch($_StueckEinheiten, $iX&":"&$iY)
		$_Enemy_unitNr=_ArraySearch($_EnemySet, $iEX&":"&$iEY)
		if $_Enemy_unitNr <> -1 then
			$_EnemySet[$_Enemy_unitNr][0]=$iEX&":"&$iEY
			$_EnemySet[$_Enemy_unitNr][1]=$iX&":"&$iY
		EndIf
	EndIf
EndFunc

Func _GebaudeSearch($_Ziel,$_enemyNr)
	if $_Ziel >=0 then
		$_EnemySet[$_enemyNr][0]=$_EnemySet[$_enemyNr][1]
		$_ZielPos=StringSplit($_StueckBauwerke[$_Ziel][1],":",1)
		if $_EnemySet[$_enemyNr][0]="" and $_ZielPos[0] = 2 then
			if 19 - $_ZielPos[1] < 10 Then
				$_StartX=0
			Else
				$_StartX=19
			EndIf
			$_StartY=Random(0,19,1)
			$_EnemySet[$_enemyNr][0]=$_StartX&":"&$_StartY
		EndIf
		$_EnemySet[$_enemyNr][1]=$_StueckBauwerke[$_Ziel][1]
	EndIf
EndFunc

Func _GameOver()
	GUIDelete($hMainGui)
	dim $__TimerDiff=Int(TimerDiff($__StartTimer)/1000), $_TotalPoints = ($__TimerDiff*3) + ($_TotalAktionen*2) + ($_TotalEinheiten*8) + ($_TotalBauwerke*12), $txt="Leider verloren!"&@CRLF&@CRLF&"Gespielte Zeit: "&$__TimerDiff&" Sekunden"&@CRLF&"Gemachte Züge: "&$_TotalAktionen&@CRLF&@CRLF&"Punktezahl: "&$_TotalPoints&@CRLF&@CRLF
	MsgBox(0, "Game Over", $txt)
	Exit
EndFunc

Func _SetData($_array)
	for $i=0 to 6
		GUICtrlSetData($_AuswahlView[$i], $_Auswahl[$i] & $_array[$i])
	next
EndFunc
