Example()

Func Example()
	; Definiere den String der später konvertiert wird.
	; Anmerkung: Dieser String könnte in der Hilfe Datei
	; und sogar in manchen Texteditoren als ?? dargestellt werden.
	; Dieses Beispiel wurde als UTF-8 mit BOM gespeichert.
	; Es sollte in Editoren die auf BOM Basis veränderbare Codeseiten
    ; unterstützen korrekt angezeigt werden.
	Local Const $sString = "Hallo - 你好"

	; Temporäre Variablen in denen die Konvertierungsresultate gespeichert werden.
	; $sBinary wird den Originalstring in Binärform enthalten und
	; $sConverted wird das Resultat enthalten nachdem es in das ursprüngliche Format gebracht wurde
	Local $sBinary, $sConverted

	; Konvertiere den originalen UTF-8 String in einen ANSI kompatiblen Binärstring.
	$sBinary = StringToBinary($sString)

	; Konvertiere den ANSI kompatiblen Binärstring zurück in einen String.
	$sConverted = BinaryToString($sBinary)

	; Zeige die Ergebnisse.  Die letzten beiden Zeichen werden als ?? dargestellt,
	; da sie in ANSI nicht repräsentiert werden können.
	DisplayResults($sString, $sBinary, $sConverted, "ANSI")

	; Konvertiere den originalen UTF-8 String in einen UTF16-LE Binärstring.
	$sBinary = StringToBinary($sString, 2)

	; Konvertiere den UTF16-LE Binärstring zurück in einen String.
	$sConverted = BinaryToString($sBinary, 2)

	; Zeige die Ergebnisse.
	DisplayResults($sString, $sBinary, $sConverted, "UTF16-LE")

	; Konvertiere den originalen UTF-8 String in einen UTF16-LE Binärstring.
	$sBinary = StringToBinary($sString, 3)

	; Konvertiere den UTF16-LE Binärstring zurück in einen String.
	$sConverted = BinaryToString($sBinary, 3)

	; Zeige die Ergebnisse.
	DisplayResults($sString, $sBinary, $sConverted, "UTF16-BE")

	; Konvertiere den originalen UTF-8 String in einen UTF-8 Binärstring.
	$sBinary = StringToBinary($sString, 4)

	; Konvertiere den UTF-8 Binärstring zurück in einen String.
	$sConverted = BinaryToString($sBinary, 4)

	; Zeige die Ergebnisse.
	DisplayResults($sString, $sBinary, $sConverted, "UTF8")
EndFunc

; Hilfsfunktion welche die Nachricht für die Darstellung formatiert.  Sie empfängt folgende Parameter:
; $sOriginal - Der originale String vor der Konvertierung.
; $sBinary - Der originale String nachdem er in Binärform konvertiert wurde.
; $sConverted - Der originale String nachdem er in Binärform und zurück konvertiert wurde.
; $sConversionType - Ein für Menschen lesbarer Name für den bei der konvertierung verwendeten Kodierungstyp.
Func DisplayResults($sOriginal, $sBinary, $sConverted, $sConversionType)
	MsgBox(4096, "", "Original:" & @CRLF & $sOriginal & @CRLF & @CRLF & "Binär:" & @CRLF & $sBinary & @CRLF & @CRLF & $sConversionType & ":" & @CRLF & $sConverted)
EndFunc