_IEFormElementOptionSelect

Beschreibung anzeigen in

Setzt den Wert des angegebenen Formelements

#include <IE.au3>
_IEFormElementOptionSelect ( ByRef $oObject, $sString [, $iSelect = 1 [, $sMode = "byValue" [, $iFireEvent = 1]]] )

Parameter

$oObject	Formelement Objekt vom Typ "Select Option"
$sString	Wert, der mit dem Element übereinstimmen soll - basierend auf der Auswahl von $sMode
$iSelect	[optional] gibt an, ob das Element ausgewählt oder nicht ausgewählt werden soll -1 = gibt den ausgewählten Status zurück 0 = Setzt den Status 'nicht ausgewählt' 1 = (Standard) Setzt den Status 'ausgewählt'
$sMode	[optional] gibt die Suchmethode an "byValue" = (Standard) Wert der Option, der ausgewählt werden soll "byText" = Text der Option, der ausgewählt werden soll "byIndex" = 0-basierender Index der Option die ausgewählt werden soll
$iFireEvent	[optional] gibt an, ob nach der Änderung ein OnChange und OnClick ausgeführt werden soll 0 = führt kein OnChange und OnClick aus 1 = (Standard) führt OnChange und OnClick nach der Wertänderung durch

Rückgabewert

Erfolg:	Wenn $iSelect = -1, ist der Rückgabewert der aktuelle Status, andernfalls ist der Rückgabewert 1.
Fehler:	0 und setzt das @error Flag auf ungleich null.
@error:	3 ($_IEStatus_InvalidDataType) - Ungültiger Datentyp 4 ($_IEStatus_InvalidObjectType) - Ungültiger Objekttyp 5 ($_IEStatus_InvalidValue) - Ungültiger Wert 7 ($_IEStatus_NoMatch) - Keine Übereinstimmung gefunden
@Extended:	Beinhaltet Nummer des ungültigen Parameters

Bemerkungen

Der $iFireEvent Parameter hat nur Bedeutung, wenn für das Formelement ein OnChange Event vorhanden ist.

Beispiel

Beispiel 1

#include <IE.au3>

; Öffnet einen Browser mit dem Formular Beispiel, stellt die Verbindung zu diesem Formular her, stellt die Verbindung zum gewählten Element her, geht in einer 10er Schleife die Auswahl Optionen byValue-Wert, byText-Wert und byIndex-Wert durch
; Es ist folgendes zu beachten: Möglicherweise muss man bis ans Ende der Seite scrollen, um die Änderung zu sehen.

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
_IEAction($oSelect, "focus")
For $i = 1 To 10
    _IEFormElementOptionSelect($oSelect, "Freepage", 1, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "midipage.html", 1, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 0, 1, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

Beispiel 2

#include <IE.au3>

; Öffnet einen Browser mit dem Formular Beispiel, stellt die Verbindung zu diesem Formular her,
; stellt die Verbindung zum gewählten Mehrfach-Element her, wählt das Element in einer 5fach Schleife an und ab; Optionen byValue, byText und byIndex.
; Folgendes ist zu beachten: Möglicherweise muss man bis ans Ende der Seite scrollen um die Änderung zu sehen.;

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "multipleSelectExample")
_IEAction($oSelect, "focus")
For $i = 1 To 3
    _IEFormElementOptionSelect($oSelect, "Carlos", 1, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Name2", 1, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 5, 1, "byIndex")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Carlos", 0, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Name2", 0, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 5, 0, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

Beispiel 3

#include <IE.au3>
#include <MsgBoxConstants.au3>

; Öffnet einen Browser mit dem Formular Beispiel, stellt die Verbindung zu diesem Formular her, stellt die Verbindung zum gewählten Element her, prüft ob die Option "Freepage" ausgewählt ist und gibt das Ergebnis zurück.
; Wiederholung mit der Option von Index 0 und mit der Option vom Wert 'midipage.html'
; Folgendes ist zu beachten: Möglicherweise muss man bis ans Ende der Seite scrollen um die Änderung zu sehen.

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
If _IEFormElementOptionSelect($oSelect, "Freepage", -1, "byText") Then
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Option Freepage ist ausgewählt")
Else
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Option Freepage ist nicht ausgewählt")
EndIf
If _IEFormElementOptionSelect($oSelect, 0, -1, "byIndex") Then
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Die erste Option (index 0) ist ausgewählt")
Else
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Die Erste Option (index 0) ist nicht ausgewählt")
EndIf
If _IEFormElementOptionSelect($oSelect, "midipage.html", -1, "byValue") Then
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Die Option mit dem Wert 'midipage.html' ist ausgewählt")
Else
    MsgBox($MB_SYSTEMMODAL, "Option ausgewählt", "Die Option mit dem Wert 'midipage.html' ist nicht ausgewählt")
EndIf

_IEQuit($oIE)

Funktionreferenz