While...WEnd

Beschreibung anzeigen in

Schleife, die auf einem Ausdruck basiert.

While <expression>
statements
...
WEnd

Parameter

expression

Wenn der Ausdruck wahr ist, werden die Codezeilen bis WEnd ausgeführt. Die Schleife wird fortgesetzt, bis der Ausdruck unwahr ist.

Bemerkungen

While...WEnd-Schleifen können verschachtelt werden.
Der Ausdruck wird ausgewertet, bevor die Schleife durchlaufen wird, sodass die Schleife Null mal oder öfter durchlaufen wird.
Um eine Endlosschleife zu erhalten, kann man eine Zahl ungleich 0 als expression verwenden.

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>

Local $i = 0
While $i <= 10
    MsgBox($MB_SYSTEMMODAL, "Der Wert von $i lautet:", $i)
    $i = $i + 1
WEnd

Beispiel 2

; Setzt einen Hotkey für die Esc-Taste um das Skript zu beenden.
HotKeySet("{ESC}", "_Terminate")

Example()

Func Example()
    ; Initialisiert ein lokale Variable.
    Local $aMgp = 0

    ; Erstellt eine Endlosschleife, da 1 immer 1 und somit True ist.
    While 1
        ; Weist einer lokalen Variable die Koordinaten des Cursors zu (Array).
        $aMgp = MouseGetPos()

        ; Zeigt ein Tooltip in der Nähe des Cursors mit dessen Koordinaten an.
        ToolTip("x: " & $aMgp[0] & ", y: " & $aMgp[1], $aMgp[0] + 10, $aMgp[1] + 10)

        ; Vermeidung zu hoher CPU-Last.
        Sleep(50)
    WEnd
EndFunc   ;==>Example

Func _Terminate()
    Exit
EndFunc   ;==>_Terminate