#include-once

Global Const $___c_NULLSTRING = ""
Global Const $___c_DISCONNECTED = -1
Global Const $___c_TIMEOUT = 0x40
Global Const $___c_PACKET_INTRO = StringToBinary("EasyTcp:")
Global Const $___c_PACKET_INTRO_LEN = BinaryLen($___c_PACKET_INTRO)
Global Const $___c_STD_ERROR = -1
Global Enum $___type_BINARY, $___type_STRING
Global Const $___c_PACKET_INIT[1][3] = [[$___c_NULLSTRING, _
		$___c_NULLSTRING, 0]]

Func _EasyTcpRecv($mainsocket, $prefix)
	If $mainsocket <= $___c_DISCONNECTED Then
		Return SetError(10, 1, $___c_STD_ERROR)
	EndIf

	Local $a_packet = ___local_TryReadPacket($mainsocket)
	If @error Or Not IsArray($a_packet) Then
		Return SetError(10, 2, $___c_STD_ERROR)
	Else
		Call($prefix & $a_packet[0][1], $a_packet)
		If @error Then
			Return SetError(10, 3, $___c_STD_ERROR)
		Else
			Return True
		EndIf
	EndIf
EndFunc   ;==>_EasyTcpRecv

Func _EasyTcpSend($mainsocket, $name, $x_param0, $x_param1 = Default)
	If $mainsocket <= $___c_DISCONNECTED Then
		Return SetError(20, 1, $___c_STD_ERROR)
	EndIf

	Local $b_packet = ___local_BinaryInit()
	If $x_param1 <> Default Then
		Local $a_single[1][2] = [[$x_param0, $x_param1]]
		$x_param0 = $a_single
	EndIf

	$b_packet = ___local_CreatePacket($name, $x_param0)
	If @error Then
		Return SetError(20, 2, $___c_STD_ERROR)
	EndIf

	Return TCPSend($mainsocket, $b_packet)
EndFunc   ;==>_EasyTcpSend

#region ; Local
Func ___local_CreatePacket($s_name, $a_data)
	Local $b_packet = $___c_PACKET_INTRO

	$b_packet &= ___local_AppendSize($s_name)
	If @error Then
		Return SetError(@error, @extended, $___c_STD_ERROR)
	EndIf

	Local $b_data = ___local_PackArray($a_data)
	If @error Then
		Return SetError(@error, @extended, $b_data)
	Else
		$b_packet &= $b_data
	EndIf

	Return $b_packet
EndFunc   ;==>___local_CreatePacket

Func ___local_TryReadPacket($i_socket)
	Local $a_packet = $___c_PACKET_INIT

	$a_packet[0][0] = ___local_TryRead($i_socket, $___c_PACKET_INTRO_LEN)
	If $a_packet[0][0] <> $___c_PACKET_INTRO Then
		Return SetError(30, 1, $___c_STD_ERROR)
	EndIf

	$a_packet[0][1] = ___local_TryReadData($i_socket)
	If @error Then
		Return SetError(30, 2, $___c_STD_ERROR)
	EndIf

	$a_packet[0][2] = ___local_TryReadINT16($i_socket)
	If @error Or $a_packet[0][2] < 0 Then
		Return SetError(30, 3, $___c_STD_ERROR)
	EndIf

	If $a_packet[0][2] = 0 Then
		Return $a_packet
	Else
		Local $i_size = $a_packet[0][2] + 1
		ReDim $a_packet[$i_size][3]
	EndIf

	For $index = 1 To $a_packet[0][2]
		$a_packet[$index][0] = ___local_TryReadINT16($i_socket)
		$a_packet[$index][1] = ___local_TryReadData($i_socket)
	Next

	Return $a_packet
EndFunc   ;==>___local_TryReadPacket

Func ___local_TryReadINT16($i_socket)
	Local $buffer = ___local_TryRead($i_socket, 2)
	If @error Then
		Return SetError(@error, @extended, $buffer)
	Else
		Return Number($buffer)
	EndIf
EndFunc   ;==>___local_TryReadINT16

