# Function Reference

GUICtrlCreateAvi

Creates an AVI video control for the GUI.

GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style [, exStyle]]]] )

Parameters

filename | The filename of the video. Only .avi files are supported.
subfileid | id of the subfile to be used. If the file only contains one video then use -1.
left | The left side of the control. If -1 is used then left will be computed according to GUICoordMode.
top | The top of the control. If -1 is used then top will be computed according to GUICoordMode.
width | [optional] The width of the control (default is the previously used width).
height | [optional] The height of the control (default is the previously used height).
style | [optional] Defines the style of the control. See GUI Control Styles Appendix. default (-1) : $ACS_TRANSPARENT $ACS_TRANSPARENT is always used unless $ACS_NONTRANSPARENT is specified.
exStyle | [optional] Defines the extended style of the control. See Extended Style Table.

Return Value

Success: | Returns the identifier (controlID) of the new control.
Failure: | Returns 0.

Remarks

To obtain the value of the control see GUICtrlRead.
To set or change information in the control see GUICtrlSet....
To start the video as soon as the control is created use the $ACS_AUTOPLAY style.
You can can start and stop the animation by setting the state to 1 or 0 with GUICtrlSetState. See example.
To combine styles with the default style use BitOr($GUI_SS_DEFAULT_AVI, newstyle,...).
Default resizing is $GUI_DOCKSIZE.

Related

GUICoordMode (option), GUICtrlSet..., GUIGetMsg

Example

#include <GUIConstants.au3>
GUICreate ("My GUI Animation",300,200)
$ani1 = GUICtrlCreateAvi (@SystemDir & "\shell32.dll",150, 50,10)
$buttonstart = GUICtrlCreateButton ("start",50,150,70,22)
$buttonstop = GUICtrlCreateButton ("stop",150,150,70,22)
GUISetState( )
; Run the GUI until the dialog is closed
While 1
$msg = GUIGetMsg()
Select
case $msg = $GUI_EVENT_CLOSE
ExitLoop
case $msg = $buttonstart
GUICtrlSetState ($ani1, 1)
case $msg = $buttonstop
GUICtrlSetState ($ani1, 0)
EndSelect
Wend