_ArrayConcatenate
Beschreibung anzeigen in
Verbindet zwei Arrays, entweder 1D Arrays oder 2D Arrays mit der gleichen Anzahl an Spalten
#include <Array.au3>
_ArrayConcatenate ( ByRef $aArrayTarget, Const ByRef $aArraySource [, $iStart = 0] )
Parameter
| $aArrayTarget | Das Array zu dem das Quell-Array hinzugefügt werden soll (Ziel) |
| $aArraySource | Das Array welches zum Ziel-Array hinzugefügt werden soll (Quelle) |
| $iStart | [optional] Index des ersten Eintrags des Quellarrays (Standard = 0) |
Rückgabewert
| Erfolg: | Die Anzahl von Elementen bzw. Zeilen in dem neuen Zielarray |
| Fehler: | -1 und setzt das @error Flag auf ungleich null |
| @error: | 1 - $aArrayTarget ist kein Array 2 - $aArraySource ist kein Array 3 - $aArrayTarget ist kein 1D oder 1D Array 4 - $aArrayTarget und $aArraySource 1D/2D stimmen nicht überein 5 - Anzahl der Spalten von $aArrayTarget und $aArraySource stimmen nicht überein (nur 2D) 6 - $iStart außerhalb der Arraygrenzen |
Bemerkungen
Der $iStart Parameter ist nützlich, wenn Arrays verknüpft werden, die die Anzahl der Elemente im Element [0] haben.
Diese Funktion ändert keine Zähler innerhalb des Arrays. Jedoch wird durch die Funktion, falls diese erfolgreich war, die neue Anzahl an Zeilen im verbundenen Array zurückgegeben.
Verwandte Funktionen
Beispiel
#include <Array.au3>
Local $aArrayTarget[5] = ["0", "1", "2", "3", "4"]
Local $aArraySource[5] = ["5", "6", "7", "8", "9"]
_ArrayDisplay($aArrayTarget, "1D Ziel")
_ArrayDisplay($aArraySource, "1D Quelle")
_ArrayConcatenate($aArrayTarget, $aArraySource)
_ArrayDisplay($aArrayTarget, "1D Ziel und Quelle verbinden")
Local $aArrayTarget[4][3]
For $i = 0 To 3
For $j = 0 To 2
$aArrayTarget[$i][$j] = $i & $j
Next
Next
Local $aArraySource[4][3]
For $i = 0 To 3
For $j = 0 To 2
$aArraySource[$i][$j] = (4 + $i) & $j
Next
Next
_ArrayDisplay($aArrayTarget, "2D Ziel")
_ArrayDisplay($aArraySource, "2D Quelle")
_ArrayConcatenate($aArrayTarget, $aArraySource)
_ArrayDisplay($aArrayTarget, "2D Ziel und Quelle verbinden")