Func ___local_TryReadData($i_socket)
	Local $i_type = ___local_TryRead($i_socket, 1)
	If @error Then
		Return SetError(@error, @extended, $i_type)
	EndIf

	Local $i_len = ___local_TryReadINT16($i_socket)
	If @error Then
		Return SetError(@error, @extended, $i_len)
	EndIf

	Local $x_data = ___local_TryRead($i_socket, $i_len)
	If @error Then
		Return SetError(@error, @extended, $x_data)
	Else
		If $i_type = $___type_BINARY Then
			Return $x_data
		ElseIf $___type_STRING Then
			Return BinaryToString($x_data)
		Else
			Return SetError(40, 1, $___c_STD_ERROR)
		EndIf
	EndIf
EndFunc   ;==>___local_TryReadData

Func ___local_TryRead($i_socket, Const $i_length)
	If $i_socket <= $___c_DISCONNECTED Then
		Return SetError(50, 1, $___c_STD_ERROR)
	EndIf
	Local $b_buffer = ___local_BinaryInit()
	Local $_timer = TimerInit()

	Do
		$b_buffer &= TCPRecv($i_socket, 1, 1)
		If @error Then
			Return SetError(50, 2, $___c_STD_ERROR)
		Else
			If $b_buffer = $___c_NULLSTRING Then
				Return SetError(50, 3, $___c_STD_ERROR)
			EndIf
		EndIf

		If TimerDiff($_timer) >= $___c_TIMEOUT Then
			Return SetError(50, 4, $___c_STD_ERROR)
		EndIf
	Until BinaryLen($b_buffer) >= $i_length

	Return $b_buffer
EndFunc   ;==>___local_TryRead

Func ___local_PackArray($a_data)
	If Not IsArray($a_data) Then
		Return SetError(60, 1, $___c_STD_ERROR)
	EndIf

	If UBound($a_data, 0) <> 2 Then
		Return SetError(60, 2, $___c_STD_ERROR)
	EndIf

	If UBound($a_data, 2) <> 2 Then
		Return SetError(60, 3, $___c_STD_ERROR)
	EndIf
	Local Const $i_data_amount = UBound($a_data, 1) - 1
	Local $buffer = ___local_ToWORD($i_data_amount + 1)

	For $index = 0 To $i_data_amount Step 1
		$buffer &= ___local_ToWORD($a_data[$index][0])
		$buffer &= ___local_AppendSize($a_data[$index][1])
	Next

	Return $buffer
EndFunc   ;==>___local_PackArray

Func ___local_AppendSize($x_data)
	Local $buffer = ___local_BinaryInit()
	Local $b_data = $x_data

	If IsBinary($x_data) Then
		$buffer = ___local_ToBYTE($___type_BINARY)
	Else
		$buffer = ___local_ToBYTE($___type_STRING)
		$b_data = StringToBinary($x_data)
	EndIf

	$buffer &= ___local_ToWORD(BinaryLen($b_data))
	$buffer &= $b_data

	Return $buffer
EndFunc   ;==>___local_AppendSize

Func ___local_BinaryInit()
	Local $binary = Binary($___c_NULLSTRING)

	Return $binary
EndFunc   ;==>___local_BinaryInit

Func ___local_ToBYTE($x_data)
	Local $byte = BitAND($x_data, 0xFF)
	$byte = BinaryMid($byte, 1, 1)
	Return $byte
EndFunc   ;==>___local_ToBYTE

Func ___local_ToWORD($x_data)
	Local $word = BitAND($x_data, 0xFFFF)
	$word = BinaryMid($word, 1, 2)
	Return $word
EndFunc   ;==>___local_ToWORD

Func _EasyTcpGetData($data, $opcode)
	For $index = 1 To $data[0][2] Step 1
		If $data[$index][0] = $opcode Then
			Return $data[$index][1]
		EndIf
	Next

	Return SetError(70, 1, $___c_STD_ERROR)
EndFunc   ;==>_EasyTcpGetData
#endregion ; Local
