Funktionreferenz


_ArrayExtract

Beschreibung anzeigen in

Extrahiert ein Array von den angegebenen Elementen des 1D oder 2D Arrays

#include <Array.au3>
_ArrayExtract ( Const ByRef $aArray [, $iStart_Row = -1 [, $iEnd_Row = -1 [, $iStart_Col = -1 [, $iEnd_Col = -1]]]] )

Parameter

$aArray Array von dem extrahiert werden soll
$iStart_Row [optional] Erste Zeile des extrahierten Arrays
$iEnd_Row [optional] Letzte Zeile des extrahierten Arrays
$iStart_Col [optional] Erste Spalte des extrahierten Arrays (nur bei 2D)
$iEnd_Col [optional] Letzte Spalte des extrahierten Arrays (nur bei 2D)

Rückgabewert

Erfolg: extrahiertes Array
Fehler: -1 und setzt das @error Flag auf ungleich null.
@error: 1 - $aArray ist kein Array
2 - $aArray ist kein 1D oder 2D Array
3 - $iStart_Row oder $iEnd_Row ist außerhalb der Arraygrenzen
4 - $iStart_Row ist größer als $iEnd_Row
5 - $iStart_Col oder $iEnd_Col ist außerhalb der Arraygrenzen
6 - $iStart_Col ist größer als $iEnd_Col

Verwandte Funktionen

_ArrayAdd, _ArrayInsert

Beispiel

#include <Array.au3>

Local $aArray[4][4]
For $i = 0 To 3
    For $j = 0 To 3
        $aArray[$i][$j] = $i & $j
    Next
Next
_ArrayDisplay($aArray, "Original")
Local $aExtract = _ArrayExtract($aArray, 1, 2, 2, 3)
_ArrayDisplay($aExtract, "Zeilen 1-2 Spalten 2-3")