#include <SQLite.au3>
#include <SQLite.dll.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Opt("GUIOnEventMode", 1)


global $SQLBefehle="#Alles hinter der # wird als Kommentar gewertet"&@crlf&"#select * from Buecher where id<100 #Buechertabelle anzeigen"&@crlf&"#delete from Buecher where id=-1 #Buch löschen"&@crlf& _
					"#INSERT INTO Buecher(id) VALUES (29) #Buch eintragen (Für Werte siehe Select)"&@crlf&"#UPDATE Buecher SET id = '-1' WHERE id='-1' #Eintrag ändern"&@crlf& _
					"#Spaltennamen: ID,Identifier,author,description,subject,title,date,path,language,rating"

global $SqlGui,$SqlGui_Edit3_1
global $aData = "",$iRow = "",$iClumn = ""

;Hauptfenster, in der Listview werden die Selects angezeigt
$MainGui=GuiCreate("Example",800,600)
$MainGui_MainListView=GUICtrlCreateListView("",5,5,790,570)
$Button=GUICtrlCreateButton("Konsole",5,575)
GUICtrlSetOnEvent(-1,"sqlkonsole")
GUISetOnEvent($GUI_EVENT_CLOSE, "MainGui_Close")
GUISetState()

;SQL-Laden
_SQLite_Startup("sqlite3.dll")
;Datenbank öffnen
$hDatabase = _SQLite_Open(@ScriptDir&"\Buecher.sqlite") ;Datenbank öffnen

While sleep(10)
WEnd

Func MainGui_Close()
	_SQLite_Close($hDatabase)
	exit
EndFunc

;Konsolefenster
Func sqlkonsole()
	;Fenster erstellen
	$SqlGui = guicreate("SQL-Konsole", 500, 600, 0, 0, $WS_CAPTION + $WS_SYSMENU + $WS_SIZEBOX + $WS_MINIMIZEBOX + $WS_MAXIMIZEBOX, -1, $MainGui);$WS_POPUP; +$WS_MINIMIZEBOX+$WS_MAXIMIZEBOX,$WS_EX_ACCEPTFILES)
	GUISetOnEvent($GUI_EVENT_CLOSE, "closeSqlGui")
	;Edit, für die Sql-Befehle
	$SqlGui_Edit3_1 = guictrlcreateedit("#Dies ist ein Kommentar"&@crlf&"#Select * from `Buecher` where id<10 #Beispiel Select"&@crlf&@crlf&$SQLBefehle&@crlf, 10, 10, 480, 540)
	GUICtrlSetResizing(-1, BitOR(2, 64, 32, 4))
	$SqlGui_Button3_1 = guictrlcreatebutton("Send", 10, 560, 100)
	GUICtrlSetResizing(-1, 768 + 2)
	guictrlsetonevent(-1, "sqlsend")
	$SqlGui_Button3_2 = guictrlcreatebutton("Close", 120, 560, 100)
	GUICtrlSetResizing(-1, 768 + 2)
	guictrlsetonevent(-1, "closeSqlGui")
	guisetstate(@sw_show, $SqlGui)
EndFunc   ;==>sqlkonsole

Func fillListView($array, $sort = true, $lastIsPath = false)
	;Dieser Befehl lässt die Listview schneller laden, da Änderungen nicht sofort angezeigt werden
	_GUICtrlListView_BeginUpdate($MainGui_MainListView)
	;löscht alle Items
	_GUICtrlListView_DeleteAllItems($MainGui_MainListView)
	;Löscht alle SpaltenNamen
	for $i = 0 to _GUICtrlListView_GetColumnCount($MainGui_MainListView) + 1 step 1
		_GUICtrlListView_DeleteColumn($MainGui_MainListView, 0)
	next
	;Erstellt die Spaltennamen neu
	for $i = 1 to $iClumn step 1
		_GUICtrlListView_AddColumn($MainGui_MainListView, $array[$i])
		_GUICtrlListView_SetColumnWidth($MainGui_MainListView, $i - 1, 200)
	next
	;Versteckt die erste Spalte (ID), die nur für Befehle genutzt wird, um mit dem selektierten Buch weiterzuarbeiten
	_GUICtrlListView_HideColumn($MainGui_MainListView, 0)
	;Füllt die Listview mit den einzelnen Einträgen
	for $i = $iClumn + 1 to UBound($array) - 1 step $iClumn
		$string = ""
		;Alle Daten in einen String schreiben
		for $x = 0 to $iClumn - 2 step 1
			$string &= $array[$i + $x] & "|"
		next
		$string &= $array[$i + $iClumn - 1]
		;Listview Item erstellen
		GUICtrlCreateListViewItem($string, $MainGui_MainListView)
		;Farbe wechseln, damit einzelne Spalten besser unterschieden werden können
		if mod(int($i / $iClumn), 2) = 0 then
			GUICtrlSetBkColor(-1, 0xDDDDDD)
		endif
	next
	;Jetzt das neuzeichnen der Listview wieder aktivieren
	_GUICtrlListView_EndUpdate($MainGui_MainListView)
EndFunc   ;==>fillListView

Func getDataAndFillListview($sql, $lastIsPath = false)
	$aData=MainGetData($sql)
	if $aData<>-1 then
		fillListView($aData, false, $lastIsPath)
	Else
		return -1
	endif
EndFunc   ;==>getDataAndFillListview

Func MainGetData($sql)
	$aData = ""
	$iRow = ""
	$iClumn = ""
	_SQLite_GetTable($hDatabase, $sql, $aData, $iRow, $iClumn)
	If @error then
		ConsoleWriteError("Fehler in der Sql-Abfrage:" & $sql)
		return -1
	EndIf
	return $aData
EndFunc   ;==>MainGetData_self

Func closeSqlGui()
	GUIDelete($SqlGui)
EndFunc   ;==>closeSqlGui

Func sqlsend()
	local $exec = false
	$x = stringsplit(guictrlread($SqlGui_Edit3_1), @crlf)
	;Alle Zeilen im Edit durchgehen
	for $a = 1 to ubound($x) - 1 step +1
		;Auf Kommentar prüfen
		if stringinstr($x[$a], "#") = 1 Then
			;nichts
		else
			;Kommentar am Ende einer Zeile löschen
			if stringinstr($x[$a], "#") > 1 Then
				$strs = stringsplit($x[$a], "#")
				$x[$a] = $strs[1]
			endif
			;Select abfrage
			if stringinstr($x[$a], "select") <3 Then
				ConsoleWrite("Select"&@crlf)
				getDataAndFillListview($x[$a])
			;SQL Exec
			else
				if $x[$a] <> "" then
					ConsoleWrite("Exec"&@crlf)
					_SQLite_Exec($hDatabase, $x[$a])
					$exec = true
				endif
			endif
		endif
	next
	;Nur damit man weiß, das die Exec ausgeführt wurde, da dort ja sonst keine Anzeige steht.
	if $exec then
		msgbox(48,"Hinweis","Änderungen durchgeführt.")
	endif
	WinActivate($MainGui)
EndFunc   ;==>sqlsend