# Function Reference

FileFindFirstFile

Returns a search "handle" according to file search string.

FileFindFirstFile ( "filename" )

Parameters

filename | File search string. (* and ? wildcards accepted)

Return Value

Success: | Returns a search "handle" for use with subsequent FileFindNextFile functions.
Failure: | Returns -1 if error occurs. If the Folder is empty the @error is set to 1.

Remarks

The search string is not case sensitive.
Wildcards: In general, * denotes zero or more characters, and ? denotes zero or one character. If your file search string contains only wildcards (or is "*.*"), then see the example below for the return value!
You can use only one wildcard in the filename part or in the extension part i.e. a*.b?.
?? seems equivalent to * (not described in Microsoft documentation).
When using a 3-char extension any extension starting with those 3 chars will match, .e.g. "*.log" will match "test.log_1". (not described either in Microsoft dosumentation).
When you have finished searching with the FileFind... functions you must call FileClose() to release the search handle.
Directory name are return according to the wildcards if any.

Related

FileClose, FileFindNextFile

Example

; Shows the filenames of all files in the current directory.
$search = FileFindFirstFile("*.*")
; Check if the search was successful
If $search = -1 Then
MsgBox(0, "Error", "No files/directories matched the search pattern")
Exit
EndIf
While 1
$file = FileFindNextFile($search)
If @error Then ExitLoop
MsgBox(4096, "File:", $file)
WEnd
; Close the search handle
FileClose($search)